메뉴
실무 위키›응용 공식›IF 함수 특정 문자 포함 검색

IF 함수 특정 문자 포함 검색

지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

IF 함수와 SEARCH 함수로 셀에 특정 문자가 포함되어 있는지 확인해 원하는 값을 출력하는 공식입니다. 찾을 문자를 하나, 여러 개, 범위로 지정할 수 있습니다.

예제파일 다운로드
IF 함수 특정 문자 포함 검색 예제 미리보기
예제 미리보기 크게 보기

인수 설명

01찾을 문자가 하나일 때

=IF ( ISNUMBER ( SEARCH ( 찾을문자, 검색범위 ) ), 출력값, "" )
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
찾을문자필수검색범위 안에 들어있는지 확인할 문자입니다. 대소문자는 구분하지 않습니다. 대소문자를 구분하려면 SEARCH 함수 대신 FIND 함수를 씁니다.
검색범위필수문자가 들어있는지 확인할 범위입니다.
출력값필수문자가 들어있을 때 내보낼 값입니다. 예) "포함", 1, B2
C2=IF(ISNUMBER(SEARCH($E$2,A2)),"포함","")
A
B
C
D
E
F
1
제품코드
제품명
포함여부
포함 글자
2
ST-10234
시스타 빅사이즈 티
RS
3
RS-2231
로즈맘 원피스
포함
4
PP-33021
피핀 봄신상 팬츠
5
TM-129
티메이 신상 블라우스
6
SS-30123
S스타일 맨투맨
7
ST-3102D
시스타 S2020 원피스
8
RS-3920
로즈맘 베스트 롱티
포함
9
SB-3309
스윗바니 원피스
10
TM-319S
티메이 블라우스
11
제품코드에 'RS' 가 들어있는 두 건만 '포함' 이 출력됩니다. 찾을 문자를 E2 셀에 두었으므로 값만 바꾸면 결과가 다시 계산됩니다.

02찾을 문자가 여러 개일 때 (OR 조건)

=IF ( OR ( ISNUMBER ( SEARCH ( 찾을문자1, 검색범위 ) ), ISNUMBER ( SEARCH ( 찾을문자2, 검색범위 ) ) ), 출력값, "" )
인수 설명 자세히 보기
인수구분설명
찾을문자1필수확인할 첫 번째 문자입니다.
찾을문자2필수확인할 두 번째 문자입니다. 셋 이상이면 ISNUMBER 함수 묶음을 쉼표로 이어 OR 함수 안에 계속 넣습니다.
검색범위필수문자가 들어있는지 확인할 범위입니다.
출력값필수문자가 하나라도 들어있을 때 내보낼 값입니다.
C2=IF(OR(ISNUMBER(SEARCH($E$2,A2)),ISNUMBER(SEARCH($E$3,A2))),"포함","")
A
B
C
D
E
F
1
제품코드
제품명
포함여부
포함 글자
2
ST-10234
시스타 빅사이즈 티
RS
3
RS-2231
로즈맘 원피스
포함
PP
4
PP-33021
피핀 봄신상 팬츠
포함
5
TM-129
티메이 신상 블라우스
6
SS-30123
S스타일 맨투맨
7
ST-3102D
시스타 S2020 원피스
8
RS-3920
로즈맘 베스트 롱티
포함
9
SB-3309
스윗바니 원피스
10
TM-319S
티메이 블라우스
11
'RS' 또는 'PP' 가 들어있는 세 건이 잡힙니다. 둘 다 들어있는 경우만 찾으려면 OR 함수를 AND 함수로 바꿉니다.

03찾을 문자를 범위로 지정할 때 (배열 수식)

=IF ( OR ( ISNUMBER ( SEARCH ( 찾을문자범위, 검색범위 ) ) ), 출력값, "" )
인수 설명 자세히 보기
인수구분설명
찾을문자범위필수확인할 문자가 나열된 범위입니다. 빈 셀이 포함되면 모든 행이 조건을 만족합니다. 값이 입력된 셀까지만 지정합니다. OR 함수가 결과를 하나로 접으므로 세로·가로 어느 방향이든 그대로 넣습니다.
검색범위필수문자가 들어있는지 확인할 범위입니다.
출력값필수문자가 하나라도 들어있을 때 내보낼 값입니다.
C2=IF(OR(ISNUMBER(SEARCH($E$2:$E$3,A2))),"포함","")
A
B
C
D
E
F
1
제품코드
제품명
포함여부
포함 글자
2
ST-10234
시스타 빅사이즈 티
RS
3
RS-2231
로즈맘 원피스
포함
PP
4
PP-33021
피핀 봄신상 팬츠
포함
5
TM-129
티메이 신상 블라우스
6
SS-30123
S스타일 맨투맨
7
ST-3102D
시스타 S2020 원피스
8
RS-3920
로즈맘 베스트 롱티
포함
9
SB-3309
스윗바니 원피스
10
TM-319S
티메이 블라우스
11
결과는 위 공식과 같지만, 찾을 문자가 늘어나도 범위만 넓히면 됩니다. 엑셀 2019 이하에서는 배열수식이므로 Ctrl+Shift+Enter 로 입력한 뒤 아래로 채웁니다.
이 공식이 사용하는 함수
IF 함수 ISNUMBER 함수 SEARCH 함수 OR 함수

동작 원리

SEARCH 함수로 문자가 들어있는 위치를 찾고, ISNUMBER 함수가 그 결과를 참·거짓으로 바꿉니다. IF 함수는 그 참·거짓에 따라 출력값을 내보냅니다.

예제 시트에서 제품코드에 'RS' 가 들어있는지 확인하는 C3 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

SEARCH 함수로 문자가 몇 번째에 있는지 찾습니다

IF 함수는 와일드카드를 지원하지 않아 셀="*RS*" 같은 조건이 통하지 않습니다. 그래서 포함 여부를 SEARCH 함수로 먼저 판정합니다. SEARCH 함수는 찾는 문자가 있으면 시작 위치를, 없으면 #VALUE! 오류를 반환합니다.

= SEARCH ( "RS", "RS-2231" )
= 1 'RS' 가 첫 글자에서 시작하므로 1 을 반환합니다.
= SEARCH ( "RS", "ST-10234" )
= #VALUE! 'RS' 가 없으므로 오류를 반환합니다.
2

ISNUMBER 함수로 숫자인지 오류인지 가릅니다

위치 번호는 그대로 조건으로 쓸 수 없습니다. ISNUMBER 함수로 한 번 더 감싸면 숫자일 때 TRUE, 오류일 때 FALSE 가 됩니다.

= ISNUMBER ( 1 )
= TRUE 문자가 들어있는 경우입니다.
= ISNUMBER ( #VALUE! )
= FALSE 문자가 없는 경우입니다.
3

IF 함수로 출력값을 정합니다

참·거짓이 정해졌으니 IF 함수가 내보낼 값을 고릅니다.

세 번째 인수를 생략하면 조건이 거짓일 때 FALSE 가 그대로 셀에 출력됩니다. 빈칸으로 두려면 "" 를 반드시 적습니다.

= IF ( TRUE, "포함", "" )
= 포함 C3 셀에 출력되는 값입니다.
= IF ( FALSE, "포함", "" )
= (빈칸) C2 셀은 비어 있게 됩니다.
댓글 89
5 (56개 평가)
Robin
Robin 2020.03.15 11:26
최고최고
갓빠두형님최고
갓빠두형님최고 2020.03.26 07:19
항상 감사드립니다!
레드불
레드불 2020.03.29 17:43
감사합니다.
항상 잘 배우고있습니다. 행복하세요
호야
호야 2020.04.03 11:34
잘보고 갑니다.
토토가
토토가 2020.04.04 05:22
나이스하네요~~^^
피로엔박카스
피로엔박카스 2020.04.13 09:05
유용하게 잘쓰고 있어요~
ky0930
ky0930 2020.04.26 20:20
여기 있는 내용을 모아서 책으로 만들어서 멋진 책이 되겠네요.
새신랑
새신랑 2020.04.29 14:39
최고 입니다!!
쭌
쭌 2020.05.04 15:47
정말 멋진 팁이네요!
chihyun****
chihyun**** 2020.05.20 23:09
정말 필요한 내용이 너무 많네요
감사합니다~
스크랩 완료