엑셀 조건에 맞게 이미지 삽입 방법 있을까요?

@tu1541 님

Sub AutoInsertPic()

    Dim regex As Object
    Set regex = CreateObject("VBScript.RegExp")
    regex.Pattern = "([가-힣]+)-([0-9]+)"
    regex.Global = True
    
    imgPath = Application.GetOpenFilename("Picture, *.jpg;*.bmp;*.tif;*.gif;*.png")
    If imgPath = "False" Then: Exit Sub
    
    If regex.Test(imgPath) Then
        Dim rng As Range
        Dim matches As Object, fileName As String, fileNo As Integer
        Set matches = regex.Execute(imgPath)
        
        ' # 예를 들어, 파일경로가 C:\documents...\호랑이-01.jpg 라면..
        ' # 정규식으로 값을 구분하여 가져옴.
        
        fileName = matches(0).SubMatches(0) ' # 호랑이
        fileNo = CInt(matches(0).SubMatches(1)) ' # 01
        
        If fileName = "호랑이" Then
            ' # 파싱한 값이 호랑이 라는 이미지 이름이면, A1:W9 까지 No를 찾음
            Set rng = Range("A1:W9").Find(fileNo)
        ElseIf fileName = "고양이" Then
            ' # 파싱한 값이 고양이 라는 이미지 이름이면, A17:W25 까지 No를 찾음
            Set rng = Range("A17:W25").Find(fileNo)
        End If
        
        If Not rng Is Nothing Then
            ' # index No가 있다면 선택한 이미지 삽입 루틴
            Set rng = Cells(rng.Row + 1, rng.Column)
            With ActiveSheet.Pictures.Insert(imgPath).ShapeRange
                .LockAspectRatio = msoFalse
                .Height = rng.Height
                .Width = rng.Width
                .Left = rng.Left
                .Top = rng.Top
            End With
            
            Set rng = Nothing
        End If
        
    End If
Set regex = Nothing
End Sub

여러가지 방법으로 할 수 있겠으나

저는 정규식으로 구현해보았습니다.

주석은 달아놨으니 해보시고 이해 안되는 부분은 말씀해주세요.