엑셀 VLOOKUP 이미지 불러오기 :: 엑셀 함수 공식

엑셀 VLOOKUP 이미지 불러오기 공식 :: 단계별 총정리

= INDEX(그림범위, MATCH(항목, 항목범위, 0 ))

VLOOKUP 이미지 불러오기 공식을 보다 쉽게 설명해드리기 위해 영상강의를 준비해 드렸습니다.

오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.

파일 이름과 경로를 입력하면 셀 안에 자동으로 그림이 추가되는 ImageLookup 함수 추가기능을 업데이트 하였습니다. 자세한 내용은 아래 링크를 참고해주세요.

아무셀이나 복사한 뒤, '연결된 이미지' 로 원하는 곳에 붙여넣기 합니다.
연결된 이미지를 선택한 뒤, '수식입력줄'을 클릭합니다.
연결된 이미지 수식입력줄에 '=불러올이미지'를 입력하여 사용자 지정범위를 연결합니다. 큰따옴표(") 없이 입력하는 점을 주의합니다. (="불러올이미지" 가 아닙니다.)

INDEX / MATCH 기초 공식을 응용한 방법입니다. INDEX/MATCH 함수의 기초사용법은 관련포스트를 참고하세요.

연결된 이미지는 다른 시트나 다른 파일, 심지어 온라인 페이지에서 이미지를 불러올 수 있는 하나의 '액자'와 같은 기능을 합니다. 해당 공식을 다루는 방법은 관련 VLOOKUP 함수 이미지 불러오기 영상강의에서 자세히 설명드렸습니다.

INDEX/MATCH 함수는 이미지를 불러오는것 외에도 다양한 방법으로 응용할 수 있습니다. INDEX/MATCH 함수의 고급사용법은 관련포스트에서 자세히 설명드렸습니다.

항목범위: =Sheet1!$A:$A
'// 국가명이 입력된 범위입니다.
그림범위: =Sheet1!$B:$B
'// 국기 이미지가 입력된 범위입니다.
불러올이미지: =INDEX(그림범위,MATCH(Sheet1!$E$2,항목범위,0))
'// 선택된 국가명을 참조하여 불러온 국기 그림이 담긴 사용자지정범위입니다.

엑셀 상단의 [서식] - [이름관리자] 를 클릭한 뒤, 아래의 이름정의 범위를 추가합니다.
이름 : 항목범위
참조대상 : =Sheet1!$A:$A

이름 : 그림범위
참조대상 : =Sheet1!$B:$B

서식 - 이름관리자에서 '이름정의범위'를 추가합니다.
'항목범위'의 국가명을 참조해서, 동일한 위치에 있는 그림을 '그림범위'에서 받아올 수 있도록 '불러올이미지' 라는 이름정의범위를 추가합니다.
이름 : 불러올이미지
참조대상 : =INDEX(그림범위,MATCH(Sheet1!$E$2,항목범위,0))

'불러올이미지'라는 이름정의범위를 추가합니다.
아무 셀이나 선택하여 '연결된이미지'로 붙여넣기합니다. 이후 연결된이미지의 수식을 '=불러올이미지'로 직접 입력합니다.
연결된그림에 '불러올이미지' 이름정의범위를 연동합니다.
오류를 방지하기 위해 국가명이 선택되는 셀을 '데이터유효성검사' 목록상자로 제한합니다.
데이 유효성검사로 입력가능한 국가목록을 제한하여 오류를 방지합니다.

국가명으로 '캐나다'를 선택한 상황을 가정하여 알아보겠습니다.

[항목범위]에서 '캐나다'가 몇번째 위치하는지 알아봅니다. MATCH 함수를 사용합니다.
= MATCH(Sheet1!$E$2,항목범위,0)
= MATCH("캐나다",A:A,0)
= 6 '// 캐나다는 6번째 위치하므로 6을 반환합니다.

캐나다는 6번째 위치하므로 MATCH 함수로 6이 반환됩니다.
[그림범위]에서 6번째 위치한 그림을 반환합니다. INDEX 함수를 사용합니다.
= INDEX(그림범위,MATCH(Sheet1!$E$2,항목범위,0))
= INDEX(B:B, 6) '// B열 6번째 위치한 캐나다 국기 이미지를 반환합니다.

그림 범위에서 6번째 위치한 '캐나다'국기가 반환됩니다.

4.8 10 투표

게시글평점