VLOOKUP 함수 여러개 값 가져오기 공식 총정리 :: 엑셀 함수 공식

VLOOKUP 함수 결과값으로 여러개의 값을 세로/가로 방향으로 출력하는 엑셀 함수 공식의 동작원리와 실전 예제를 알아봅니다.

홈페이지 » VLOOKUP 함수 여러개 값 가져오기 :: 엑셀 공식

VLOOKUP 함수 여러개 값 출력 공식 총정리 (세로/가로 방향 모두!)

목차 바로가기

공식이 길어서 어려워보일 수 있으나, 전혀 어렵지 않습니다!
딱 3가지, "찾을값, 찾을범위, 출력범위" 만 공식에 대입해주면 끝! 같이 알아볼까요?

현재 오피스 365 최신버전을 사용중이시라면, FILTER 함수를 사용해보세요!
더욱 편리하게 VLOOKUP 함수 여러 값 불러오기를 구현할 수 있습니다.

함수 공식

  1. VLOOKUP 여러개 값을 세로로 반환하는 공식
    = INDEX($출력범위, SMALL(IF(($찾을값=$찾을범위),MATCH(ROW($찾을범위), ROW($찾을범위)), ""), ROWS($A$1:A1)))

    VLOOKUP 여러개 값 가져오기 세로방향
    VLOOKUP 여러개 값을 세로로 반환하는 공식입니다.
  2. VLOOKUP 여러개 값을 가로로 반환하는 공식
    = INDEX($출력범위,SMALL(IF($찾을값=$찾을범위,ROW($찾을범위)-MIN(ROW($찾을범위))+1, ""),COLUMN(A1)))

    VLOOKUP 여러개 가져오기 가로방향
    VLOOKUP 여러개 값을 가로 방향으로 반환하는 공식입니다.
  3. VLOOKUP 여러 필드의 값을 동시에 반환하는 공식 [COLUMNS 함수 이용]
    COLUMNS 함수를 이용하여 첫번째, 두번째, 세번째.. 열을 순서대로 반환합니다.

    = INDEX($출력범위, SMALL(IF(($찾을값=$찾을범위),MATCH(ROW($찾을범위), ROW($찾을범위)), ""), ROWS($A$1:A1)), COLUMNS($A$1:A1))

    VLOOKUP 여러값 가져오기 여러필드 동시출력
    여러필드의 값을 동시에 출력할 수도 있습니다
  4. VLOOKUP 여러개 필드값을 동적으로 반환하는 공식 [MATCH 함수 이용]
    MATCH 함수를 이용합니다. 필드 머릿글을 바꾸면 출력범위가 동적으로 변하는 공식입니다. %머릿글은 행고정참조(예: A$10 형태)로 입력하는것에 주의합니다.

    = INDEX($출력범위, SMALL(IF(($찾을값=$찾을범위),MATCH(ROW($찾을범위), ROW($찾을범위)), ""), ROWS($A$1:A1)), MATCH($머릿글, $찾을머릿글범위, 0))

    VLOOKUP 여러개값 여러필드 동적출력

  5. VLOOKUP 여러개 값 중 '고유값'만 출력하는 공식 (간단수식 or 배열수식)
    중복값 제거 공식을 응용하여 VLOOKUP 고유값 출력 공식을 작성할 수 있습니다. 중복값 제거 공식에 대한 자세한 설명은 관련 포스트를 참고하세요.

    아래 수식은 간단수식이으로 ENTER로만 입력합니다. 고유값을 '역방향'으로 출력합니다.

    =LOOKUP(2, 1/((COUNTIF($머릿글:머릿글, $출력범위)=0)*($찾을값=$찾을범위)), $출력범위)

    만약 고유값을 정방향으로 출력해야 할 경우, 아래 배열수식을 사용합니다.

    = INDEX($출력범위,MATCH(1,(COUNTIF($머릿글:머릿글,$출력범위)=0)*($찾을값=$찾을범위),0))

    VLOOKUP 여러 값 중 고유값만 출력 설명
    여러값 중 고유값만 반환할 수도 있습니다.
  6. VLOOKUP 두 날짜 사이를 만족하는 여러값 불러오기 공식
    = INDEX($출력범위, SMALL(IF(($시작일<=$날짜범위)*($종료일>=$날짜범위),MATCH(ROW($찾을범위), ROW($찾을범위)), ""), ROWS($A$1:A1)))

    VLOOKUP 두 날짜 사이 만족 여러값 출력
    두 날짜사이 조건을 만족하는 여러값을 출력합니다.

 해당 포스트에 적어드린 공식은 모두 배열수식이므로 반드시 CTRL + SHIFT + ENTER 로 입력하는 것을 주의하세요!

인수 설명

VLOOKUP 여러개 값 출력 : 세로/가로, 1개 필드만 출력하는 경우
VLOOKUP 함수 여러개 값 출력 인수 설명
VLOOKUP 여러개 값 가져오기 공식에 들어갈 인수입니다.
  • $찾을범위 : 찾을값을 조회할 범위입니다. (  VLOOKUP 범위의 맨 좌측열)
  • $출력범위 : 출력할 값이 나열된 범위입니다. (  VLOOKUP 범위 중 출력할 열)
  • $찾을값 : 찾을범위에서 찾을 값입니다. (  VLOOKUP 함수의 첫번째 인수)
VLOOKUP 여러개 값 출력 : 여러 필드를 동시에 출력하는 경우
VLOOKUP 여러값 출력 여러필드 인수설명_2
여러 필드를 동시에 출력하는 공식에 사용된 인수입니다
  • $찾을범위 : 찾을값을 조회할 범위입니다.
  • $출력범위 : 출력할 값이 나열된 범위입니다.
  • $찾을값 : 찾을 범위에서 찾을 값입니다.
  • $머릿글 : 출력할 범위의 머릿글입니다. (행절대참조로 입력합니다. (예: A$10 형태))
  • $찾을머릿글범위 : 출력범위의 머릿글입니다.
VLOOKUP 여러개 값 중 '고유값'만 출력
VLOOKUP 여러 값 중 고유값만 출력 인수
고유값만 추출하는 공식에 사용된 인수입니다.
  • $찾을범위 : '찾을값'을 조회할 범위입니다.( VLOOKUP 범위 중 맨 좌측 열)
  • $찾을값 : '찾을범위'에서 찾을 값입니다. ( VLOOKUP 함수의 조건)
  • $출력범위 : 출력할 값이 나열된 범위입니다. ( VLOOKUP 범위 중 출력할 열)
  • $머릿글 : 값을 출력할 범위의 머릿글입니다. 범위형태로 입력하되 동적확장범위(혼합참조형태)로 입력하는 것에 주의합니다. (예: $A$1:A1)
VLOOKUP 두 날짜 사이를 만족하는 여러값 출력
두 날짜 사이의 여러값 불러오기 인수
두 날짜 사이 여러값을 구하는 공식에서 사용된 인수입니다.
  • $날짜범위 : 날짜가 입력된 범위입니다.
  • $출력범위 : 출력할 값이 나열된 범위입니다.
  • $시작일/종료일 : '날짜범위'에서 조회할 시작일과 종료일입니다.

사용 예제

VLOOKUP 함수 여러개 값 출력 사용예제 GIF
VLOOKUP 여러개 값 가져오기 공식의 사용예제입니다.

예제파일 다운로드

관련 기초함수
선택한 범위에서 원하는 위치의 값을 반환합니다.
범위 내 찾는값의 위치(순번)을 반환합니다.

예제파일 살펴보기

예제파일에서 사용된 함수 공식

본 예제에서는 해당 지역에 거주하는 여러명의 직원을 출력하는 VLOOKUP 함수 여러개 값 가져오기 공식을 알아보겠습니다. 공식에 들어가는 인수는 아래와 같습니다.

{ =IFERROR(INDEX($C$3:$C$10,SMALL(IF(($F$3=$B$3:$B$10),MATCH(ROW($B$3:$B$10), ROW($B$3:$B$10)), ""), ROWS($A$1:A1))),"") }
VLOOKUP 여러개 값 가져오기 사용공식
예제파일에서는 위 공식이 사용되었습니다.
  1. $찾을범위 : 지역 (=$B$3:$B$10)
  2. $출력범위 : 이름 (=$C$3:$C$10)
  3. $찾을값 : 찾을지역 (=$F$3)
VLOOKUP 함수 여러개 값을 동시에 출력하는 공식의 동작원리

예제에서 사용된 공식을 바탕으로 VLOOKUP 여러개 값을 동시에 출력하는 공식의 동작원리를 단계별로 알아보겠습니다. 본 포스트에서는 값을 세로로 출력하는 공식의 동작원리만 적어드렸습니다.

가로로 출력하는 공식은 세로로 출력하는 공식과 동일한 원리로 동작합니다. 여러 필드의 값을 동적으로 가져오는 공식은 INDEX/MATCH 함수를 응용합니다. INDEX/MATCH 함수에 대한 자세한 설명은 관련포스트를 참고하세요.

  1. 지역범위에서 선택한 지역과 동일한 값을 찾아 배열로 반환합니다.
    =IFERROR(INDEX($C$3:$C$10,SMALL(IF(($F$3=$B$3:$B$10),MATCH(ROW($B$3:$B$10), ROW($B$3:$B$10)), ""), ROWS($A$1:A1))),"")

    지역에서 선택한 지역(예: 서울)을 만족하는 값을 찾습니다.

    = $F$3 = $B$3:$B$10
    = "서울" = ("서울","경기","서울","경기","서울","인천",...)
    = { TRUE, FALSE, TRUE, FALSE, TRUE, FALSE, ... }
  2. 전체 지역의 개수를 1부터 증가하는 순번의 배열로 반환합니다.
    =IFERROR(INDEX($C$3:$C$10,SMALL(IF(($F$3=$B$3:$B$10),MATCH(ROW($B$3:$B$10), ROW($B$3:$B$10)), ""), ROWS($A$1:A1))),"")

    ROW 함수는 각 셀의 행번호를 반환합니다. 따라서 MATCH 함수는 아래와 같이 입력됩니다.

    = MATCH ( ROW($B$3:$B$10), ROW($B$3:$B$10) )
    = MATCH ( {3,4,5,6,7,8,9,10}, {3,4,5,6,7,8,9,10} )
    = {1,2,3,4,5,6,7,8 }
  3. 지역 범위에서 선택한 지역과 일치하는 항목의 순번(=n)을 반환합니다.
    =IFERROR(INDEX($C$3:$C$10,SMALL(IF(($F$3=$B$3:$B$10),MATCH(ROW($B$3:$B$10), ROW($B$3:$B$10)), ""), ROWS($A$1:A1))),"")

    IF 함수로 TRUE 와 FALSE 일때의 값을 구분하여 결과값을 출력합니다.

    = IF(($F$3=$B$3:$B$10),MATCH(ROW($B$3:$B$10), ROW($B$3:$B$10)), "")
    = IF ( { TRUE, FALSE, TRUE, FALSE, TRUE, FALSE, ... } , {1,2,3,4,5,6,7,8 }, "" )
    = { 1,"" ,3 ,"" ,5 ,"" , ... }
  4. 출력된 순번(=n) 중 x번째로 작은 값을 반환합니다.
    =IFERROR(INDEX($C$3:$C$10,SMALL({ 1,"" ,3 ,"" ,5 ,"" , ... }, ROWS($A$1:A1))),"")

    ROWS 함수는 입력한 범위의 행개수를 반환합니다. 동적확장범위를 사용하여 아래로 자동채우기를 할 때마다 1,2,3..의 값이 순차적으로 증가합니다.

    = ROWS($A$1:A1) '// -> 1
    = ROWS($A$1:A2) '// -> 2
    = ROWS($A$1:a3) '// -> 3... 이런 식으로 증가합니다.

    이후 SMALL 함수를 사용하여 순번(=n) 중 x 번째로 작은 값을 출력합니다.

    = SMALL({ 1,"" ,3 ,"" ,5 ,"" , ... }, ROWS($A$1:A1))  '// 가장 작은값을 출력할 경우
    = SMALL( { 1,"" ,3 ,"" ,5 ,"" , ... } , 1 )
    = 1

    또는 두번째로 작은 값을 출력할 경우는 아래와 같습니다.

    = SMALL({ 1,"" ,3 ,"" ,5 ,"" , ... }, ROWS($A$1:A2))  '// 두번째로 작은값을 출력할 경우
    = SMALL( { 1,"" ,3 ,"" ,5 ,"" , ... } , 2 )
    = 3
  5. 출력범위에서 각 n번째 위치하는 값을 반환합니다.
    =IFERROR(INDEX($C$3:$C$10, { 1, 3, 5 } ),"")

    INDEX 함수는 입력한 범위에서 n번째 위치하는 값을 반환합니다. 따라서 이름범위에서 1, 3, 5번째에 위치하는 값을 출력합니다.

    = INDEX($C$3:$C$10, { 1, 3, 5 } )
    = INDEX( { 박지훈, 김진아, 박시형, 유매력, 황석훈, 박나연 , ... } , { 1, 3, 5 } )
    = { 박지훈, 박시형, 황석훈 }
  6. IFERROR 함수로 오류처리를하여 공식을 마무리합니다.
    =IFERROR(INDEX($C$3:$C$10, #NUM ),"")

    출력할 개수보다 넓은 범위에 공식이 입력될 경우 SMALL 함수는 오류를 반환합니다. 즉, 입력된 개수보다 높은 값이 입력될경우 #NUM 오류를 반환하게됩니다. (예: 3개의 값중 4번째로 작은값을 출력하시오? -> #NUM!오류)
    따라서 IFERROR 함수로 오류일경우 빈칸을 출력하는 방식으로 공식을 마무리합니다.

링크: MS 홈페이지 VLOOKUP 함수 사용법 상세설명

4.9 39 votes
게시글평점
현재 페이지 댓글알림 신청
알림 설정
guest
84 Comments
Inline Feedbacks
View all comments
최지오
최지오
2020년 2월 6일 7:28 오후
게시글평점 :
     

천재신가요?....
감탄만 나오네

이도경
이도경
2020년 2월 7일 7:16 오전
게시글평점 :
     

와 ㅜㅜ 출근해서 꼭해봐야겠어요 진짜 ㅠㅠ 오빠두님최고

유정천사
유정천사
2020년 2월 7일 9:27 오전
게시글평점 :
     

왕짱~너무 멋집니다~^^

Ireer
Ireer
2020년 2월 7일 9:41 오전
게시글평점 :
     

와 늘 유투브 강의만 보다가 너무 알고싶었던 내용이라 덧글 남기러 왔습니다! 정말 대단하세요 ㅠ 그런데 혹시 여러개의 결과를 각 결과 사이에 ", "를 삽입해 1개의 셀에 표기하는게 가능할까요? 가능하다면 어떤… 더보기 »

차트윈
차트윈
2020년 2월 7일 3:26 오후
게시글평점 :
     

잘보구 갑니다. 그런데 왠지 영상보다는 눈에들어오질 않네요^^ 항상 고급정보 공유 감사드립니다. 올한해도 준비하고 계획하는일 잘 되시길 기도합니다. 수고하세요

박원조
박원조
2020년 2월 8일 10:21 오전
게시글평점 :
     

최곱니다 혹시 지금은 필드가 두 개(지역,이름)만 있는데 3~6(지역,이름,주소, 전화번호)개 확장되었을 때 리턴 값이 다 나오게 할수는 없는지요 예제는 서울 지역 선택시 해당지역에사는 사람만 나오는데 더 확장해서 그 사람의 주소와 이름까지… 더보기 »

박원조
박원조
2020년 2월 9일 10:42 오전

감사합니다 제가 여기저기 홍보도 많이 하고 있습니다
늘 감탄의 연속입니다~~~더 많은 복 받은실겁니다
보이지 않는 누군가에게 선을 쌓은 집은 분명 선의 열매가 열린다고 했어요

하늬돌이
하늬돌이
2020년 2월 9일 11:07 오전
게시글평점 :
     

항상 필요한 기능인데 어려워서 잘 사용을 못하고 있었는데 자세하게 설명해 주셔서 이해하는데 도움이 많이 되었습니다. 감사해요

봉도리
봉도리
2020년 2월 9일 3:40 오후
게시글평점 :
     

항상 강의 잘 보고 있습니다
위의 식 적용했을때 출력값이 두개 이상 일경우 그중 하나만 나오게 할수는 없을까요??

예제파일에서 서울 박지훈이 두개 일경우 하나만 나오게요

김지웅
김지웅
2020년 2월 19일 7:48 오후
게시글평점 :
     

이해 안갔던 부분마저 하나씩 설명이 차근차근 잘 되어있어서 결국 이해하는데 성공하게 만들어주셨네요.
이제 회사가서 적용하는 것 만 남았는데 노력해 보겠습니다.

레전드21
레전드21
2020년 2월 21일 10:48 오전
게시글평점 :
     

데이터가 계속 추가될경우 방법에 대해 매우 궁금합니다. 데이터값을 "표"로 지정해서 응용해보았는데 찾을값이 2개까지만 불러오네요~혹시 추가로 설명가능할까요? 감사합니다.

레전드21
레전드21
2020년 2월 21일 8:15 오후
Reply to  레전드21

정말 제 업무에 꼭 필요한 함수를 찾은것 같습니다^^ vba코딩으로 데이터 입력시 sheet2(DB)로 자동입력되는 방식인데 출력범위를 '표'로 지정하고 match함수포함된 함수로 응용하면 자동채우기 하지않더라도 추가입력된 자료가 자동으로 출력이 되는데, 문제는 찾을 머리글이… 더보기 »

레전드21
레전드21
2020년 2월 22일 3:26 오후

감사합니다^^우연히 유튜브 보고 들어왔다가 제게 꼭 필요한 함수를 배울수 있었습니다.
친절한 댓글도 감사하며, 요즘 완전 초보가 엑셀배우는 재미에 시간가는줄 모르고 삽니다^^

갈매기
갈매기
2020년 2월 23일 7:35 오후
게시글평점 :
     

구글링하다 내용이 너무 좋아서 가입까지 했습니다. 홈페이지에 있는 다른 것들도 시간되면 한번 연습해봐야겠습니다. 좋은 자료 너무 감사합니다. ^^

길
2020년 3월 3일 1:10 오전
게시글평점 :
     

정말 감사합니다. 너무너무 잘보고 있는 1인 입니다. 혹시 조건이 두개이상일때도 가능한가요?? 예를들어 예제에 찾을지역조건이 하나인데 지역조건을 두개로 늘리고 부산,서울 둘중 하나라도 만족하는 사람을 모두 불러온다. 단 동명이인은 제외한다. 이런식으로요.. small(if((찾을값,찾을범위)… 더보기 »

boyz02men
boyz02men
2020년 3월 18일 11:54 오후

안녕하세요 좋은강의 좋은 댓글 감사드립니다. 상기의 공식을 이용하여 연중인데 결과값이 잘 나오질 않네요. 더 공부해보고 질문드리겠습니다^^ 쌤의 댓글의 수식중 MATCH(1,--..................)에서 -- 이 표시는 무엇을 의미하는지요. 그리고 상기 공식도 컨트롤 쉬프트… 더보기 »

lastpass****
2020년 4월 29일 4:12 오전

위에 있는거랑 똑같이 했는데, 함수에 너무 많은 인수가 들어갔다며 않됩니다... 도와주세요 ㅠㅠ

lastpass****
2020년 4월 29일 10:26 오후

다른 match 함수 예제를보면, (MATCH(1,--(($찾을값1=$찾을범위1),($찾을값2=$찾을범위2) 저기서 찾을값사이에 , 가 아니고 *가 들어가던데 어떤차이가 있는건가요?
그리고 여기다가 column함수까지 사용하려면 마지막에 기존자료처럼 함수만 추가하면 되는지요?

lastpass****
2020년 4월 29일 10:40 오후
Reply to  lastpass****

=INDEX($E$3:$G$48,small(if(match(1,--($M$4=$B$3:$B$48),($N$4=$C$3:$C$48)),0),match(row($B$3:$B$48),row($B$3:$B$48)),""),rows($A$1:a1))

여기서 "" 이부분에 문제가 있다고 나옵니다. 너무 많은 인수가 입력되었다고

일빵빵
일빵빵
2020년 3월 20일 12:56 오후
게시글평점 :
     

제가 직장인이라 다 살펴보지 못해서 그런데.....이게 다 무료인가요>?

일빵빵
일빵빵
2020년 3월 20일 12:56 오후
게시글평점 :
     

유투브 보고 왔는데 강의가 좋네요~

고지성
고지성
2020년 3월 20일 6:32 오후
Reply to  일빵빵

예제 파일 다운로드가 안되는데 확인해주실 수 있을까요?

해운대갈매기
해운대갈매기
2020년 3월 24일 10:26 오후
게시글평점 :
     

저도 감탄만 하게 됩니다!! 항상 잘 보고 많이 배우고 있습니다. 감사합니다! 저도 궁금한 점이 있습니다. 중복인지 모르겠으나 찾을 조건이 중복일 때(or 다중검색조건) 모두 반환되는 공식은 없을까요? 예를 들면 찾을지역이 부산… 더보기 »

김명환
김명환
2020년 3월 31일 7:08 오후
게시글평점 :
     

피트니스 관련 내용 하려고 하는데 가능한지 불가능한지 저로서는 가늠이 잘안되서 ㅎㅎ
혹시 글+ 이미지도 이런식으로 검색 값으로 여러개를 가져오는게 가능할까요?
설명+ 예제파일이 너무 유용했습니다. 감사합니다.

민준봄날
민준봄날
2020년 4월 7일 4:16 오후
게시글평점 :
     

안녕하세요. 유익하고 알기 쉬운 가르침 정말 감사합니다. 덕분에 업무에 엑셀을 아주 유용하게 사용하고 있습니다. 적게 일하고 많이 버시는 행복한 삶 누리시길 바래요^^ 다름이 아니라 서식(경력확인서)을 하나 만들고 있는데요, 조건이 두… 더보기 »

민준봄날
민준봄날
2020년 4월 7일 5:15 오후

=INDEX($E$22:$E$7328, SMALL(IF(MATCH(1,--(($A$2=$A$22:$A$7328),($B$2=$C$22:$C$7328)),MATCH(ROW($A$22:$A$7328), ROW($A$22:$A$7328)), ""), ROWS($A$1:A1)))) 이렇게 했는데 문제가 있다고 나오네요 ㅠㅠ

lastpass****
2020년 4월 29일 7:23 오전
Reply to  민준봄날

저두 안돼요 ㅠㅠ...

태브라더스
태브라더스
2020년 4월 9일 12:15 오후
게시글평점 :
     

정말..대단하네요. 자료 정리도 깔끔하고..감사합니다.

lastpass****
2020년 4월 29일 12:55 오전
게시글평점 :
     

예제에서 찾을지역, criteria 가 여러개일 경우에는 어떤함수를 추가로 이용해야 하나요?
예를들어 sumifs처럼 몇가지 항목을 만족하는 값을 땅겨오고 싶은데, and 함수를 통해서 가능할까요?

박영석
박영석
2020년 4월 29일 2:14 오후
게시글평점 :
     

안녕하세요, VLOOKUP 여러개 값 출력 : 여러 필드를 동시에 출력하는 경우에 조건을 2개로 걸고 싶은데, 그러면 * 사용해서 2개 조건 넣으면 될까요? 어디 부분에 조건을 추가해야 할까요? 어렵네요..ㅜㅜ

c***
2020년 5월 3일 4:17 오후
게시글평점 :
     

VLOOKUP 여러개 값 출력 : 여러 필드를 동시에 출력하는 경우에서 지역이 서울, 성별이 남인 2개 조건 모두 충족하는 표의 모든 값이 쭉 다 나오게 거는 수식은 없을까요? 단순히 2개 조건… 더보기 »

호야
호야
2020년 5월 11일 3:11 오후
게시글평점 :
     

1번 세로로 변환하는 공식에서 ROWS($A$1:A1)를 그냥 row(a1)으로 해도 상관없는건지 궁금하구요
2번 가로로 변환하는 공식도 1번이랑 똑같이 하고 뒤에 ROWS($A$1:A1)부분만 column(a1)으로 바꿔도 되는지 궁금합니다.결과는 같이 나오더라구요..

신태준
신태준
2020년 5월 20일 5:19 오후
게시글평점 :
     

항상 보면서 감탄하면서 도움을 많이 받고있는 사람입니다. 어지간하면 써주신 내용으로 해결을 해왔지만, 이번에 좀 애매한 경우에 부닥쳤습니다. 도와주실수 있으실가욥.. 우선 표가 2개가 있고, 각 표에 기준값은 국가코드이며 국가별로 이용자 숫자가… 더보기 »

신태준
신태준
2020년 5월 22일 12:14 오전

그게 처음 서버에서 표기될땐 표 형식으로는 되어있지만 그것이 엑셀표 형식으로 다운받을수있는게 아니라서, 그저 인터넷창에서 글자 긁어오듯이 긁어서 오는 방법말곤 없어서, 긁어온 글자를 표1에다가 그대로 저장을 해오는 형식이라서요.
알려주신방법으로 시도해보겠습니닷

이유진
이유진
2020년 5월 22일 1:21 오전
게시글평점 :
     

와... 반할 것 같아요

타임
2020년 5월 25일 3:33 오후
게시글평점 :
     

예제 파일을 다운 받을 수가 없네요 ㅠㅠ

타임
2020년 5월 25일 3:34 오후
게시글평점 :
     

vlookup을 활용하여 가로로 데이터를 받는것을 하려고 하는데 위에 찾을 범위라는 것이 동일한 구간인지 궁급합니다.
예를 들어 이름인지.. 지역인지..

박성철
박성철
2020년 5월 27일 10:16 오전
게시글평점 :
     

너무 잘보고 있습니다!
=IFERROR(INDEX($C$3:$C$10,SMALL(IF(($F$3=$B$3:$B$10),MATCH(ROW($B$3:$B$10), ROW($B$3:$B$10)), ""), ROWS($A$1:A1))),"") 마지막에 ROW가 아닌 ROWS를 써야되는데 왜 인가요..?
그 부분은 배열함수랑은 상관없는거 같은데

탁이
탁이
2020년 6월 7일 11:23 오후
게시글평점 :
     

안녕하세요. 위 수식으로 물류 상품 주문자별 분배하고 검수하는 서식을 나름대로 만들어서 잘 사용하고 있습니다. 정말 감사드립니다. 그런데 위 수식 사용하다 한 가지 더 궁금한 게 있어서 질문 드립니다. 입력은 고정된… 더보기 »

minasama@hanmail.net
2020년 6월 9일 10:51 오전
게시글평점 :
     

정말 대단하십니다. 제게 필요한 것에 답을 주셨네요. 감사합니다.   1번 항목을 적용해서 하고 있는데 값이 잘 나오다가 갑자기 값이 셀에서 보이지 않는군요..   해당 셀에 공식은 잘 적용이 되어 있는데요..… 더보기 »

창제
창제
2020년 6월 10일 9:08 오전
게시글평점 :
     

쌤 ㅠ 예제파일 다운로드가 안되네요..
그리고 엑셀 관련 서적 출판 계획은 없으신지요..?

greentea
greentea
2020년 6월 10일 2:33 오후
게시글평점 :
     

저 이 게시글 보구서 가입하고 갑니다! 자주 올것같네요! 감사합니다ㅠㅠ

greentea
greentea
2020년 6월 17일 5:24 오후
게시글평점 :
     

지난번에 보구서 도움 받아갔는데 오늘 좀 더 응용된 부분을 하려니 어렵네요.. 예제파일 올려주신걸로 예를 들때, 여러필드출력 시트에서 좌측 데이터 내용(지역이 다양하고 해당 내용도 많을경우)이 많을 경우에, 찾을 지역이 여러개고 출력표에… 더보기 »

Last edited 3 월 전 by greentea
greentea
greentea
2020년 6월 18일 11:19 오전

오호 감사합니다!!! 빠른 피드백도 너무 감사드려요!! 한번 적용해볼게요!! ><

박서아
박서아
2020년 7월 17일 10:13 오전
게시글평점 :
     

안녕하세요! 유용한 정보 감사합니다:) 아래 함수에서 궁금한게 있는데 아래 함수 입력 후 자동채우기 했을때 ROWS($A$1:A3) 값 이후부터는 #NUM! 오류가 뜨는데 그건 왜그럴까요..? 오류가 뜬 부분부터 다시 ROWS($A$1:A1) 으로 수정하면은 또… 더보기 »

나나
나나
2020년 7월 17일 4:04 오후

혹시 그러면 30개이하의 값을 추출하고자 할땐 어떤식으로 활용해야 할까요...? 도움청합니다ㅠㅠ

하늘바라기
하늘바라기
2020년 8월 6일 4:26 오후
게시글평점 :
     

5번(VLOOKUP 여러개 값 중 '고유값'만 출력하는 공식 (간단수식 or 배열수식)) 은,  1번 (VLOOKUP 여러개 값을 세로로 반환하는 공식) 에 중복을 제거하는 버전이라고 생각할 수 있을 것 같은데요. 2번 (VLOOKUP 여러개… 더보기 »

yoo
yoo
2020년 8월 19일 1:42 오후
게시글평점 :
     

안녕하세요 너무나 좋을 자료 감사합니다. 하나 질문이 있는데요 동시 출력하는 함수에서 만약 예시 문기준으로 한명의 나이를 기입하지 않았을때 출력 값이 0이 아닌 것으로 표기 되려면 어떻게 해야하나요?

CSZㅡLuis
CSZㅡLuis
2020년 8월 20일 9:59 오전
게시글평점 :
     

중복된 엑셀값 정리하는 법 찾다 찾다 겨우 발견해서 말씀주신 방법을 사용했는데... #value가 나오네요... 뭐가 문제인지 모르겠습니다. 혹시 몰라 엑셀 상황 이미지 링크 함께 올려봅니다 ㅜㅜ?type=w580 데이터 값이 너무 많아 수기로… 더보기 »

Last edited 1 월 전 by CSZㅡLuis
영두
영두
2020년 9월 3일 9:36 오후
게시글평점 :
     

매커니즘까지 자세히 적혀있어서 너무 좋네요. 유튜브 구독만해놓고 늘 봐야지 봐야지하다가...ㅎㅎ 앞으로 하루에 5개씩 보고 따라할꺼에요. 고맙읍니다.

강정호
강정호
2020년 9월 12일 8:38 오전
게시글평점 :
     

혹시 6번에 날짜가 아니라 시간사이에 데이터 추출도 가능한가요..?

소가소가
소가소가
2020년 9월 27일 3:09 오후
게시글평점 :
     

안녕하세요~ 혹시 해당 함수도 역순으로 아래에서부터 데이터를 추출하게 하려면 어떤 함수를 쓰면 될지 도무지 떠오르지않아 댓글 남깁니다!

84
0
여러분의 생각을 댓글로 남겨주세요.x