엑셀 소득세 산출세액 계산 공식
지원 버전 자세히 보기
과세표준에 세율과 누진공제를 적용해 산출세액을 계산하는 공식입니다.
인수 설명
01VLOOKUP 유사일치 공식
=과세표준 * VLOOKUP ( 과세표준, 세율표, 2, TRUE ) - VLOOKUP ( 과세표준, 세율표, 3, TRUE )인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
022021 이후 XLOOKUP 공식
=과세표준 * XLOOKUP ( 과세표준, 구간하한, 세율, , -1 ) - XLOOKUP ( 과세표준, 구간하한, 누진공제, , -1 )인수 설명 자세히 보기
동작 원리
01VLOOKUP 유사일치 공식
VLOOKUP 함수는 과세표준 이하의 가장 큰 구간에서 세율과 누진공제를 찾고, 두 값을 적용해 세액공제 전 산출세액을 계산합니다.
VLOOKUP 유사일치 공식의 예제 시트에서 E2 셀이 4,170,000원을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
VLOOKUP 함수가 적용 세율을 찾습니다
F2 셀의 35,000,000원보다 작거나 같은 가장 큰 하한은 12,000,000원입니다. VLOOKUP 함수는 해당 행의 두 번째 값인 15%를 반환합니다.
=VLOOKUP ( F2, A2:C9, 2, TRUE )
= 15%
12,000,000원 구간의 세율입니다. VLOOKUP 함수가 누진공제를 찾습니다
같은 구간의 세 번째 값에서 누진공제 1,080,000원을 반환합니다.
=VLOOKUP ( F2, A2:C9, 3, TRUE )
= 1,080,000
12,000,000원 구간의 누진공제입니다. 세율을 곱한 뒤 누진공제를 뺍니다
35,000,000원에 15%를 곱한 5,250,000원에서 누진공제 1,080,000원을 빼면 세액공제 전 산출세액은 4,170,000원입니다.
=F2 * VLOOKUP ( F2, A2:C9, 2, TRUE ) - VLOOKUP ( F2, A2:C9, 3, TRUE )
= 4,170,000
세액공제 전 산출세액입니다. 022021 이후 XLOOKUP 공식
XLOOKUP 함수는 일치 모드 -1로 과세표준 이하의 가장 가까운 구간에서 세율과 누진공제를 찾아 산출세액을 계산합니다.
2021 이후 XLOOKUP 공식의 예제 시트에서 E2 셀이 4,170,000원을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
XLOOKUP 함수가 적용 세율을 찾습니다
일치 모드 -1은 정확히 일치하는 값이 없을 때 다음으로 작은 값을 찾습니다. 35,000,000원보다 작은 12,000,000원 구간에서 세율 15%를 반환합니다.
=XLOOKUP ( F2, A2:A9, B2:B9, , -1 )
= 15%
12,000,000원 구간의 세율입니다. XLOOKUP 함수가 누진공제를 찾습니다
같은 구간의 누진공제 범위에서 1,080,000원을 반환합니다.
=XLOOKUP ( F2, A2:A9, C2:C9, , -1 )
= 1,080,000
12,000,000원 구간의 누진공제입니다. 세율을 곱한 뒤 누진공제를 뺍니다
35,000,000원에 15%를 곱한 5,250,000원에서 누진공제 1,080,000원을 빼면 세액공제 전 산출세액은 4,170,000원입니다.
=F2 * XLOOKUP ( F2, A2:A9, B2:B9, , -1 ) - XLOOKUP ( F2, A2:A9, C2:C9, , -1 )
= 4,170,000
세액공제 전 산출세액입니다. 
누진공제로 이상(초과)된 금액 이전 세금이 공제된 금액이 최종 산출세액으로 계산되기 때문에 차이는 없습니다.^^
감사합니다.
과표 4,600만원은 소득세율 24%, 누진공제 5,220,000원이 아닙니다.
4,600만원을 초과할 때 해당 구간이 적용됩니다.
즉, 4,600만원은 소득세율 15%와 누진공제 1,080,000원이 적용되는게 맞습니다.
그래서 저는 소득세 구할 때 과세표준에 0.1을 더해서 해당 수식을 적용합니다.
혹시, 더 좋은 방법이 있을까 싶어서 댓글을 남겼었습니다.
(세무사에게 검증 받은 내용입니다만, 틀린 부분있으면 말씀해주세요.)
네 말씀하신 내용이 맞습니다. 하지만 세액이 계산되는 절차는 달라도, 결국 산출되는 세액은 동일하기 때문에 문제가 되진 않습니다.
다시 한번 확인해보시겠어요? :)
감사합니다.
다만, 제가 근무하는 곳에서는 경우에 따라 꼭 세액만 구하는 것은 아니라서..
과표가 얼마면 세율이 얼마야? 라는 질문에는 틀린 답이 나옵니다.
INDEX, MAX, IF 배열로 답은 구할 수 있는데,
혹시 좀 더 간략한 방법은 없을까요?
끈질기게 질문드려 죄송합니다 ㅠㅠ
VLOOKUP 함수의 유사일치는 '이상' 조건으로 검색하기 때문에, 말씀하신 상황은 VLOOKUP 함수만으로는 구현할 수 없습니다.
다른 공식을 사용해서 구하거나, 보조열을 추가(0.1을 더한)한 후, 보조열 기준으로 VLOOKUP 함수를 사용하시면 될 듯 합니다.
감사합니다.
제가 만든건 그림으로 첨부하겠습니다.
왼쪽 박스는 여쭤보신 부분에 대한 것이고,
오른쪽 박스는 좀 더 나아가 과세연도, 1주택자인지 다주택자인지 등 요건에 따라 적용해야 하는 세율표가 다른 경우 함수로 만들어 본 것입니다.
오른쪽 박스가 제가 각종 세액을 구할 때 사용하는 실무함수입니다.