메뉴
실무 위키›응용 공식›주번호 날짜 범위 변환 공식

주번호 날짜 범위 변환 공식

2010
지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

연도와 주번호로 해당 주의 시작일과 종료일을 구하는 공식입니다. WEEKDAY 함수의 기준요일을 바꿔 한 주의 시작 요일을 지정할 수 있습니다.

예제파일 다운로드
주번호 날짜 범위 변환 공식 예제 미리보기
예제 미리보기 크게 보기

인수 설명

=MAX ( DATE ( 연도, 1, 1 ), DATE ( 연도, 1, 1 ) - WEEKDAY ( DATE ( 연도, 1, 1 ), 기준요일 ) + ( 주번호 - 1 ) * 7 + 1 )
=MIN ( DATE ( 연도 + 1, 1, 0 ), DATE ( 연도, 1, 1 ) - WEEKDAY ( DATE ( 연도, 1, 1 ), 기준요일 ) + 주번호 * 7 )
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
연도필수날짜 범위를 계산할 기준 연도입니다.
주번호필수기준 연도의 1월 1일을 포함한 기간을 1주차로 두고 계산할 주번호입니다. 이 공식은 ISO 주차가 아니라 시스템 1 방식입니다.
기준요일필수한 주의 시작 요일을 정하는 WEEKDAY 함수의 반환 형식입니다. 11은 월~일, 12는 화~월, 13은 수~화, 14는 목~수, 15는 금~목, 16은 토~금, 17은 일~토입니다. 11~17은 엑셀 2010부터 사용할 수 있습니다.
D2=MAX(DATE(A2,1,1),DATE(A2,1,1)-WEEKDAY(DATE(A2,1,1),C2)+(B2-1)*7+1)
E2=MIN(DATE(A2+1,1,0),DATE(A2,1,1)-WEEKDAY(DATE(A2,1,1),C2)+B2*7)
A
B
C
D
E
F
1
연도
주번호
기준요일
시작일
종료일
2
2026
1
11
2026-01-01
2026-01-04
3
2026
2
11
2026-01-05
2026-01-11
4
2026
53
11
2026-12-28
2026-12-31
5
2026
1
16
2026-01-01
2026-01-02
6
2026
2
16
2026-01-03
2026-01-09
7
2026
1
17
2026-01-01
2026-01-03
8
2026
2
17
2026-01-04
2026-01-10
9
2026년 1주차를 월~일 기준으로 계산하면 시작 후보 2025-12-29는 연도 시작일로 제한됩니다. 종료일은 2026-01-04이므로 D2:E2는 2026-01-01~2026-01-04를 반환합니다.
이 공식이 사용하는 함수
MAX 함수 DATE 함수 WEEKDAY 함수 MIN 함수

동작 원리

DATE 함수는 연도 경계를, WEEKDAY 함수는 1월 1일의 요일 번호를 계산합니다. MAX 함수는 시작일을, MIN 함수는 종료일을 기준 연도 안으로 제한합니다.

주차 시작일과 종료일 계산 예제 시트에서 D2:E2가 2026-01-01~2026-01-04를 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

DATE 함수가 연도 시작일을 만듭니다

DATE 함수는 A2의 연도 2026과 월·일 1을 결합해 2026-01-01을 반환합니다.

=DATE ( A2, 1, 1 )
= 2026-01-01 기준 연도의 시작일입니다.
2

WEEKDAY 함수가 요일 번호를 계산합니다

WEEKDAY 함수는 2026-01-01을 월요일부터 시작하는 반환 형식 11로 계산해 네 번째 요일인 4를 반환합니다.

=WEEKDAY ( DATE ( A2, 1, 1 ), C2 )
= 4 2026-01-01은 월~일 기준 네 번째 요일인 목요일입니다.
3

MAX 함수가 시작일을 연도 안으로 제한합니다

월요일 시작 기준으로 2026년 1주차의 계산상 시작일은 2025-12-29입니다. MAX 함수는 이 값과 2026-01-01 중 늦은 날짜를 선택해 시작일이 이전 연도로 넘어가지 않도록 합니다.

=MAX ( DATE ( A2, 1, 1 ), DATE ( A2, 1, 1 ) - WEEKDAY ( DATE ( A2, 1, 1 ), C2 ) + ( B2 - 1 ) * 7 + 1 )
= 2026-01-01 기준 연도 안으로 제한한 1주차 시작일입니다.
4

MIN 함수가 종료일을 연도 안으로 제한합니다

2026년 1주차의 계산상 종료일은 2026-01-04입니다. MIN 함수는 이 값과 DATE(A2+1,1,0)이 반환한 2026-12-31 중 이른 날짜를 선택해 종료일이 다음 연도로 넘어가지 않도록 합니다.

=MIN ( DATE ( A2 + 1, 1, 0 ), DATE ( A2, 1, 1 ) - WEEKDAY ( DATE ( A2, 1, 1 ), C2 ) + B2 * 7 )
= 2026-01-04 기준 연도 안으로 제한한 1주차 종료일입니다.
댓글 4
5 (4개 평가)
오진짱
오진짱 2022.01.16 18:23
감사합니다
미니오빠
미니오빠 2022.01.25 13:08
오... 이거 멋집니다. 잘 사용하겠습니다.
강민준🤗
강민준🤗 2024.08.11 20:05
좋은 강의 감사합니다🙇‍♂️
__
__ 2024.08.12 20:55
감사합니다!
스크랩 완료