재고 관리 계산(복잡합니다ㅠㅠ)

@나지나지 님 본 내용에 대한 사전 제약 조건을 보면,
미래 구간 재고 물량 중 출고가 예정되어 있는 물량에 대해서는 출고가 불가합니다.
따라서, 일별 재고 가용량을 조건으로 확인을 해야 합니다.

일별 재고 가용량
= 전일 재고 + 미래구간 입고 계획(출고 계획이 있는 날짜까지) - 미래구간 출고 계획(전체)
이며, 각각의 공식은 아래와 같습니다.
1. 전일 재고 = 전전일 재고 + 전일 입고 + 전일 출고
2. 미래구간 입고계획
= sum(당일 ~ 출고 계획이 있는 날짜의 입고 수량)
3. 미개구간 출고계획
= sum(당일 ~ 출고 계획이 있는 잘짜의 출고 수량)
4. 출고 가능한 가장 빠른 날짜
= 주문 수량 >= 주문 가용량이 가장 빠른 날짜

각각의 데이터를 찾는 방법은 다음과 같습니다.
1. 출고 계획이 있는 날짜 찾기
= match(0, D7:D11, -1) -> 9월 30 ~ 10월 20일에서 출고 계획이 있는 마지막 날짜인 10월 15일에 대한 순서 4
2. 당일부터 10월 15일까지의 입고 수량
= sum(SUM(OFFSET(C7,0,0,IFERROR(MATCH(0,D7:$D$11,-1),1),1))
3. 당일부터 10월 15일까지의 출고 수량
= SUM(OFFSET(D7,0,0,IFERROR(MATCH(0,D7:$D$11,-1),1),1))
4. 주문 가용량
= E6+H7-I7
5. 주문 가능 여부
= IFERROR(IF(J7>=$E$3,"T","F"),"F")
6. 출고 가능 날짜
= IFERROR(INDEX($B$7:$B$11,MATCH("T",$F$7:$F$11,0),1),"Not Acceptable")

* 추가 고려사항
- 각각의 함수에서는 당일 이후를 확인해야 하므로 if 및 offset 범위의 시작은 D7과 같이 절대참조가 없음
- 10월 20일의 경우 당일 포함 미래구간에 더이상 출고 계획이 없으므로 범위를 당일로 지정하기 위해서
IFERROR(MATCH(0,D11:$D$11,-1),1)로 범위 제약을 추가함
- 데이터 관리시 현재 재고인 9월 28일도 데이터의 일부분이므로 데이터에 해당 라인을 추가함
만약 당일에 대한 조회조건이 따로 필요하다면 일별 재고 리스트에는 가능한 날짜를 모두 주고
시작일의 재고를 표기해 주는 것이 나을 거 같습니다 (향후 동적/범용적인 사례로 사용시 필요)

- F 컬럼에 있는 값은 계산 과정을 보여주기 위해서 K 컬럼을 참조했습니다.
이 내용을 한 번에 반영하려면 F 컬럼에 아래의 식을 반영하면 됩니다.
=IFERROR(IF(E6+SUM(OFFSET(C7,0,0,IFERROR(MATCH(0,D7:$D$11,-1),1),1))-SUM(OFFSET(D7,0,0,IFERROR(MATCH(0,D7:$D$11,-1),1),1))>=$E$3,"T","F"),"F")

첨부파일 : 재고-계산_Sum_offset.xlsx