메뉴
실무 위키›응용 공식›엑셀 분기별 합계 구하기 공식

엑셀 분기별 합계 구하기 공식

지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

지출 내역에서 날짜와 부서별 합계를 구합니다. 분기(1,2,3,4)를 직접 입력해 구하는 방법도 함께 알아봅니다.

인수 설명

01시작일과 종료일 기준으로 집계하기

=SUMIFS ( 합계 범위, 부서 범위, 부서, 날짜 범위, 시작 조건, 날짜 범위, 종료 조건 )
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
합계 범위필수더할 금액이 들어 있는 범위입니다.
부서 범위필수부서를 대조할 범위입니다. 합계 범위와 크기가 같아야 합니다.
부서필수집계할 부서 이름입니다.
날짜 범위필수기간을 대조할 날짜 범위입니다.
시작 조건필수">="&F2처럼 비교 연산자를 큰따옴표로 묶고 &로 셀을 잇습니다. 연산자를 셀 안에 함께 적으면 텍스트로 읽혀 집계되지 않습니다.
종료 조건필수"<="&G2 형식으로 적습니다. 종료일을 분기의 마지막 날로 두어야 그날 발생한 금액까지 들어갑니다.
H2=SUMIFS($C$2:$C$7,$B$2:$B$7,E2,$A$2:$A$7,">="&F2,$A$2:$A$7,"<="&G2)
A
B
C
D
E
F
G
H
I
1
날짜
부서
금액
부서
시작일
종료일
분기 합계
2
2026-01-14
영업팀
420,000
영업팀
2026-01-01
2026-03-31
960,000
3
2026-02-03
개발팀
185,000
영업팀
2026-04-01
2026-06-30
530,000
4
2026-02-27
개발팀
360,000
개발팀
2026-01-01
2026-03-31
545,000
5
2026-03-22
영업팀
540,000
개발팀
2026-04-01
2026-06-30
270,000
6
2026-04-08
영업팀
530,000
7
2026-05-19
개발팀
270,000
8
왼쪽 내역은 날짜순이 아니어도 됩니다. 오른쪽 표의 시작일과 종료일만 맞으면 순서와 상관없이 집계됩니다.

02분기 번호(1,2,3,4)로 분기별 합계 구하기

=SUMIFS ( 합계 범위, 부서 범위, 부서, 날짜 범위, 시작 조건, 날짜 범위, 종료 조건 )
인수 설명 자세히 보기
인수구분설명
합계 범위필수더할 금액이 들어 있는 범위입니다.
부서 범위필수부서를 대조할 범위입니다.
부서필수집계할 부서 이름입니다.
날짜 범위필수기간을 대조할 날짜 범위입니다.
시작 조건필수분기 번호로 그 분기의 첫날을 만들어 씁니다. 1분기는 1월, 2분기는 4월처럼 세 달씩 건너뛰므로 번호에 3을 곱하고 2를 뺍니다.
종료 조건필수시작 조건과 같은 분기 번호에서 만듭니다. 분기 첫날에서 두 달 뒤 말일이 곧 분기의 마지막 날이므로, 말일을 직접 적지 않아도 윤년의 2월까지 자동으로 맞습니다.
G2=SUMIFS($C$2:$C$7,$B$2:$B$7,E2,$A$2:$A$7,">="&DATE(2026,F2*3-2,1),$A$2:$A$7,"<="&EOMONTH(DATE(2026,F2*3-2,1),2))
A
B
C
D
E
F
G
H
1
날짜
부서
금액
부서
분기
분기 합계
2
2026-01-14
영업팀
420,000
영업팀
1
960,000
3
2026-02-03
개발팀
185,000
영업팀
2
530,000
4
2026-02-27
개발팀
360,000
개발팀
1
545,000
5
2026-03-22
영업팀
540,000
개발팀
2
270,000
6
2026-04-08
영업팀
530,000
7
2026-05-19
개발팀
270,000
8
분기 번호만 바꾸면 되므로 분기 경계 날짜를 따로 관리하지 않아도 됩니다.
이 공식이 사용하는 함수
SUMIFS 함수 DATE 함수 EOMONTH 함수

동작 원리

02분기 번호(1,2,3,4)로 분기별 합계 구하기

DATE 함수가 분기 번호로 첫날을 만들고, EOMONTH 함수가 그 날짜에서 두 달 뒤 말일을 구해 분기의 끝을 정합니다.

예제 시트에서 영업팀 1분기를 집계하는 G2 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

DATE 함수가 분기의 첫날을 만듭니다

분기 번호 1에 3을 곱하고 2를 빼면 1이 되어 1월을 가리킵니다. DATE 함수가 그 달의 1일을 날짜로 만듭니다.

=SUMIFS ( … , ">="&DATE ( 2026, F2*3-2, 1 ), … )
= 2026-01-01
2

EOMONTH 함수가 분기의 마지막 날을 구합니다

EOMONTH 함수에 두 달을 넣으면 첫날에서 두 달 뒤의 말일을 반환합니다. 분기가 세 달이므로 이 값이 곧 분기의 끝입니다.

=SUMIFS ( … , "<="&EOMONTH ( 2026-01-01, 2 ) )
= 2026-03-31 말일을 직접 적지 않으므로 2월이 28일인 해와 29일인 해가 모두 맞습니다.
3

SUMIFS 함수가 그 기간의 금액만 더합니다

부서가 영업팀이면서 날짜가 1월 1일부터 3월 31일 사이인 행만 남습니다. 420,000과 540,000이 더해집니다.

=SUMIFS ( C2:C7, B2:B7, "영업팀", A2:A7, ">=2026-01-01", A2:A7, "<=2026-03-31" )
= 960,000
댓글 0
아직 댓글이 없습니다. 첫 번째 댓글을 작성해보세요!
스크랩 완료