엑셀 만·천 단위 제거 후 합계 공식
지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀
한글 만·천 단위 텍스트를 숫자로 바꿔 더하는 합계 공식입니다.
인수 설명
01SUMPRODUCT 일반 수식
=SUMPRODUCT ( --SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( 합계범위, "만", "." ), "천", "" ), "원", "" ), " ", "" ) * 10000 )인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
합계범위필수만·천 단위 텍스트를 제거한 뒤 합산할 범위입니다. 4만 3천원처럼 만과 천 단위가 자릿값 순서대로 입력되어야 합니다.
A
B
C
D
E
1
품목
금액
합계
2
사무용품
4만 3천원
309000
3
교통비
3만 2천원
4
배송비
1만 8천원
5
광고비
7만 5천원
6
식비
2만 1천원
7
교육비
6만 4천원
8
통신비
5만 6천원
9
02SUM 배열 수식 (Excel 2019 이하 CSE)
{=SUM ( SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( 합계범위, "만", "." ), "천", "" ), "원", "" ), " ", "" ) * 10000 )}인수 설명 자세히 보기
인수구분설명
합계범위필수만·천 단위 텍스트를 제거한 뒤 합산할 범위입니다. 4만 3천원처럼 만과 천 단위가 자릿값 순서대로 입력되어야 합니다.
A
B
C
D
E
1
품목
금액
합계
2
사무용품
4만 3천원
309000
3
교통비
3만 2천원
4
배송비
1만 8천원
5
광고비
7만 5천원
6
식비
2만 1천원
7
교육비
6만 4천원
8
통신비
5만 6천원
9
이 공식이 사용하는 함수
동작 원리
01SUMPRODUCT 일반 수식
SUBSTITUTE 함수가 만·천 단위를 소수 형태로 바꾸고 SUMPRODUCT 함수가 원 단위 숫자 배열의 합계를 계산합니다.
SUMPRODUCT 일반 수식의 예제 시트에서 D2 셀이 309000을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
1
SUBSTITUTE 함수가 단위를 제거합니다
SUBSTITUTE 함수는 만을 소수점으로 바꾸고 천·원·공백을 제거합니다. 억·천만 단위에 같은 원리를 적용할 때는 억을 소수점으로, 천만을 빈 문자열로 바꾼 뒤 100000000을 곱합니다.
=SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( B2:B8, "만", "." ), "천", "" ), "원", "" ), " ", "" )
만·천 단위 금액을 소수 형태의 텍스트로 바꿉니다. = {"4.3";"3.2";"1.8";"7.5";"2.1";"6.4";"5.6"}
각 금액에서 단위를 제거한 결과입니다. 2
금액을 원 단위 숫자로 바꿉니다
이중 음수 기호가 텍스트를 숫자로 바꾸고 10000을 곱해 각 값을 원 단위 금액으로 환산합니다.
=--{"4.3";"3.2";"1.8";"7.5";"2.1";"6.4";"5.6"}*10000
소수 형태의 텍스트를 원 단위 숫자로 환산합니다. = {43000;32000;18000;75000;21000;64000;56000}
B2:B8에 대응하는 원 단위 금액입니다. 3
SUMPRODUCT 함수가 금액을 더합니다
SUMPRODUCT 함수는 일곱 금액을 모두 더해 최종 합계를 반환합니다.
=SUMPRODUCT ( {43000;32000;18000;75000;21000;64000;56000} )
원 단위 금액 배열을 합산합니다. = 309000
43000+32000+18000+75000+21000+64000+56000의 합계입니다. 02SUM 배열 수식 (Excel 2019 이하 CSE)
SUBSTITUTE 함수가 만·천 단위를 소수 형태로 바꾸고 SUM 함수가 원 단위 숫자 배열의 합계를 계산합니다.
SUM 배열 수식의 예제 시트에서 D2 셀이 309000을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
1
SUBSTITUTE 함수가 단위를 제거합니다
SUBSTITUTE 함수는 만을 소수점으로 바꾸고 천·원·공백을 제거해 각 금액을 소수 형태로 만듭니다.
=SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( SUBSTITUTE ( B2:B8, "만", "." ), "천", "" ), "원", "" ), " ", "" )
만·천 단위 금액을 소수 형태의 텍스트로 바꿉니다. = {"4.3";"3.2";"1.8";"7.5";"2.1";"6.4";"5.6"}
각 금액에서 단위를 제거한 결과입니다. 2
금액을 원 단위 숫자로 바꿉니다
치환 결과에 10000을 곱하면 텍스트가 숫자로 변환되면서 각 값이 원 단위 금액으로 환산됩니다.
={"4.3";"3.2";"1.8";"7.5";"2.1";"6.4";"5.6"}*10000
소수 형태의 텍스트를 원 단위 숫자로 환산합니다. = {43000;32000;18000;75000;21000;64000;56000}
B2:B8에 대응하는 원 단위 금액입니다. 3
SUM 함수가 금액을 더합니다
SUM 함수는 배열 수식으로 계산된 일곱 금액을 모두 더해 최종 합계를 반환합니다.
=SUM ( {43000;32000;18000;75000;21000;64000;56000} )
원 단위 금액 배열을 합산합니다. = 309000
43000+32000+18000+75000+21000+64000+56000의 합계입니다. 
혹시 "."로 바꿀 텍스트 외의 텍스트는 한꺼번에 substitute 함수로 바꿔줘도 괜찮을까요?
"천", "원" 각각이 아니라 "천원"으로 바꾸는 방식이요. 해보니까 결과값은 다르지 않는데 실제로 응용하는 경우 염두해야할 사항이 있을까요?
네 위의 공식은 하나의 예제입니다. "천", "원" 각각이 아닌 "천원"으로 변경해서 사용하셔도 무방합니다. 다만, 천 이하 단위의 숫자가 있을 경우 4"천원"32 이런식으로 옳지 않은 값이 반환될 수도 있을듯 하니, 이 점만 유의하시면 될 듯 합니다.
답변이 도움이 되셨길 바랍니다.