엑셀 한 셀 여러 줄 나누기 공식
지원 버전 자세히 보기
엑셀 2013 이전엑셀 2016엑셀 2019엑셀 2021엑셀 2024M365웹 엑셀
셀 안에서 줄바꿈으로 나뉘어 입력된 텍스트를 줄 단위로 나누어 출력하는 공식입니다. TEXTSPLIT 함수 또는 LEFT·MID·RIGHT 함수로 나눌 수 있습니다.
인수 설명
01TEXTSPLIT 함수 공식 (엑셀 2024 이후)
=TEXTSPLIT ( 셀,, CHAR ( 10 ) )인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
인수구분설명
셀필수여러 줄로 입력된 텍스트가 있는 셀입니다. 예제 시트에서는 B2:B8의 값을 CHAR 함수의 줄바꿈 문자로 연결해 셀 안 줄바꿈을 재현합니다.
A
B
C
D
E
1
줄 번호
줄 내용
TEXTSPLIT 결과
2
1
안녕하세요
안녕하세요
3
2
오빠두입니다
4
3
세번째줄
5
4
네번째줄
6
5
다섯번째줄
7
6
여섯번째줄
8
7
마지막줄
9
수식을 입력한 셀자동으로 채워진 범위
02LEFT + MID + RIGHT 공식 (모든 버전)
=LEFT ( 셀, FIND ( CHAR ( 10 ), 셀 ) - 1 )
=MID ( 셀, FIND ( "|", SUBSTITUTE ( 셀, CHAR ( 10 ), "|", 줄번호-1 ) ) + 1, FIND ( "|", SUBSTITUTE ( 셀, CHAR ( 10 ), "|", 줄번호 ) ) - FIND ( "|", SUBSTITUTE ( 셀, CHAR ( 10 ), "|", 줄번호-1 ) ) - 1 )
=RIGHT ( 셀, LEN ( 셀 ) - FIND ( "|", SUBSTITUTE ( 셀, CHAR ( 10 ), "|", 줄번호-1 ) ) )
인수 설명 자세히 보기
인수구분설명
셀필수여러 줄로 입력된 텍스트가 있는 셀입니다. 중간·마지막 줄 공식은 줄바꿈을 |로 바꾸므로 원문에 |가 있으면 #이나 ^처럼 원문에 없는 문자로 바꿔 사용합니다. 예제 시트에서는 B2:B8의 값을 CHAR 함수의 줄바꿈 문자로 연결해 셀 안 줄바꿈을 재현합니다.
줄번호필수출력할 줄 번호입니다. 중간 줄은 2부터 전체 줄 수보다 1 작은 값까지, 마지막 줄은 전체 줄 수를 입력합니다.
A
B
C
D
E
F
G
H
I
1
줄 번호
줄 내용
선택 줄
전체 줄
첫 줄
선택 줄 결과
마지막 줄
2
1
안녕하세요
3
7
안녕하세요
세번째줄
마지막줄
3
2
오빠두입니다
4
3
세번째줄
5
4
네번째줄
6
5
다섯번째줄
7
6
여섯번째줄
8
7
마지막줄
9
이 공식이 사용하는 함수
동작 원리
01TEXTSPLIT 함수 공식 (엑셀 2024 이후)
CHAR 함수는 여러 문장을 줄바꿈으로 연결하고 TEXTSPLIT 함수는 각 줄을 세로 배열로 나눕니다.
엑셀 2024 · M365 TEXTSPLIT 공식의 예제 시트에서 D2:D8에 스필되는 일곱 값을 추적합니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
1
CHAR 함수가 일곱 문장을 연결합니다
CHAR 함수가 문자 코드 10의 줄바꿈을 만들고 B2:B8의 문장 사이에 넣습니다.
=B2&CHAR ( 10 )&B3&CHAR ( 10 )&B4&CHAR ( 10 )&B5&CHAR ( 10 )&B6&CHAR ( 10 )&B7&CHAR ( 10 )&B8
= "안녕하세요↵오빠두입니다↵세번째줄↵네번째줄↵다섯번째줄↵여섯번째줄↵마지막줄"
↵는 셀 안 줄바꿈 문자입니다. 2
TEXTSPLIT 함수가 일곱 줄을 나눕니다
TEXTSPLIT 함수는 CHAR 함수의 줄바꿈 문자를 행 구분자로 사용해 일곱 값을 D2:D8에 세로로 스필합니다.
=TEXTSPLIT ( B2&CHAR ( 10 )&B3&CHAR ( 10 )&B4&CHAR ( 10 )&B5&CHAR ( 10 )&B6&CHAR ( 10 )&B7&CHAR ( 10 )&B8,, CHAR ( 10 ) )
= {"안녕하세요";"오빠두입니다";"세번째줄";"네번째줄";"다섯번째줄";"여섯번째줄";"마지막줄"}
D2:D8에 출력되는 세로 배열입니다. 02LEFT + MID + RIGHT 공식 (모든 버전)
FIND 함수와 SUBSTITUTE 함수가 필요한 줄바꿈 위치를 찾고 LEFT·MID·RIGHT 함수가 위치별 텍스트를 반환합니다.
모든 버전 LEFT·MID·RIGHT 공식의 예제 시트에서 G2 셀이 세번째줄을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
1
FIND 함수가 두 번째 줄바꿈 위치를 찾습니다
SUBSTITUTE 함수가 두 번째 줄바꿈을 |로 바꾸면 FIND 함수는 그 위치를 13으로 반환합니다.
=FIND ( "|", SUBSTITUTE ( 셀, CHAR ( 10 ), "|", 3-1 ) )
= 13
두 번째 줄바꿈의 위치입니다. 2
FIND 함수가 세 번째 줄바꿈 위치를 찾습니다
SUBSTITUTE 함수가 세 번째 줄바꿈을 |로 바꾸면 FIND 함수는 그 위치를 18로 반환합니다.
=FIND ( "|", SUBSTITUTE ( 셀, CHAR ( 10 ), "|", 3 ) )
= 18
세 번째 줄바꿈의 위치입니다. 3
MID 함수가 선택한 줄을 반환합니다
MID 함수는 두 번째 줄바꿈 다음인 14번째 문자부터 두 위치의 차이에서 줄바꿈 1자를 뺀 4글자를 반환합니다.
=MID ( 셀, 13+1, 18-13-1 )
= "세번째줄"
G2 셀이 반환하는 세 번째 줄입니다. ![[도구 업데이트] 투명 인감 도장 PNG를 만들어보세요!](https://www.oppadu.com/wp-content/uploads/2026/09/투명-도장-생성기-안내.png)
![[직원 채용] 오빠두엑셀이 정규직 동료를 모십니다](https://www.oppadu.com/wp-content/uploads/2026/08/직원-채용-1_R.png)
네 nr (순번)을 가로로 나열하신 후 자동채우기해보세요 :)