메뉴
실무 위키›응용 공식›엑셀 중복 데이터 찾기 공식

엑셀 중복 데이터 찾기 공식

지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

명단에서 두 번 이상 중복된 값을 찾아 표시합니다. 이름만으로는 구분되지 않을 경우, 여러 조건을 함께 보는 방법도 알아봅니다.

인수 설명

01명단에서 중복된 이름 찾기

=IF ( COUNTIF ( 확인 범위, 확인할 값 ) > 1, 중복 표시, 그 외 표시 )
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
확인 범위필수중복을 셀 전체 범위입니다. 아래로 채워도 범위가 밀리지 않도록 $A$2:$A$6처럼 절대참조로 고정합니다.
확인할 값필수지금 행에서 중복인지 확인할 값입니다.
중복 표시필수두 번 이상 나왔을 때 표시할 값입니다. 텍스트는 큰따옴표로 묶어 입력합니다.
그 외 표시필수한 번만 나왔을 때 표시할 값입니다. 빈칸으로 두려면 ""를 입력합니다.
D2=IF(COUNTIF($A$2:$A$6,A2)>1,"중복","신규")
A
B
C
D
E
1
이름
휴대폰
가입일
중복 여부
2
김서준
010-2431-8890
2026-02-03
중복
3
이하은
010-7712-3045
2026-02-05
중복
4
김서준
010-5580-1177
2026-02-11
중복
5
박도윤
010-3391-6620
2026-02-14
신규
6
이하은
010-7712-3045
2026-02-19
중복
7
먼저 들어온 행까지 함께 중복으로 표시됩니다. 나중에 들어온 것만 잡으려면 확인 범위의 끝을 지금 행으로 두어 $A$2:A2처럼 적습니다.

02동명이인이 있을 경우, 이름과 연락처로 중복값 찾기

=IF ( COUNTIFS ( 확인 범위 1, 확인할 값 1, 확인 범위 2, 확인할 값 2 ) > 1, 중복 표시, 그 외 표시 )
인수 설명 자세히 보기
인수구분설명
확인 범위 1필수첫 번째로 대조할 범위입니다.
확인할 값 1필수지금 행의 이름입니다.
확인 범위 2필수두 번째로 대조할 범위입니다. 첫 번째 범위와 크기가 같아야 합니다.
확인할 값 2필수지금 행의 휴대폰 번호입니다. 두 조건을 모두 만족하는 행만 개수에 들어갑니다.
중복 표시필수두 값이 모두 같은 행이 두 개 이상일 때 표시할 값입니다.
그 외 표시필수그 밖의 경우에 표시할 값입니다.
D2=IF(COUNTIFS($A$2:$A$6,A2,$B$2:$B$6,B2)>1,"중복","신규")
A
B
C
D
E
1
이름
휴대폰
가입일
중복 여부
2
김서준
010-2431-8890
2026-02-03
신규
3
이하은
010-7712-3045
2026-02-05
중복
4
김서준
010-5580-1177
2026-02-11
신규
5
박도윤
010-3391-6620
2026-02-14
신규
6
이하은
010-7712-3045
2026-02-19
중복
7
동명이인인 김서준 두 사람은 휴대폰이 달라 각각 신규로 남고, 이름과 휴대폰이 모두 같은 이하은만 중복으로 잡힙니다.
이 공식이 사용하는 함수
COUNTIF 함수 COUNTIFS 함수 IF 함수

동작 원리

01명단에서 중복된 이름 찾기

COUNTIF 함수가 그 값이 몇 번 나오는지 세고, IF 함수가 그 개수를 조건으로 표시할 값을 고릅니다.

예제 시트에서 김서준을 확인하는 D2 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

COUNTIF 함수가 같은 값의 개수를 셉니다

확인 범위 전체에서 김서준이 몇 번 나오는지 셉니다. 2행과 4행 두 곳에 있으므로 2를 반환합니다.

=IF ( COUNTIF ( $A$2:$A$6, A2 ) > 1, "중복", "신규" )
=IF ( 2 > 1, "중복", "신규" )
2

IF 함수가 개수를 조건으로 값을 고릅니다

개수가 1보다 크면 두 번 이상 나왔다는 뜻입니다. 조건이 참이므로 앞의 값을 표시합니다.

=IF ( 2 > 1, "중복", "신규" )
= 중복
댓글 0
아직 댓글이 없습니다. 첫 번째 댓글을 작성해보세요!
스크랩 완료