5년 연속 IT분야 베스트셀러! 「 진짜쓰는 실무엑셀 」로 2026년 공부 끝내기 오빠두엑셀 `2026 무료 챌린지` 오픈! 완주하고 수료증 받아가세요! 엑셀이 막히셨나요? Q&A 게시판에서 바로 해결하세요.
메뉴
실무 위키›응용 공식›엑셀 그룹별 순위 구하기 공식

엑셀 그룹별 순위 구하기 공식

지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

같은 그룹 안에서 값의 순위를 계산하는 그룹별 순위 공식입니다.

예제파일 다운로드
엑셀 그룹별 순위 구하기 공식 예제 미리보기
예제 미리보기 크게 보기

인수 설명

01모든 버전 동률 순위 공식

=SUMPRODUCT ( ( 그룹범위=그룹명 ) * ( 값범위>시작값 ) ) + 1
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
그룹범위필수순위를 나눌 그룹이 입력된 범위입니다. 아래로 채울 때 바뀌지 않도록 절대참조로 입력합니다.
그룹명필수현재 행이 속한 그룹을 지정하는 셀입니다.
값범위필수그룹별 순위를 계산할 값이 입력된 범위입니다. 아래로 채울 때 바뀌지 않도록 절대참조로 입력합니다.
시작값필수현재 행에서 순위를 계산할 값입니다. 큰 값을 1위로 계산할 때는 값범위와 > 연산자로 비교하고, 작은 값을 1위로 계산하려면 < 연산자로 바꿉니다.
D2=SUMPRODUCT(($A$2:$A$8=A2)*($B$2:$B$8>B2))+1
A
B
C
D
E
1
그룹
값
동률 순위
2
A그룹
27
2
3
A그룹
32
1
4
A그룹
12
4
5
B그룹
26
2
6
B그룹
22
3
7
B그룹
39
1
8
A그룹
27
2
9
A그룹의 27보다 큰 값은 32 하나이므로 D2 셀은 2를 반환하고, 같은 그룹의 같은 값은 같은 순위를 받습니다.

02Excel 2007 이후 동률 해소 공식

=SUMPRODUCT ( ( 그룹범위=그룹명 ) * ( 값범위>시작값 ) ) + COUNTIFS ( 누적그룹범위, 그룹명, 누적값범위, 시작값 ) + 1
인수 설명 자세히 보기
인수구분설명
그룹범위필수순위를 나눌 그룹이 입력된 범위입니다. 아래로 채울 때 바뀌지 않도록 절대참조로 입력합니다.
그룹명필수현재 행이 속한 그룹을 지정하는 셀입니다.
값범위필수그룹별 순위를 계산할 값이 입력된 범위입니다. 아래로 채울 때 바뀌지 않도록 절대참조로 입력합니다.
시작값필수현재 행에서 순위를 계산할 값입니다. 큰 값을 1위로 계산할 때는 값범위와 > 연산자로 비교하고, 작은 값을 1위로 계산하려면 < 연산자로 바꿉니다.
누적그룹범위필수그룹 머리글부터 현재 행의 바로 위 셀까지 넓어지는 확장범위입니다. 시작 셀은 절대참조, 끝 셀은 상대참조로 입력합니다.
누적값범위필수값 머리글부터 현재 행의 바로 위 셀까지 넓어지는 확장범위입니다. 시작 셀은 절대참조, 끝 셀은 상대참조로 입력합니다.
D2=SUMPRODUCT(($A$2:$A$8=A2)*($B$2:$B$8>B2))+COUNTIFS($A$1:A1,A2,$B$1:B1,B2)+1
A
B
C
D
E
1
그룹
값
고유 순위
2
A그룹
27
2
3
A그룹
32
1
4
A그룹
12
4
5
B그룹
26
2
6
B그룹
22
3
7
B그룹
39
1
8
A그룹
27
3
9
두 번째 A그룹 27은 기본 순위 2에 앞서 나온 같은 그룹·같은 값 1건을 더하므로 D8 셀은 중복 없는 순위 3을 반환합니다.

03Excel 2007 이후 COUNTIFS 공식

=COUNTIFS ( 그룹범위, 그룹명, 값범위, ">"&시작값 ) + 1
인수 설명 자세히 보기
인수구분설명
그룹범위필수순위를 나눌 그룹이 입력된 범위입니다. 아래로 채울 때 바뀌지 않도록 절대참조로 입력합니다.
그룹명필수현재 행이 속한 그룹을 지정하는 셀입니다.
값범위필수그룹별 순위를 계산할 값이 입력된 범위입니다. 아래로 채울 때 바뀌지 않도록 절대참조로 입력합니다.
시작값필수현재 행에서 순위를 계산할 값입니다. 비교 연산자는 큰따옴표로 묶고 &로 셀과 연결합니다. 예) ">"&B2 (큰 값을 1위), "<"&B2 (작은 값을 1위)
D2=COUNTIFS($A$2:$A$8,A2,$B$2:$B$8,">"&B2)+1
A
B
C
D
E
1
그룹
값
COUNTIFS 순위
2
A그룹
27
2
3
A그룹
32
1
4
A그룹
12
4
5
B그룹
26
2
6
B그룹
22
3
7
B그룹
39
1
8
A그룹
27
2
9
COUNTIFS 함수가 A그룹에서 27보다 큰 값 32를 1개 세고 1을 더하므로 D2 셀은 2를 반환합니다.
이 공식이 사용하는 함수
SUMPRODUCT 함수 COUNTIFS 함수

댓글 22

댓글 22
4.9 (13개 평가)
이혜
이혜 2020.09.11 01:44
감사합니다
yim****
yim**** 2020.10.03 09:05
감사합니다
기러기
기러기 2020.11.19 13:15
잘보았읍니다..
오승학
오승학 2021.04.29 23:51
오름차순으로 하려면어떻게 해야 할까요?
dr****
dr**** 2021.04.30 09:48
오름차순으로 계산하려면 부등호만 바꿔주면 되겠죠??
오빠두엑셀
오빠두엑셀 작성자 2021.05.07 02:08
안녕하세요. 네 맞습니다. 오름차순으로 계산하려면 공식의 부등호를 반대로 입력해주세요 :)
강유정
강유정 2021.05.01 21:40
=SUMPRODUCT(($그룹범위=그룹명)*($값범위>시작값))+COUNTIFS($그룹명머릿글:그룹명머릿글,그룹명,$시작값머릿글:시작값머릿글,시작값)+1
여기서 그룹명머릿글이 어떤건가요?
오빠두엑셀
오빠두엑셀 작성자 2021.05.07 02:14
안녕하세요.
표의 머릿글입니다. :)
dolon****
dolon**** 2022.06.02 08:13
그룹명머릿글 시작값머릿글은 어떻게 지정하나요?
오빠두엑셀
오빠두엑셀 작성자 2022.06.02 15:42
표의 머리글이 A1셀에 있다면 $A$1:A1 형태로 입력해보세요.
홍반장
홍반장 2021.05.02 09:39
감사합니다. 학년 자료에서 반별 순위를 구할 때 간단히 해결됩니다.
PDY
PDY 2021.06.15 16:06
그룹 별 순위에 연속순위(예를들어 123345)는 어떤방식으로 해야하나요!?
오빠두엑셀
오빠두엑셀 작성자 2021.06.16 01:59
안녕하세요.
1,2,3,3,4,5 로 출력하는 건 공식 하나만으론느 해결이 어려워 보입니다.
우측에 보조열을 추가해서 COUNTIF 함수로 중복되는 값이 있는지 확인 후 -1, -2를 빼주는 형태로..
단계별로 작성하셔야 할 듯 합니다.
PDY
PDY 2021.06.16 07:57
감사합니다! 화이팅입니다!
조세형
조세형 2023.02.01 16:37
중복순위 삭제를 위해 sumproduct, countif 함수 끝에 '+1'을 넣으면 결과 값이 1이 없고2,3,4... 이렇게 나옵니다. 1부터 나오게하려면 '+1' 삭제하면 됩니다.
스톤젬
스톤젬 2023.11.28 11:29
그룹 조건을 여러개 추가할 수 있나요? 지금은 그룹 범위가 "부서"로 하나인데 그룹이랑 조건을 추가하고 싶어서요!
오빠두엑셀
오빠두엑셀 작성자 2023.11.29 03:53
안녕하세요.
네 가능합니다.
($그룹범위1=그룹명1)*($그룹범위2=그룹명2)*($값범위>시작값)
형식으로 추가 조건을 곱셈으로 연산해보세요.
경북이슬사과
경북이슬사과 2024.02.10 01:00
좋은 강의 감사합니다.
1차 조건 동 순위시, 2차 조건으로 순위 매기는 방법은 없을까요?
오빠두엑셀
오빠두엑셀 작성자 2024.02.20 20:14
안녕하세요.
여러가지 방법이 있습니다. 그 중 하나로 아래와 같이 수식을 작성해서 해결할 수 있을 듯 합니다.
=SUMPRODUCT(($그룹범위=그룹명)*($값범위>시작값))+SUMPRODUCT(($그룹범위=그룹명)*($값범위=시작값)*($보조범위>보조시작값))+1
스크랩 완료