API 오류가 납니다 ㅠ

Option Explicit

#If VBA7 Then
    Public Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal Milliseconds As LongPtr)
#Else
    Public Declare Sub Sleep Lib "kernel32" (ByVal Milliseconds As Long)
#End If
 
Function getSolCalInfo(y1 As Integer, m1 As Integer, d1 As Integer, Optional n As String) As Variant
 
    Dim OHTTP As Object, OXML As Object, NodeCell As Object, NodeChild As Object
    Dim s_URL As String, C_Key As String
    Dim y2 As Integer, m2 As Integer, d2 As Integer
 
    C_Key = [인증키]
 
    s_URL = "http://apis.data.go.kr/B090041/openapi/service/LrsrCldInfoService/getSolCalInfo?" & _
            "lunYear=" & y1 & _
            "&lunMonth=" & Format(m1, "00") & _
            "&lunDay=" & Format(d1, "00") & _
            "&ServiceKey="
 
    Set OHTTP = CreateObject("WINHTTP.WinHTTPRequest.5.1")
 
    OHTTP.Open "Get", s_URL & C_Key
    OHTTP.send

    If OHTTP.Status = 200 Then

        Set OXML = CreateObject("MSXML2.DOMDocument.6.0")

        With OXML
            .LoadXML (OHTTP.responseText)
            Set NodeCell = .SelectSingleNode("response/body/items")
            If NodeCell Is Nothing Then
                getSolCalInfo = CVErr(xlErrNA)
                Debug.Print DateSerial(y1, m1, d1) & n & ":ResponseText 오류"
                Exit Function
            End If
        End With
        
        If InStr(1, n, "윤", vbTextCompare) = 0 Then
            Set NodeChild = NodeCell.FirstChild
        Else
            If NodeCell.ChildNodes.Length > 1 Then
                Set NodeChild = NodeCell.LastChild
            Else
                getSolCalInfo = CVErr(xlErrNA)
                Debug.Print DateSerial(y1, m1, d1) & n & ":윤달 아님"
                Exit Function
            End If
        End If
        With NodeChild
            y2 = .SelectSingleNode("solYear").Text
            m2 = .SelectSingleNode("solMonth").Text
            d2 = .SelectSingleNode("solDay").Text
            getSolCalInfo = DateSerial(y2, m2, d2)
        End With
    Else
        Debug.Print DateSerial(y1, m1, d1) & n & ": Response Not OK "
        getSolCalInfo = CVErr(xlErrValue)
    End If

End Function