VBA 두 행 비교 관련 질문입니다

Sub ExclusiveList(List1 As Variant, List2 As Variant, Target As Range, Optional CaseInsensitive As Boolean = True)
    '// 2개의 범위나 Array를 비교하여 결과를 하나의 열로 반환
    '// Target 셀부터 결과를 출력
    '// CaseInsensitive    True : Case-Insensitive, False : Case-Sensitive
    
    Dim ListA As Variant, ListB As Variant
    Dim oDicA As Object: Set oDicA = CreateObject("Scripting.Dictionary"): oDicA.CompareMode = IIf(CaseInsensitive, vbTextCompare, vbBinaryCompare)
    Dim oDicB As Object: Set oDicB = CreateObject("Scripting.Dictionary"): oDicB.CompareMode = IIf(CaseInsensitive, vbTextCompare, vbBinaryCompare)
    Dim vItem As Variant, rArray As Variant
    
    If TypeName(List1) = "Range" Then ListA = Intersect(List1.Parent.UsedRange, List1).Value2 Else ListA = List1
    If TypeName(List2) = "Range" Then ListB = Intersect(List2.Parent.UsedRange, List2).Value2 Else ListB = List2
    
    If IsArray(ListA) Then
        For Each vItem In ListA
            If vItem <> vbNullString Then oDicA(vItem) = CStr(vItem)
        Next
    Else
        If ListA <> vbNullString Then oDicA(ListA) = CStr(ListA)
    End If
    
    If IsArray(ListB) Then
        For Each vItem In ListB
            If vItem <> vbNullString Then oDicB(vItem) = CStr(vItem)
        Next
    Else
        If ListB <> vbNullString Then oDicB(ListB) = CStr(ListB)
    End If
    
    For Each vItem In oDicB.keys
        If oDicA.exists(vItem) Then oDicB.Remove vItem: oDicA.Remove vItem
    Next
    For Each vItem In oDicA.keys
        If oDicB.exists(vItem) Then oDicA.Remove vItem: oDicB.Remove vItem
    Next
    For Each vItem In oDicB.keys
        If Not oDicA.exists(vItem) Then oDicA(vItem) = oDicB(vItem)
    Next
    If oDicA.Count > 0 Then rArray = oDicA.keys

    If IsEmpty(rArray) Then GoTo EXIT_RUN
    If oDicA.Count = 1 Then Target.Cells(1,1) = rArray: GoTo EXIT_RUN

    rArray = Application.Transpose(rArray)
    Target.Cells(1, 1).Resize(UBound(rArray, 1), UBound(rArray, 2)) = rArray
    
EXIT_RUN:
    Set oDicA = Nothing: Set oDicB = Nothing

End Sub

Sub Test()
    ExclusiveList Range("A1:A11"),  Range("B1:B8"),  Range("C1")
End Sub