메뉴
실무 위키›응용 공식›엑셀 빈칸에 위 셀 값 채우기 공식

엑셀 빈칸에 위 셀 값 채우기 공식

지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀

병합을 풀고 남은 빈칸에 바로 위의 부서명을 자동으로 채웁니다.

예제파일 다운로드
엑셀 빈칸에 위 셀 값 채우기 공식 예제 미리보기
예제 미리보기 크게 보기

인수 설명

=IF ( 원본 셀 <> "", 원본 셀, LOOKUP ( 2, 1 / ( 누적 범위 <> "" ), 누적 범위 ) )
인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
원본 셀필수현재 행에서 원본 값이 있거나 비어 있는 셀입니다.
누적 범위필수첫 값부터 현재 행까지 이어지는 범위입니다. 수식을 아래로 복사하면 끝행만 한 줄씩 늘어납니다.
B3=IF(A3<>"",A3,LOOKUP(2,1/($A$2:A3<>""),$A$2:A3))
B4=IF(A4<>"",A4,LOOKUP(2,1/($A$2:A4<>""),$A$2:A4))
B5=IF(A5<>"",A5,LOOKUP(2,1/($A$2:A5<>""),$A$2:A5))
B6=IF(A6<>"",A6,LOOKUP(2,1/($A$2:A6<>""),$A$2:A6))
B7=IF(A7<>"",A7,LOOKUP(2,1/($A$2:A7<>""),$A$2:A7))
B8=IF(A8<>"",A8,LOOKUP(2,1/($A$2:A8<>""),$A$2:A8))
A
B
C
1
부서(원본)
빈칸 채우기
2
영업팀
영업팀
3
영업팀
4
영업팀
5
개발팀
개발팀
6
개발팀
7
기획팀
기획팀
8
기획팀
9
원본의 첫 행에는 값이 있어야 합니다. 새 부서명이 나오면 그 아래 빈칸은 다시 다음 부서명이 나올 때까지 같은 값으로 이어집니다.
이 공식이 사용하는 함수
IF 함수 LOOKUP 함수

동작 원리

IF 함수가 원본 값이 있는 행은 그대로 두고, 빈 행에서는 LOOKUP 함수가 마지막으로 입력된 값을 찾습니다.

예제 시트에서 첫 빈칸을 채우는 B3 셀의 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.

1

현재 행이 비어 있는지 확인합니다

A3 셀은 비어 있으므로 비교 결과가 FALSE가 되고 LOOKUP 함수가 있는 뒤쪽 계산으로 넘어갑니다.

=A3 <> ""
= FALSE
2

값이 있는 위치만 숫자로 남깁니다

빈칸이 아닌 셀은 TRUE이므로 1이 되고, 빈칸은 0으로 나누는 오류가 됩니다. LOOKUP 함수는 이 오류를 건너뜁니다.

=1 / ( $A$2:A3 <> "" )
= 1, #DIV/0!
3

마지막 숫자 위치의 부서명을 가져옵니다

LOOKUP 함수가 2보다 작거나 같은 마지막 숫자 1을 찾습니다. 그 위치에 대응하는 A2 셀의 영업팀을 반환합니다.

=LOOKUP ( 2, 1 / ( $A$2:A3 <> "" ), $A$2:A3 )
= 영업팀
댓글 0
아직 댓글이 없습니다. 첫 번째 댓글을 작성해보세요!
스크랩 완료