대소문자 구분 검색 공식
지원 버전 자세히 보기
영문 대소문자를 구분해 정확히 일치하는 값을 찾는 검색 공식입니다.
인수 설명
01모든 버전 INDEX·MATCH 기본 공식
{=INDEX ( 출력범위, MATCH ( 1, --EXACT ( 찾을값, 찾을범위 ), 0 ), 0 )}인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
02모든 버전 INDEX·MATCH 다중조건 공식
{=INDEX ( 출력범위, MATCH ( 1, --( EXACT ( 찾을값, 찾을범위 ) * ( 조건범위=조건 ) ), 0 ), 0 )}인수 설명 자세히 보기
03Excel 2021·M365 XLOOKUP 공식
=XLOOKUP ( TRUE, EXACT ( 찾을값, 찾을범위 ), 출력범위 )인수 설명 자세히 보기
동작 원리
01모든 버전 INDEX·MATCH 기본 공식
EXACT 함수가 대소문자까지 비교하고 MATCH 함수가 첫 일치 위치를 찾으면 INDEX 함수가 같은 행의 값을 반환합니다.
INDEX·MATCH 기본 공식의 예제 시트에서 G2 셀이 18000을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
EXACT 함수가 대소문자를 비교합니다
EXACT 함수는 E2의 Apple을 A2:A8과 비교해 대소문자까지 같은 세 위치만 TRUE로 반환합니다.
=EXACT ( E2, A2:A8 )
Apple과 철자가 같은 세 행을 비교합니다. = {FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;TRUE}
세 번째, 네 번째, 일곱 번째 값이 정확히 일치합니다. 이중 음수가 논리값을 숫자로 바꿉니다
이중 음수 기호는 TRUE를 1로, FALSE를 0으로 바꿔 MATCH 함수가 검색할 수 있는 배열을 만듭니다.
=--EXACT ( E2, A2:A8 )
논리 배열을 0과 1로 변환합니다. = {0;0;1;1;0;0;1}
정확히 일치한 행만 1입니다. MATCH 함수가 첫 일치 위치를 찾습니다
MATCH 함수는 숫자 배열에서 첫 번째 1이 있는 세 번째 위치를 반환합니다.
=MATCH ( 1, {0;0;1;1;0;0;1}, 0 )
정확히 일치하는 첫 번째 위치를 찾습니다. = 3
A2:A8에서 세 번째 위치입니다. INDEX 함수가 같은 행의 값을 반환합니다
INDEX 함수는 세로 범위 C2:C8의 세 번째 행을 선택해 단가 18000을 반환합니다.
=INDEX ( C2:C8, 3, 0 )
세로 범위의 세 번째 값을 선택합니다. = 18000
C4 셀의 단가입니다. 02모든 버전 INDEX·MATCH 다중조건 공식
EXACT 함수의 대소문자 비교 결과에 추가 조건을 곱하고 MATCH 함수와 INDEX 함수로 첫 일치 값을 반환합니다.
INDEX·MATCH 다중조건 공식의 예제 시트에서 G2 셀이 21000을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
EXACT 함수가 대소문자를 비교합니다
EXACT 함수는 E2의 Apple을 A2:A8과 비교해 대소문자까지 같은 세 위치만 TRUE로 반환합니다.
=EXACT ( E2, A2:A8 )
Apple과 철자가 같은 세 행을 비교합니다. = {FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;TRUE}
세 번째, 네 번째, 일곱 번째 값이 정확히 일치합니다. 추가 조건이 일치 배열을 좁힙니다
B2:B8에서 오프라인인 행과 EXACT 함수의 결과를 곱하면 두 조건을 모두 만족하는 네 번째와 일곱 번째 위치만 1로 남습니다.
=--( EXACT ( E2, A2:A8 ) * ( B2:B8=F2 ) )
대소문자와 구분 조건을 함께 비교합니다. = {0;0;0;1;0;0;1}
두 조건을 모두 만족한 행만 1입니다. MATCH 함수가 첫 일치 위치를 찾습니다
MATCH 함수는 두 조건을 모두 만족하는 첫 번째 1이 있는 네 번째 위치를 반환합니다.
=MATCH ( 1, {0;0;0;1;0;0;1}, 0 )
두 조건을 만족하는 첫 번째 위치를 찾습니다. = 4
A2:A8에서 네 번째 위치입니다. INDEX 함수가 같은 행의 값을 반환합니다
INDEX 함수는 세로 범위 C2:C8의 네 번째 행을 선택해 단가 21000을 반환합니다.
=INDEX ( C2:C8, 4, 0 )
세로 범위의 네 번째 값을 선택합니다. = 21000
C5 셀의 단가입니다. 03Excel 2021·M365 XLOOKUP 공식
EXACT 함수가 대소문자 일치 여부를 반환하면 XLOOKUP 함수가 첫 TRUE와 같은 행의 값을 찾습니다.
XLOOKUP 공식의 예제 시트에서 G2 셀이 18000을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
EXACT 함수가 대소문자를 비교합니다
EXACT 함수는 E2의 Apple을 A2:A8과 비교해 대소문자까지 같은 세 위치만 TRUE로 반환합니다.
=EXACT ( E2, A2:A8 )
Apple과 철자가 같은 세 행을 비교합니다. = {FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;TRUE}
세 번째, 네 번째, 일곱 번째 값이 정확히 일치합니다. XLOOKUP 함수가 첫 TRUE의 값을 반환합니다
XLOOKUP 함수는 논리 배열에서 첫 TRUE를 찾아 C2:C8의 같은 위치에 있는 단가를 반환합니다.
=XLOOKUP ( TRUE, {FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;TRUE}, C2:C8 )
첫 TRUE인 세 번째 위치를 찾습니다. = 18000
C4 셀의 단가입니다. 
VBA는 기본값으로 대소문자를 구분하여 비교합니다.
와 같이 사용해보세요 ^^