엑셀 SUMIFS 함수의 조건에 연산자와 와일드카드 쓰는 공식
지원 버전 자세히 보기
비교 연산자와 와일드카드를 조건 셀에 연결해 기간, 포함, 제외 기준별 금액을 합산합니다.
인수 설명
01시작일과 종료일로 기간 자르기
=SUMIFS ( 합계 범위, 날짜 범위, ">=" & 시작일, 날짜 범위, "<=" & 종료일 )인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
02일부 글자가 들어간 품목만 더하기
=SUMIFS ( 합계 범위, 품목 범위, "*" & 키워드 & "*" )인수 설명 자세히 보기
03특정 구분값을 빼고 더하기
=SUMIFS ( 합계 범위, 구분 범위, "<>" & 제외값 )인수 설명 자세히 보기
동작 원리
01시작일과 종료일로 기간 자르기
첫 조건이 시작일 이전을 걷어내고, 두 번째 조건이 종료일 이후를 걷어내어 그 사이 금액만 SUMIFS 함수가 더합니다.
예제 시트에서 기간 합계를 구하는 G4 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
시작일 이상인 금액만 먼저 남깁니다
큰따옴표 안의 >=와 G2를 &로 이어 >=2026-08-03 조건을 만듭니다. 이 날짜부터 마지막 날짜까지 일곱 건의 금액은 830,000원입니다.
=SUMIFS ( $D$2:$D$10, $A$2:$A$10, ">=" & G2 )
= 830,000
종료일 이하 조건으로 뒤쪽 날짜를 자릅니다
큰따옴표 안의 <=와 G3를 &로 이어 <=2026-08-07 조건을 추가합니다. 8월 8일과 9일의 금액이 빠지면서 결과는 650,000원이 됩니다.
=SUMIFS ( $D$2:$D$10, $A$2:$A$10, ">=" & G2, $A$2:$A$10, "<=" & G3 )
= 650,000
02일부 글자가 들어간 품목만 더하기
별표 와일드카드를 키워드 양쪽에 붙여 품목명 일부만 대조하고, 조건에 맞는 금액을 SUMIFS 함수가 더합니다.
예제 시트에서 키워드 포함 합계를 구하는 I3 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
별표와 키워드를 조건 문자열로 잇습니다
별표는 글자가 없거나 여러 글자가 오는 경우를 모두 허용합니다. 키워드 셀 I2의 앞뒤에 별표를 &로 이어 품목명 중간에서도 찾을 수 있는 조건을 만듭니다.
="*" & I2 & "*"
= *모니터*
조건 문자열이 들어간 품목의 금액을 더합니다
모니터암, 모니터 받침대, 모니터 케이블, 모니터가 조건을 만족합니다. 다섯 행의 금액을 더한 결과는 670,000원입니다.
=SUMIFS ( $D$2:$D$10, $B$2:$B$10, "*" & I2 & "*" )
= 670,000
03특정 구분값을 빼고 더하기
같지 않다는 뜻의 연산자를 제외값 앞에 붙여 조건을 만들고, 그 조건을 만족하는 금액만 SUMIFS 함수가 더합니다.
예제 시트에서 반품을 뺀 합계를 구하는 K3 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
같지 않음 연산자와 제외값을 잇습니다
는 같지 않다는 뜻입니다. 큰따옴표로 묶은 연산자와 제외값 셀 K2를 &로 이어 반품이 아닌 행을 찾는 조건을 만듭니다.
="<>" & K2
= <>반품
반품이 아닌 행의 금액을 더합니다
구분이 판매인 일곱 행만 조건을 만족합니다. 30,000원과 50,000원인 반품 두 건을 뺀 결과는 950,000원입니다.
=SUMIFS ( $D$2:$D$10, $C$2:$C$10, "<>" & K2 )
= 950,000
![[도구 업데이트] 실시간 추첨, 무료 도구 업데이트!](https://www.oppadu.com/wp-content/uploads/2026/09/마블레이스-런칭.png)
![[도구 업데이트] 투명 인감 도장 PNG를 만들어보세요!](https://www.oppadu.com/wp-content/uploads/2026/09/투명-도장-생성기-안내.png)