월 주차 구하기 (기본·이월·분리)
지원 버전 자세히 보기
세 가지 기준으로 날짜의 월 주차를 계산하는 공식입니다.
인수 설명
01월 1일 분리 기본형
=WEEKNUM ( 날짜, 기준 )-WEEKNUM ( EOMONTH ( 날짜, -1 )+1, 기준 )+1인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
동작 원리
EOMONTH 함수로 해당 월의 1일을 구하고 두 WEEKNUM 함수의 연간 주차 차이로 월 주차를 계산합니다.
월 1일 분리 기본형의 예제 시트에서 C2 셀이 4를 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
해당 월의 1일을 구합니다
EOMONTH 함수로 이전 달의 마지막 날을 구한 뒤 1을 더해 2025년 12월 1일을 반환합니다.
=EOMONTH ( A2, -1 )+1
= 2025-12-01
2025년 12월의 첫날입니다. 대상 날짜의 연간 주차를 구합니다
WEEKNUM 함수는 월요일 시작 기준에서 2025년 12월 28일을 그해 52번째 주로 계산합니다.
=WEEKNUM ( A2, B2 )
= 52
대상 날짜의 연간 주차입니다. 월 첫날의 연간 주차를 구합니다
같은 기준으로 2025년 12월 1일의 연간 주차를 계산하면 49를 반환합니다.
=WEEKNUM ( EOMONTH ( A2, -1 )+1, B2 )
= 49
해당 월 첫날의 연간 주차입니다. 두 주차의 차이로 월 주차를 계산합니다
대상 날짜의 연간 주차 52에서 월 첫날의 연간 주차 49를 빼고 1을 더해 넷째 주를 반환합니다.
=52-49+1
= 4
2025년 12월의 넷째 주입니다. 02특정 요일 기준 이월형
=WEEKNUM ( DATE ( YEAR ( 날짜 ), 1, DAY ( 날짜-WEEKDAY ( 날짜, 기준 )+1 ) ), WEEKDAY ( DATE ( YEAR ( 날짜 ), 1, 1 ), 11 )+10 )인수 설명 자세히 보기
동작 원리
WEEKDAY 함수로 날짜가 속한 주의 시작일을 찾고, DATE 함수로 만든 1월의 대응 날짜를 WEEKNUM 함수가 월 주차로 바꿉니다.
특정 요일 기준 이월형의 예제 시트에서 D5 셀이 5를 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
주 시작일을 1월의 날짜로 바꿉니다
2026년 1월 1일이 속한 주는 2025년 12월 29일에 시작합니다. DAY 함수가 29를 반환하고 DATE 함수는 이를 2026년 1월 29일로 바꿉니다.
=DATE ( YEAR ( A5 ), 1, DAY ( A5-WEEKDAY ( A5, B5 )+1 ) )
= 2026-01-29
주 시작일의 일 번호 29를 1월에 대입한 날짜입니다. 해당 연도의 주 시작 기준을 맞춥니다
2026년 1월 1일은 목요일이므로 WEEKDAY 함수가 4를 반환하고 10을 더한 14가 WEEKNUM 함수의 목요일 시작 기준이 됩니다.
=WEEKDAY ( DATE ( YEAR ( A5 ), 1, 1 ), 11 )+10
= 14
목요일 시작을 뜻하는 WEEKNUM 함수의 기준값입니다. 대응 날짜의 주차를 계산합니다
목요일 시작 기준에서 2026년 1월 29일은 다섯째 주이므로 원래 날짜를 이전 달의 다섯째 주로 계산합니다.
=WEEKNUM ( DATE ( YEAR ( A5 ), 1, DAY ( A5-WEEKDAY ( A5, B5 )+1 ) ), 14 )
= 5
월요일 시작 주를 이전 달에 이월한 월 주차입니다. 03매월 1일 포함 주 이월형
=IF ( OR ( WEEKNUM ( DATE ( YEAR ( 날짜 ), MONTH ( 날짜 ), DAY ( 날짜-WEEKDAY ( 날짜, 기준 )+1 ) )+7 )<;WEEKNUM ( DATE ( YEAR ( 날짜 ), MONTH ( 날짜 ), DAY ( 날짜-WEEKDAY ( 날짜, 기준 )+1 ) ) ), WEEKNUM ( 날짜, 기준 )=WEEKNUM ( EOMONTH ( 날짜, 0 )+1, 기준 ) ), 1, WEEKNUM ( 날짜, 기준 )-WEEKNUM ( EOMONTH ( 날짜, -1 )+1, 기준 )+1 )인수 설명 자세히 보기
동작 원리
OR 함수가 다음 달 또는 다음 해로 넘어가는 주를 판정하고 IF 함수가 해당 주를 새 달의 첫째 주로 바꿉니다.
매월 1일 포함 주 이월형의 예제 시트에서 E3 셀이 1을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
날짜가 속한 주의 시작일을 구합니다
월요일 시작 기준에서 2025년 12월 29일이 속한 주의 시작일은 같은 날입니다. DATE 함수가 월말·연말 판정에 사용할 날짜로 다시 만듭니다.
=DATE ( YEAR ( A3 ), MONTH ( A3 ), DAY ( A3-WEEKDAY ( A3, B3 )+1 ) )
= 2025-12-29
A3 셀이 속한 주의 월요일입니다. 주차가 연말에 초기화되는지 판정합니다
2025년 12월 29일의 연간 주차는 53이고 7일 뒤인 2026년 1월 5일은 2입니다. 다음 주차가 더 작으므로 OR 함수가 TRUE를 반환합니다.
=OR ( WEEKNUM ( DATE ( YEAR ( A3 ), MONTH ( A3 ), DAY ( A3-WEEKDAY ( A3, B3 )+1 ) )+7 )<WEEKNUM ( DATE ( YEAR ( A3 ), MONTH ( A3 ), DAY ( A3-WEEKDAY ( A3, B3 )+1 ) ) ), WEEKNUM ( A3, B3 )=WEEKNUM ( EOMONTH ( A3, 0 )+1, B3 ) )
= TRUE
주가 다음 해로 넘어간다는 판정값입니다. 새 달의 첫째 주를 반환합니다
OR 함수의 판정이 TRUE이므로 IF 함수가 기본형의 5 대신 새 달의 첫째 주를 뜻하는 1을 반환합니다.
=IF ( OR ( TRUE, FALSE ), 1, 5 )
= 1
다음 달에 포함되는 첫째 주입니다. 
="2020-02-09"+1
="2020-03-01"
EOMONTH 오타욤
ㅜㅜ 하나하나 꼼꼼히 신경써주시고 감사드립니다.
앞으로는 더욱 신경써서 포스트 작성하도록 하겠습니다..ㅜ-ㅜ
본 공식은 주차(숫자)를 반환합니다.
<자주묻는질문1. 전달 마지막 주를 이번달 첫째주로 이월해서 계산하고 싶습니다.>=IF(WEEKNUM(날짜,계산방식)=WEEKNUM(EOMONTH(날짜,0),계산방식),1,WEEKNUM(날짜,계산방식)-WEEKNUM(EOMONTH(날짜,-1)+1,계산방식)+1)
예제파일을 다운받으시면 이월공식이 사용된 예제를 확인하실 수 있습니다. :)
ex) '20년 44주차
-- 일요일: 10/25일
-- 월요일: 10/26일
특정주차를 날짜로 변환하려면 아래 공식을 사용해보세요
특정 주차의 시작 요일을 반환합니다.
특정주차의 특정요일을 날짜로 환산하는 방법은 어떻게 구해야 하나요? 바로 위의 엑셀공식을 제머리로 이해하기가 어렵네요 ㅠㅠ
두번째 공식을 써서 2021-02-01 을(1월) 5째주로 계산 했습니다.(returetype: 15)
이 때 2021-02-01 "월"과 "주"를 기준값으로 사용하고 싶습니다.
그냥 월을 구하면 2월이 구해지니까 2021-02-01을 "1월"로 계산해서 사용하고 싶습니다.
=DATE(YEAR(날짜),MONTH(1),DAY(1))+(날짜-1)*7
항상 감사합니다.
이거더라구요.
MONTH(DATE(YEAR(날짜),1,1)+(WEEKNUM(날짜,기준)-1)*7)
저는 공식 2번 사용했습니다.
공식3) 매월 1일 기준 월 주차 계산
에 따른 월 구하는 방법을 알수 있을까요?
공식3) 매월 1일 기준 월 주차 계산
에 따른 월 구하는 방법을 알수 있을까요?