메뉴
실무 위키›응용 공식›엑셀 텍스트 날짜 변환 공식

엑셀 텍스트 날짜 변환 공식

지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

텍스트 형식으로 입력된 날짜를 계산 가능한 실제 날짜로 변경합니다.

예제파일 다운로드
엑셀 텍스트 날짜 변환 공식 예제 미리보기
예제 미리보기 크게 보기

인수 설명

018자리 숫자를 날짜로 바꾸기

=DATE ( LEFT ( 셀, 4 ), MID ( 셀, 5, 2 ), RIGHT ( 셀, 2 ) )
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
셀필수연도 4자리·월 2자리·일 2자리로 구성된 총 8자리 텍스트 날짜가 입력된 셀입니다. 자릿수가 다르면 오류 없이 엉뚱한 날짜를 결과값으로 출력할 수 있는 입력 형식입니다. 예) 260115 → 2602-03-15 (연도 자리가 2601로 잘림)
D2=DATE(LEFT(C2,4),MID(C2,5,2),RIGHT(C2,2))
A
B
C
D
E
1
전표번호
거래처
원본(텍스트)
변환 결과
2
SL-1001
한빛상사
20260115
2026-01-15
3
SL-1002
누리유통
20260122
2026-01-22
4
SL-1003
다온물산
20260203
2026-02-03
5
SL-1004
한빛상사
20260210
2026-02-10
6
SL-1005
세일산업
20260228
2026-02-28
7
엑셀에서 날짜가 셀 왼쪽에 붙어 표시되면 숫자가 아니라 텍스트로 입력된 값입니다.

02마침표로 구분된 날짜를 올바른 날짜로 바꾸기

=DATEVALUE ( SUBSTITUTE ( 셀, ".", "-" ) )
인수 설명 자세히 보기
인수구분설명
셀필수마침표로 구분된 텍스트 날짜가 입력된 셀입니다. 월과 일에 0을 붙이지 않아도 됩니다. 값 끝에 마침표가 하나 더 붙어 있으면 하이픈으로 바꿔도 날짜가 되지 않아 #VALUE! 오류를 출력합니다. 예) 2026.2.10 → 2026-02-10, 2026.01.22. → 오류
D2=DATEVALUE(SUBSTITUTE(C2,".","-"))
A
B
C
D
E
1
전표번호
거래처
원본(텍스트)
변환 결과
2
SL-1001
한빛상사
2026.01.22
2026-01-22
3
SL-1002
누리유통
2026.02.03
2026-02-03
4
SL-1003
다온물산
2026.2.10
2026-02-10
5
SL-1004
한빛상사
2026.02.28
2026-02-28
6
SL-1005
세일산업
2026.3.5
2026-03-05
7
변환 결과 열에는 날짜 서식을 적용해야 합니다. 서식을 적용하기 전에는 2026-01-22 대신 일련번호 46044가 표시됩니다.

03슬래시로 구분된 두 자리 연도 날짜를 바꾸기

=DATEVALUE ( 셀 )
인수 설명 자세히 보기
인수구분설명
셀필수슬래시로 구분된 텍스트 날짜가 입력된 셀입니다. 슬래시는 엑셀이 그대로 읽는 구분 기호라 다른 기호로 바꾸지 않아도 됩니다. 두 자리 연도는 0~29를 2000년대로, 30~99를 1900년대로 해석합니다. 예) 26/1/15 → 2026-01-15, 30/1/15 → 1930-01-15
D2=DATEVALUE(C2)
A
B
C
D
E
1
전표번호
거래처
원본(텍스트)
변환 결과
2
SL-1001
한빛상사
26/1/15
2026-01-15
3
SL-1002
누리유통
26/1/22
2026-01-22
4
SL-1003
다온물산
26/2/3
2026-02-03
5
SL-1004
한빛상사
26/2/10
2026-02-10
6
SL-1005
세일산업
26/2/28
2026-02-28
7
두 자리 연도는 1930년까지만 거슬러 올라갑니다. 그보다 앞선 날짜는 원본에서 네 자리 연도로 받아야 합니다.
이 공식이 사용하는 함수
DATE 함수 LEFT 함수 MID 함수 RIGHT 함수 DATEVALUE 함수 SUBSTITUTE 함수

동작 원리

018자리 숫자를 날짜로 바꾸기

LEFT 함수·MID 함수·RIGHT 함수가 텍스트에서 연·월·일 자리를 잘라내고, DATE 함수가 세 조각을 받아 실제 날짜로 조립합니다.

예제 시트에서 20260115를 변환하는 D2 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

LEFT 함수가 연도 자리를 잘라냅니다

LEFT 함수가 C2 셀 텍스트의 왼쪽에서 4자리를 잘라냅니다. 반환값은 숫자 2026이 아니라 문자열 "2026"입니다.

=DATE ( LEFT ( C2, 4 ), MID ( C2, 5, 2 ), RIGHT ( C2, 2 ) )
=DATE ( "2026", MID ( C2, 5, 2 ), RIGHT ( C2, 2 ) )
2

MID 함수와 RIGHT 함수가 월과 일 자리를 잘라냅니다

MID 함수는 5번째 자리부터 2자리를 잘라내 월 "01"을, RIGHT 함수는 오른쪽 2자리를 잘라내 일 "15"를 반환합니다. 두 반환값도 모두 문자열입니다.

=DATE ( "2026", MID ( C2, 5, 2 ), RIGHT ( C2, 2 ) )
=DATE ( "2026", "01", "15" )
3

DATE 함수가 세 조각을 실제 날짜로 조립합니다

DATE 함수의 연·월·일 자리에는 숫자가 필요하지만 문자열 "2026"·"01"·"15"를 받으면 숫자 2026·1·15로 변환해 계산합니다. 잘라낸 조각을 별도로 숫자로 바꾸지 않아도 날짜를 만드는 방식입니다.

=DATE ( "2026", "01", "15" )
= 2026-01-15 저장되는 값은 날짜 일련번호 46037이고, 화면에는 날짜 서식으로 표시됩니다.

02마침표로 구분된 날짜를 올바른 날짜로 바꾸기

SUBSTITUTE 함수가 마침표를 하이픈으로 바꿔 엑셀이 날짜로 읽는 형식을 만들고, DATEVALUE 함수가 그 텍스트를 날짜 일련번호로 변환합니다.

예제 시트에서 2026.01.22를 변환하는 D2 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

SUBSTITUTE 함수가 마침표를 하이픈으로 바꿉니다

한국어 윈도우는 하이픈을 날짜 구분 기호로 쓰기 때문에 마침표로 구분된 2026.01.22는 엑셀이 날짜로 읽지 못합니다. SUBSTITUTE 함수가 마침표를 모두 하이픈으로 바꿔 엑셀이 읽는 형식으로 만듭니다.

=DATEVALUE ( SUBSTITUTE ( C2, ".", "-" ) )
=DATEVALUE ( "2026-01-22" )
2

DATEVALUE 함수가 텍스트를 날짜 일련번호로 바꿉니다

DATEVALUE 함수는 날짜 형식 텍스트를 1900년 1월 1일부터 세는 날짜 일련번호로 변환합니다.

=DATEVALUE ( "2026-01-22" )
= 46044 2026년 1월 22일의 날짜 일련번호입니다.
댓글 0
아직 댓글이 없습니다. 첫 번째 댓글을 작성해보세요!
스크랩 완료