VBA 관련 문의드립니다!

Sub MergeData()
    Dim ws As Worksheet, fNames As Variant, iNext As Long, Col As Variant, vCopy As Variant
    Dim sh As Worksheet, vData As Variant, vTitle As Variant, iLast As Long, C As Long, R As Long
    
    '// 각 부서 양식에서 사용한 필드명의 변형들을 결과값에 표시되어야 하는 열 순서대로 모두 나열합니다.
    fNames = Array("CS상태", "NO", "택배사", "송장번호|송장" & Chr(10) & "번호", "부서|담당부서|DEPT", "성함|이름|성명", "사번|사원번호|개인번호", _
                   "휴대폰1|개인연락처", "동복|상품명", "사이즈명|옵션사이즈", _
                  "수량|개수", "금액|구매금액")


    Set ws = Worksheets("결과값")
    
    For Each sh In Worksheets
        If sh.Name = ws.Name Then GoTo NEXT_SH
        sh.AutoFilterMode = False
        iLast = sh.Cells(sh.Rows.Count, "A").End(xlUp).Row
        If iLast < 2 Then GoTo NEXT_SH
        
        iNext = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row + 1
        
        vTitle = sh.Range("A1:BX1").Value2
        vData = sh.Range("A2:BC" & iLast).Value2
        For C = LBound(vTitle, 2) To UBound(vTitle, 2)
            '// vTitle과 vData에 실제로 자료가 있는 부분보다 넓게 설정했으므로 빈셀에 대한 처리 필요
            Col = CVErr(xlErrNA)
            If vTitle(1, C) <> "" Then Col = Application.Match("*" & vTitle(1, C) & "*", fNames, 0)
            If Not IsError(Col) Then
                vCopy = Application.Index(vData, 0, C)
                For R = LBound(vCopy) To UBound(vCopy)
                    '// 갑이 숫자형 '문자열'일 때 숫자로 변경되지 않도록 수정
                    If TypeName(vCopy(R, 1)) = "String" And IsNumeric(vCopy(R, 1)) Then
                        vCopy(R, 1) = "'" & vCopy(R, 1)
                    End If
                Next
                '// 시작위치를 Col + 0으로 조정해야 함... A열부터는 +0, E부터는 +4
                ws.Cells(iNext, Col + 0).Resize(UBound(vData, 1), 1) = vCopy
            Else
                '// 열 제목이 fNames에서 찾을 수 없으므로 복사하지 않음
            End If
        Next C
        
NEXT_SH:
    Next sh

End Sub