메뉴
실무 위키›응용 공식›엑셀 누적 합계 구하기 공식

엑셀 누적 합계 구하기 공식

지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

입출금 내역에서 행마다 자동으로 채워지는 잔액을 계산합니다. 계좌가 여러 개일 경우, 계좌별로 나눠 누적하는 방법도 알아봅니다.

예제파일 다운로드
엑셀 누적 합계 구하기 공식 예제 미리보기
예제 미리보기 크게 보기

인수 설명

01행마다 잔액 쌓기

=SUM ( 입금 누적 범위 ) - SUM ( 출금 누적 범위 )
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
입금 누적 범위필수첫 행부터 지금 행까지 늘어나는 입금 범위입니다. $C$2:C2처럼 시작만 절대참조로 묶어야 아래로 채울 때 범위가 한 행씩 넓어집니다.
출금 누적 범위필수같은 방식으로 늘어나는 출금 범위입니다. 입금 누계에서 이 값을 빼면 그 행까지의 잔액이 됩니다.
E2=SUM($C$2:C2)-SUM($D$2:D2)
E3=SUM($C$2:C3)-SUM($D$2:D3)
E4=SUM($C$2:C4)-SUM($D$2:D4)
E5=SUM($C$2:C5)-SUM($D$2:D5)
E6=SUM($C$2:C6)-SUM($D$2:D6)
A
B
C
D
E
F
1
날짜
적요
입금
출금
잔액
2
2026-03-02
3월 급여
3,200,000
3,200,000
3
2026-03-05
카드대금
870,000
2,330,000
4
2026-03-11
관리비
185,000
2,145,000
5
2026-03-17
환급금
64,000
2,209,000
6
2026-03-25
월세
650,000
1,559,000
7
아래로 내려갈수록 범위가 한 행씩 넓어집니다. 범위의 시작을 고정하지 않으면 범위가 통째로 밀려 그 행의 값만 나옵니다.

02계좌별로 나눠서 누적하기

=SUMIFS ( 입금 누적 범위, 계좌 누적 범위, 현재 계좌 ) - SUMIFS ( 출금 누적 범위, 계좌 누적 범위, 현재 계좌 )
인수 설명 자세히 보기
인수구분설명
입금 누적 범위필수첫 행부터 지금 행까지 늘어나는 입금 범위입니다.
출금 누적 범위필수같은 방식으로 늘어나는 출금 범위입니다.
계좌 누적 범위필수입금·출금 범위와 똑같이 늘어나야 하는 계좌 범위입니다. 세 범위의 크기가 다르면 #VALUE! 오류를 출력합니다.
현재 계좌필수지금 행의 계좌입니다. 이 값과 같은 계좌만 골라 누계에 넣습니다.
F3=SUMIFS($D$2:D3,$B$2:B3,B3)-SUMIFS($E$2:E3,$B$2:B3,B3)
F4=SUMIFS($D$2:D4,$B$2:B4,B4)-SUMIFS($E$2:E4,$B$2:B4,B4)
F5=SUMIFS($D$2:D5,$B$2:B5,B5)-SUMIFS($E$2:E5,$B$2:B5,B5)
F6=SUMIFS($D$2:D6,$B$2:B6,B6)-SUMIFS($E$2:E6,$B$2:B6,B6)
F7=SUMIFS($D$2:D7,$B$2:B7,B7)-SUMIFS($E$2:E7,$B$2:B7,B7)
A
B
C
D
E
F
G
1
날짜
계좌
적요
입금
출금
잔액
2
2026-03-02
급여통장
3월 급여
3,200,000
3,200,000
3
2026-03-05
급여통장
관리비
185,000
3,015,000
4
2026-03-08
생활비통장
이체 입금
2,000,000
2,000,000
5
2026-03-12
생활비통장
카드대금
870,000
1,130,000
6
2026-03-17
급여통장
환급금
64,000
3,079,000
7
2026-03-25
생활비통장
월세
650,000
480,000
8
통장이 섞여 있어도 같은 계좌끼리만 누적됩니다. 생활비통장은 4행에서 처음 시작하므로 잔액도 그 행부터 다시 쌓입니다.
이 공식이 사용하는 함수
SUM 함수 SUMIFS 함수

동작 원리

SUM 함수 두 개가 입금과 출금을 각각 그 행까지 더하고, 두 누계의 차이가 그 행의 잔액이 됩니다. 계좌별로 나눌 때도 흐름은 같고 계좌 조건만 더해집니다.

첫 번째 예제 시트에서 마지막 행 잔액을 구하는 E6 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

첫 번째 SUM 함수가 입금을 그 행까지 더합니다

범위가 $C$2:C6이라 2행부터 6행까지의 입금만 더합니다. 시작을 절대참조로 묶어 두었기 때문에 아래로 채워도 시작점은 2행에 그대로 남고 끝만 내려갑니다.

=SUM ( $C$2:C6 ) - SUM ( $D$2:D6 )
= 3,264,000
2

두 번째 SUM 함수가 출금을 같은 구간까지 더합니다

출금도 똑같이 2행부터 6행까지 더합니다. 두 범위의 끝 행이 어긋나면 서로 다른 구간을 빼게 되므로 잔액이 맞지 않습니다.

= 3,264,000 - SUM ( $D$2:D6 )
= 3,264,000 - 1,705,000
3

두 누계의 차이가 그 행의 잔액입니다

입금 누계에서 출금 누계를 빼면 6행까지의 잔액이 나옵니다. 한 행 위인 E5는 범위가 $C$2:C5·$D$2:D5로 한 칸씩 짧아 2,209,000이 됩니다.

= 3,264,000 - 1,705,000
= 1,559,000 계좌별로 나눌 때는 SUMIFS 함수가 같은 계좌인 행만 골라 더할 뿐, 두 누계를 빼는 방식은 그대로입니다.
댓글 0
아직 댓글이 없습니다. 첫 번째 댓글을 작성해보세요!
스크랩 완료