FILTER 조건별 텍스트 합치기
2021지원 버전 자세히 보기
조건에 맞는 텍스트를 합칩니다. 단일 조건, AND, OR 조건으로 텍스트를 합칠 수 있습니다.
인수 설명
01조건이 하나일 때
=TEXTJOIN ( 구분자, TRUE, FILTER ( 텍스트범위, 조건범위=조건, "" ) )인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
02여러 조건을 동시에 만족할 때 (AND 조건)
=TEXTJOIN ( 구분자, TRUE, FILTER ( 텍스트범위, ( 조건범위1=조건1 )*( 조건범위2=조건2 ), "" ) )인수 설명 자세히 보기
03여러 조건 중 하나라도 만족할 때 (OR 조건)
=TEXTJOIN ( 구분자, TRUE, FILTER ( 텍스트범위, ( 조건범위1=조건1 )+( 조건범위2=조건2 ), "" ) )인수 설명 자세히 보기
동작 원리
01조건이 하나일 때
FILTER 함수는 조건에 맞는 텍스트만 추리고 TEXTJOIN 함수는 반환된 배열을 구분자로 연결합니다.
단일 조건 공식의 예제 시트에서 H2 셀이 사과+포도+딸기를 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
FILTER 함수가 과일 제품만 추립니다
A2:A8에서 과일인 행에 대응하는 C2:C8의 제품만 남겨 세 값의 배열을 반환합니다.
=FILTER ( C2:C8, A2:A8=F3, "" )
= {"사과";"포도";"딸기"}
조건을 만족하는 제품만 남은 배열입니다. TEXTJOIN 함수가 세 제품을 연결합니다
FILTER 함수가 반환한 세 값 사이에 F2 셀의 +를 넣습니다. FILTER 함수의 배열은 TEXTJOIN 함수가 소비하므로 결과가 여러 셀로 펼쳐지지 않습니다.
=TEXTJOIN ( F2, TRUE, FILTER ( C2:C8, A2:A8=F3, "" ) )
= "사과+포도+딸기"
조건을 만족하는 세 제품을 연결한 결과입니다. 02여러 조건을 동시에 만족할 때 (AND 조건)
두 조건 비교 결과를 곱해 모두 참인 행만 FILTER 함수로 추리고 TEXTJOIN 함수가 반환된 텍스트를 연결합니다.
다중 AND 조건 공식의 예제 시트에서 H3 셀이 사과+딸기를 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
두 조건 배열을 곱합니다
분류가 과일인 결과와 지역이 서울인 결과를 곱하면 두 조건을 모두 만족하는 첫째·다섯째 행만 1이 됩니다.
=( A2:A8=F3 )*( B2:B8=F4 )
= {1;0;0;0;1;0;0}
두 조건을 모두 만족하는 행만 1인 배열입니다. FILTER 함수가 두 제품만 추립니다
조건 배열이 1인 행에 대응하는 제품인 사과와 딸기만 반환합니다.
=FILTER ( C2:C8, ( A2:A8=F3 )*( B2:B8=F4 ), "" )
= {"사과";"딸기"}
AND 조건을 만족하는 제품만 남은 배열입니다. TEXTJOIN 함수가 두 제품을 연결합니다
FILTER 함수가 반환한 두 값 사이에 +를 넣어 한 셀에 표시합니다.
=TEXTJOIN ( F2, TRUE, FILTER ( C2:C8, ( A2:A8=F3 )*( B2:B8=F4 ), "" ) )
= "사과+딸기"
두 조건을 모두 만족하는 제품을 연결한 결과입니다. 03여러 조건 중 하나라도 만족할 때 (OR 조건)
두 조건 비교 결과를 더해 하나 이상 참인 행만 FILTER 함수로 추리고 TEXTJOIN 함수가 반환된 텍스트를 연결합니다.
다중 OR 조건 공식의 예제 시트에서 H4 셀이 사과+배추+포도+딸기+콜라를 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
두 조건 배열을 더합니다
분류가 과일인 결과와 지역이 부산인 결과를 더합니다. 두 조건을 모두 만족하는 포도 행은 2가 되며 1과 2는 모두 참으로 처리됩니다.
=( A2:A8=F3 )+( B2:B8=F5 )
= {1;1;0;2;1;0;1}
두 조건 중 하나 이상을 만족하는 행이 1 이상인 배열입니다. FILTER 함수가 다섯 제품만 추립니다
조건 배열이 1 이상인 행에 대응하는 사과·배추·포도·딸기·콜라를 반환합니다.
=FILTER ( C2:C8, ( A2:A8=F3 )+( B2:B8=F5 ), "" )
= {"사과";"배추";"포도";"딸기";"콜라"}
OR 조건을 만족하는 제품만 남은 배열입니다. TEXTJOIN 함수가 다섯 제품을 연결합니다
FILTER 함수가 반환한 다섯 값 사이에 +를 넣어 한 셀에 표시합니다.
=TEXTJOIN ( F2, TRUE, FILTER ( C2:C8, ( A2:A8=F3 )+( B2:B8=F5 ), "" ) )
= "사과+배추+포도+딸기+콜라"
두 조건 중 하나 이상을 만족하는 제품을 연결한 결과입니다. ![[도구 업데이트] 투명 인감 도장 PNG를 만들어보세요!](https://www.oppadu.com/wp-content/uploads/2026/09/투명-도장-생성기-안내.png)
![[직원 채용] 오빠두엑셀이 정규직 동료를 모십니다](https://www.oppadu.com/wp-content/uploads/2026/08/직원-채용-1_R.png)