엑셀 VBA 파일선택창(FileDialog) 마스터 코드 사용법

Sub Multiple_FileDialog()
 
Dim FDG As FileDialog
Dim Selected As Integer: Dim i As Integer
Dim ReturnStr As String
 
Set FDG = Application.FileDialog(msoFileDialogFilePicker)
 
End Sub

With FDG
    .Title = "파일을 선택하세요"
    .Filters.Add "엑셀파일", "*.xls; *.xlsx; *.xlsm"
    .InitialView = msoFileDialogViewList
    .InitialFileName = ThisWorkbook.Path
    .AllowMultiSelect = True
    Selected = .Show
End With

If Selected = -1 Then  '파일이 선택되었을 경우 -1을 반환
    For i = 1 To FDG.SelectedItems.Count - 1
        ReturnStr = ReturnStr & FDG.SelectedItems(i) & ", "
        '// ReturnStr = ReturnStr & FDG.SelectedItems(i) & "| "
        '// 파일명에 콤마(,)가 들어갈 경우 구분기호를 세로바(|)로 대체합니다.
    Next i
    ReturnStr = ReturnStr & FDG.SelectedItems(.SelectedItems.Count)
End If

SelectAgain:
'.... 파일선택 본문
 
If Selected = 0 Then
    MsgBox "선택된 파일이 없습니다. 파일을 다시 선택해주세요."
    Goto SelectAgain:
end if

If Selected = 0 Then
    MsgBox "아무런 파일이 선택되지 않았습니다. 프로세스를 종료합니다."
    End
end if

Public Function Multiple_FileDialog(Optional Title As String = "파일을 선택하세요", Optional FilterName As String = "엑셀파일", _
Optional FilterExt As String = "*.xls; *.xlsx; *.xlsm", Optional InitialFolder As String = "", _
Optional InitialView As MsoFileDialogView = msoFileDialogViewList, Optional MultiSelection As Boolean = True, Optional PathDelimiter As String = "|", _
Optional withPath As Boolean = True, Optional withExt As Boolean = True) As String
'###############################################################
'오빠두엑셀 VBA 사용자지정함수 (https://www.oppadu.com)
'▶ MultipleFileDialog 함수
'▶ 파일선택창으로 여러개의 파일 경로를 받아옵니다.
'▶ 인수 설명
'_____________Title         : 파일선택창의 제목입니다.
'_____________FilterName    : 특정 확장자를 가진 파일만 표시할 경우, 표시할 이름 입니다.
'_____________FilterExt     : 파일 확장자입니다.
'_____________InitialFolder : 파일 선택창 시작 폴더경로입니다. 기본값은 윈도우 기본경로입니다 .
'_____________Initialview   : 파일선택창의 보기 형식입니다. 기본값은 일반보기입니다.
'_____________MultiSelection : True일 경우 여러 파일을 선택할 수 있습니다. 기본값은 True 입니다.
'_____________PathDelimiter : 여러 파일이 선택될 경우, 각 파일을 구분할 구분자입니다. 기본값은 "|" 입니다.
'_____________withPath      : True일 경우 파일 경로를 같이 출력합니다. 기본값은 True 입니다.
'_____________withExt       : True일 경우 파일 확장자를 같이 출력합니다. 기본값은 True 입니다.
'▶ 사용 예제
'GetPath = Multiple_FileDialog(, "PDF 또는 그림파일", "*.pdf, *.png, *.jpg, *.bmp, *.jpeg")
'Paths = Split(GetPath, "|")
'For Each Path In Paths
'    MsgBox Path
'Next
'##############################################################
Dim FDG As FileDialog
Dim Selected As Integer: Dim i As Integer
Dim ReturnStr As String: Dim tempStr As Variant
 
Set FDG = Application.FileDialog(msoFileDialogFilePicker)
 
With FDG
    .Title = Title
    .Filters.Add FilterName, FilterExt
    .InitialView = InitialView
    .InitialFileName = InitialFolder
    .AllowMultiSelect = MultiSelection
    Selected = .Show
 
    If Selected = -1 Then
        For i = 1 To FDG.SelectedItems.Count - 1
            If withPath = False Then tempStr = Right(FDG.SelectedItems(i), Len(FDG.SelectedItems(i)) - InStrRev(FDG.SelectedItems(i), "\")) Else tempStr = FDG.SelectedItems(i)
            If withExt = False Then tempStr = Left(tempStr, InStrRev(tempStr, ".") - 1)
            ReturnStr = ReturnStr & tempStr & PathDelimiter
        Next i
        If withPath = False Then tempStr = Right(FDG.SelectedItems(.SelectedItems.Count), Len(FDG.SelectedItems(.SelectedItems.Count)) - InStrRev(FDG.SelectedItems(.SelectedItems.Count), "\")) Else tempStr = FDG.SelectedItems(.SelectedItems.Count)
        If withExt = False Then tempStr = Left(tempStr, InStrRev(tempStr, ".") - 1)
        ReturnStr = ReturnStr & tempStr
 
        Multiple_FileDialog = ReturnStr
    ElseIf Selected = 0 Then
        MsgBox "선택된 파일이 없으므로 프로그램을 종료합니다."
        End
    End If
 
End With
 
End Function

Sub OpenFiles()
 
Dim SelectionStr As String
Dim Vars As Variant: Dim Var As Variant
 
SelectionStr = Multiple_FileDialog
 
Vars = Split(SelectionStr, "|")
 
For Each Var In Vars
    Application.Workbooks.Open Var
Next
 
MsgBox "선택된 엑셀 파일을 모두 실행하였습니다."
 
End Sub