메뉴
이 페이지에서
실무 위키›엑셀 함수›찾기 및 참조

TOCOL 함수

M365
지원 버전 자세히 보기
M365웹 엑셀

엑셀 TOCOL 함수는 선택한 범위를 하나의 세로 열로 변환하는 함수입니다.

예제파일 다운로드
TOCOL 함수 예제 미리보기
예제 미리보기 크게 보기

인수 설명

=TOCOL(범위, [제외옵션], [읽기방향])
인수구분설명
범위 필수
세로 열로 변환할 범위입니다.
  • 여러 범위를 세로로 변환할 때에는 (범위1,범위2,범위3,..)과 같이 괄호 안에 작성하거나,
    HSTACK 함수를 사용합니다.
  • 여러 시트를 동시에 선택한 후, 3D 함수로 범위를 참조할 수 있습니다.
    예) '시트1:시트3'!A1:A100
제외옵션 선택
빈 셀과 오류를 처리할 방식입니다. 기본값은 모든 값 포함입니다.
  • 0 : [기본값] 모든 값 포함
  • 1 : 빈 셀 무시
  • 2 : 오류 무시
  • 3 : 빈 셀과 오류 무시
읽기방향 선택
범위의 데이터를 읽을 방향입니다. 기본 값은 행 방향(가로) 읽기입니다.
  • FALSE : [기본값] 범위의 데이터를 가로 방향으로 읽습니다.
  • TRUE : 데이터를 세로 방향으로 읽습니다.
예제 시트
D2=TOCOL(A2:B3)
A
B
C
D
E
1
직원1
직원2
세로 결과
2
김하늘
김신우
김하늘
3
이초롱
정아름
김신우
4
이초롱
5
정아름
6

수식을 입력한 셀자동으로 채워진 범위

2행 2열 범위를 행 방향으로 읽은 네 이름이 D2:D5에 세로로 펼쳐집니다.

함수 개요

엑셀 TOCOL 함수는 선택한 범위를 세로의 단일 열로 변환하는 함수입니다. 가로/세로로 넓게 퍼진 데이터, 특히 정규화되지 않은 데이터를 가공할 때 구조를 초기화하는 단계에 사용할 수 있습니다. 또한 '제외옵션'과 '읽기방향'을 변경하여, 데이터를 효율적으로 변환할 수 있습니다.

=TOCOL(범위)범위를 세로로 긴 하나의 열로 변환합니다.
=TOCOL(범위,1)범위에서 공백을 제외한 값을 하나의 열로 변환합니다.
엑셀 TOCOL 함수 수식 입력 예제 1

TOCOL 함수는 여러 범위 또는 시트로 분산된 데이터를 하나로 취합할 때에도 유용하게 사용됩니다. 괄호 안에 여러 범위를 입력하거나, 여러 시트를 동시에 선택한 상태로 범위를 입력하여 데이터를 취합할 수 있습니다.

=TOCOL((범위1,범위2,범위3),1)범위1, 범위2, 범위3 의 공백을 제외한 값을 하나의 열로 취합합니다.
=TOCOL('시트1:시트5'!A1:A100,1)시트1~시트5의 A1:A100 범위에서 공백을 제외한 값을 하나의 열로 취합합니다.
엑셀 TOCOL 함수 수식 입력 예제 2

TOCOL 함수는 VSTACK 함수 와 달리 2차원의 배열을 1차원의 세로 배열로 변환하므로 복잡한 형태의 데이터를 정규화할 때 유리하며, IFNA 함수 와 WRAPROWS 함수 를 함께 사용하여 다양한 구조의 데이터를 변환할 수 있습니다.

TOCOL 함수 간단 예제

1
부서별 직원 명단 취합하기

A1:A10, C1:C10, E1:E10 범위에 각각 영업팀, 인사팀, 개발팀 직원 명단이 작성되어 있을 경우, 다음과 같이 함수를 작성하여 여러 범위의 직원 명단을 한 줄로 취합할 수 있습니다.

=TOCOL((A1:A10,C1:C10,E1:E10),1)여러 범위의 데이터를 한 열로 취합합니다. 범위에 빈 칸이 있을 경우, 빈 칸을 무시하고 취합합니다.
엑셀 TOCOL 함수 간단 예제 1
2
부서별 실적 데이터 하나로 취합하기

다음과 같이, A1:B3, C1:D3 에 부서별 실적 데이터가 작성되어 있다고 가정하겠습니다.

/ /A1:B3 = {영업팀-1월,100;영업팀-2월,200;영업팀-3월,300}
/ /C1:D3 = {광고팀-1월,150;광고팀-2월,250;광고팀-3월,350}
엑셀 TOCOL 함수 간단 예제 2 수식 1

이러한 경우, 다음과 같이 TOCOL 함수로 두 범위의 데이터를 세로로 취합한 후, WRAPROWS 함수 를 사용하여 2줄 단위로 데이터를 감싸 실적 데이터를 완성합니다.

=WRAPROWS(TOCOL((A1:B3,C1:D3)),2)
=WRAPROWS({영업팀-1월,100,영업팀2월,200,영업팀-3월,300,광고팀-1월,150,광고팀-2월,250,광고팀-3월,350})
={영업팀-1월,100;영업팀-2월,200;영업팀-3월,300;광고팀-1월,150;광고팀-2월,250;광고팀-3월,350}
엑셀 TOCOL 함수 간단 예제 2 수식 2
3
여러 시트 데이터를 하나로 취합하기

TOCOL 함수는 3D 형태로 작성하여 여러 개의 시트로 나뉘어 작성된 데이터를 하나로 취합할 수 있습니다.

=TOCOL('시트1:시트3'!A1:A100, 1)시트1 ~ 시트3의 A1:A100 범위에서 공백을 제외한 값을 한 줄로 취합합니다.
엑셀 TOCOL 함수 간단 예제 3

그 외 주의사항

TOCOL 함수의 결과로 반환되는 배열이 엑셀에서 처리 가능한 행의 최대 개수인 1,048,576 개를 초과할 경우 #NUM! 오류를 반환합니다.

TOCOL 함수로 반환되는 범위에 기존 데이터가 있을 경우, #SPILL! 오류를 반환합니다.

댓글 0
아직 댓글이 없습니다. 첫 번째 댓글을 작성해보세요!
MS 공식 문서에서 TOCOL 함수 보기최종 수정 2026. 8. 19.
이전 함수TRANSLATE 함수다음 함수 IFNA 함수
스크랩 완료