이 페이지에서

실무 위키›엑셀 함수›논리

BYROW 함수

2024

지원 버전 자세히 보기

엑셀 2024M365웹 엑셀

엑셀 BYROW 함수는 범위의 각 행에 지정한 함수를 적용하고 결과 배열을 반환하는 함수입니다.

예제파일 다운로드

BYROW 함수 예제 미리보기

예제 미리보기 크게 보기

인수 설명

=BYROW(범위, 계산식)

인수구분설명

범위 필수

BYROW 함수를 사용해 행 단위로 계산을 적용할 범위 또는 배열입니다.

계산식 필수

각 행에 적용할 계산식 또는 LAMBDA 함수입니다.

단순 합계(SUM), 평균(AVERAGE) 등 계산은 'short-form' 내장 함수로 계산할 수 있습니다.
예) =BYROW(범위, SUM), =BYROW(범위, AVERAGE) 등..
LAMBDA 함수를 직접 작성하여 다양한 고급 로직을 구현할 수 있으며, LAMBDA 함수는 아래 구조로 작성합니다.
예) =BYROW(범위, LAMBDA(a, 함수(a)))
BYROW 함수의 내장함수는 총 12개를 제공합니다.
- SUM(합계), AVERAGE(평균), MEDIAN(중앙값), COUNT(숫자개수), COUNTA(개수), MAX(최대값), MIN(최소값), PRODUCT(곱), ARRAYTOTEXT(텍스트변환),CONCAT(텍스트병합),STDEV(표준편차),VAR(분산),MODE(최빈값)

예제 시트

G2=BYROW(B2:E6,SUM)

A

B

C

D

E

F

G

H

1

년도

1분기

2분기

3분기

4분기

합계

2

용산점

265

100

272

124

761

3

신촌점

272

163

188

275

898

4

영등포점

277

275

259

282

1,093

5

강남점

271

195

287

112

865

6

분당점

142

282

283

113

820

7

수식을 입력한 셀자동으로 채워진 범위

각 행의 1~4분기 값에 SUM을 적용한 합계 761, 898, 1,093, 865, 820이 G2:G6에 차례로 펼쳐집니다.

함수 개요

엑셀 BYROW 함수는 범위의 각 행에 지정한 함수를 적용한 결과를 배열로 반환하는 함수입니다. 즉, 이 함수는 범위의 각 행 단위로 데이터를 처리하는 함수로 합계, 평균, 최대값 등 다양한 계산을 한 번에 수행할 수 있습니다. 아래 예제에서 B2:D4 범위에는 세 학생의 국어, 수학, 영어 점수가 입력되어 있습니다.

=BYROW(B2:D4,SUM)각 행별 합계를 계산합니다.

=BYROW(B2:D4,AVERAGE)각 행별 평균을 계산합니다.

=BYROW(B2:D4,CONCAT)각 행별 텍스트를 합칩니다.

엑셀 BYROW 함수 수식 입력 예제 1

이 외에도 함수식에 LAMBDA 를 활용해서 다양한 계산을 수행할 수 있습니다. 아래 예제에서 B2:D3 범위에는 두 제품의 분기별 판매량이 입력되어 있습니다.

=BYROW(B2:D3,LAMBDA(a,SUM(a)))각 행별 합계를 계산합니다. SUM과 동일합니다.

=BYROW(B2:D3,LAMBDA(a,TEXTJOIN(",",,a)))각 행별 텍스트를 ","로 구분해서 합칩니다.

엑셀 BYROW 함수 수식 입력 예제 2

BYROW 함수는 LET 함수 , LAMBDA 함수 , MAP 함수 , BYCOL 함수 등 여러 동적 배열 함수와 결합해서 다양한 데이터 가공 및 분석에 활용할 수 있습니다.

BYROW 함수 간단 예제

1

각 행별 월 매출 합계 구하기

각 부서별 월간 매출데이터가 아래 그림과 같이 작성되어 있을 때, BYROW 함수를 사용하면 각 부서의 총 매출을 빠르게 계산할 수 있습니다.

=BYROW(B2:D5,SUM)B2:D5 범위의 행별 합계를 계산합니다.

BYROW-예제-1 — 각 부서의 월별 매출 합계를 계산합니다.

2

다수의 시험 점수 중 최대값 찾기

아래 그림과 같이 총 3회에 걸친 시험 점수 데이터에서 각 학생별 최고 성적을 구해야 할 때, 다음과 같이 BYROW 함수를 사용할 수 있습니다.

=BYROW(B2:D5,MAX)B2:D2 범위의 각 행별로 최대값을 계산합니다.

BYROW-예제-2 — 각 학생의 최고 성적을 구합니다.

3

각 행별 고유값을 하나로 취합하기

각 지점의 월별 우수 사원이 정리된 데이터에서 지점별 우수사원 목록을 취합해야 할 때, 다음과 같이 BYROW 함수를 작성합니다.

=BYROW(B2:E6,LAMBDA(a,TEXTJOIN(",",,UNIQUE(a,TRUE))))B2:E6 범위의 각 행별 고유값을 쉼표로 구분해서 취합합니다.

BYROW-예제-3 — 각 지점의 우수 사원을 쉼표로 구분해서 하나로 취합합니다.

그 외 주의사항

계산식으로 잘못된 수식이나 LAMBDA 함수가 입력된 경우, 함수는 #VALUE! 오류를 반환합니다.

LAMBDA 로 함수를 입력하지 않거나, 작성한 LAMBDA 수식이 또 다른 배열을 반환할 경우 #CALC! 오류가 발생할 수 있습니다.

단순 계산식은 SUM, AVERAGE, COUNT 등 인수를 하나만 받는 단일 함수에만 적용되며, 복잡한 집계는 LAMBDA를 직접 작성해야 합니다.

BYROW 함수는 결과로 배열을 반환하므로, 출력 범위에 다른 값이 있으면 #SPILL! 오류가 반환됩니다.

BYROW 함수는 M365 및 엑셀 2024 이후 버전에서만 제공되며, 이전 버전 엑셀에서는 #NAME? 오류를 출력합니다.

댓글 1

5 (1개 평가)

JOHW 2026.05.28 11:14

감사합니다.

MS 공식 문서에서 BYROW 함수 보기최종 수정 2026. 8. 20.

이전 함수CHOOSEROWS 함수 다음 함수 BYCOL 함수

스크랩 완료