엑셀 저장여부 확인 및 파일 강제종료 :: CloseWB 함수 사용법 총정리

Public blnClose As Boolean
Function CloseWB(Optional SaveChanges As Boolean = True, Optional DisplayAlert As Boolean = False) As Boolean
 
Dim WB As Workbook
Dim i As Long
Dim vbYN As VbMsgBoxResult
 
Application.DisplayAlerts = False
 
Logout
 
If blnClose = False Then
 
    If DisplayAlert = True Then
 
        vbYN = MsgBox("'" & ThisWorkbook.Name & "' 의 변경내용을 저장하시겠습니까?", vbYesNoCancel)
 
        If vbYN = vbNo Then SaveChanges = False: blnClose = True
        If vbYN = vbYes Then SaveChanges = True: blnClose = True
        If vbYN = vbCancel Then blnClose = False: GoTo Finally
 
    End If
 
    For Each WB In Application.Workbooks
        If WB.Name <> "PERSONAL.XLSB" Then i = i + 1
    Next
 
    If i = 1 Then
        If SaveChanges = True Then
            ThisWorkbook.Save
            Application.EnableEvents = False
            Application.Quit
        Else
            ThisWorkbook.Saved = True
            Application.EnableEvents = False
            Application.Quit
        End If
    Else
        If SaveChanges = True Then
            ThisWorkbook.Save
            ThisWorkbook.Close
        Else
            ThisWorkbook.Saved = True
            ThisWorkbook.Close
        End If
    End If
 
End If
 
CloseWB = False
Application.DisplayAlerts = True
 
Exit Function
 
Finally:
Application.DisplayAlerts = True
CloseWB = True
 
End Function
 
Sub Logout()
 
'파일 종료 전 실행 할 특정 로그아웃 동작을 작성합니다
 
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
 
' 통합문서가 종료되기 전, CloseWB 함수를 실행한 뒤 사용자가 '취소' 버튼을 클릭할 경우 파일 강제종료를 취소합니다.
' 사용자가 예 / 아니오를 클릭할 경우 파일을 결과값에 따라 파일이 강제 종료 됩니다.
 
Cancel = CloseWB(, True)
 
End Sub