엑셀 IFS 함수는 여러 조건을 순서대로 평가하여 처음 만족하는 조건의 결과를 반환하는 함수입니다.
=IFS(조건1, 결과1, [조건2], [결과2], ... , [TRUE], [그외결과])
- 조건-결과는 최대 127개의 쌍을 입력할 수 있습니다.
- 모든 조건을 만족하지 않으면 IFS 함수는 #N/A 오류를 반환하므로 TRUE 조건을 마지막에 추가하는 것을 권장합니다.
엑셀 IFS 함수는 여러 조건을 순서대로 비교하여 처음 만족하는 조건의 결과를 반환하는 함수입니다. 기존의 다중 조건 IF 함수를 더욱 편리하게 작성할 수 있으며, 특히 조건이 많아질수록 복잡해지는 IF 함수 구문을 효율적으로 대체할 수 있습니다.
=IFS(조건1,결과1,[조건2],[결과2],...,[TRUE],[그외결과]) / /각 조건을 비교하여 결과를 반환하고, 그렇지 않을 경우 그 외 결과를 반환합니다. =IF(조건1,결과1,IF(조건2,결과2,IF(조건3,결과3,그외결과))) / /각 조건을 비교하여 결과를 반환하고, 그렇지 않을 경우 그 외 결과를 반환합니다.
모든 조건이 FALSE일 경우 #N/A 오류를 반환하므로, 마지막에 TRUE 조건과 그외결과를 추가하는 것이 좋습니다.
=IFS(1>2,"A",2>3,"B",3>4,"C") / / 모든 조건을 만족하지 않으므로 #N/A 를 반환합니다. =IFS(1>2,"A",2>3,"B",3>4,"C",TRUE,"D") / / 모든 조건을 만족하지 않을 경우, 그 외 결과로 "D"를 반환합니다.
IFS 함수의 조건/결과쌍으로는 최대 127개까지 입력할 수 있습니다. 만약 비교할 조건이 5개 이상으로 넘어간다면, IFS 함수 대신 VLOOKUP 함수를 사용하는 것을 권장합니다.
아래 함수는 성적을 비교하여 "수우미양가"로 등급을 매깁니다. 만약 성적이 85점이라면, 결과로 "우"를 반환합니다.
=IFS(성적<60,"가",성적<70,"양",성적<80,"미",성적<90,"우",TRUE,"수") / / 성적이 85점일 경우, 결과로 "우"를 반환합니다.
아래 함수는 1~5점까지의 고객 만족도를 "매우만족, 만족, 보통, 불만족, 매우불만족"의 문자로 변경합니다. 예를 들어, 고객만족도가 3일 경우 결과값으로 "보통"을 반환합니다.
=IFS(만족도=5,"매우만족",만족도=4,"만족",만족도=3,"보통",만족도=2,"불만족",만족도=1,"매우불만족") / / 고객 만족도 점수를 문자로 변환합니다.
다음과 같이 IFS 함수를 작성하면 고객의 연간 구매액과 구매 횟수를 기반으로 고객 등급을 분류할 수 있습니다. 예를 들어, A1셀에 연간 구매액, B1셀에 구매 횟수가 작성된 경우 아래와 같이 함수를 작성합니다.
=IFS(A1>=100000,"VIP",AND(A1>=50000,B1>=10),"골드",AND(A1>=20000,B1>=5),"실버",B1>0,"일반",TRUE,"비활성") / / 연간구매액과 구매횟수에 따라 고객 등급을 분류합니다. / / 10만원 이상 : VIP / / 5만원 이상, 10회 이상 구매 : 골드 / / 2만원 이상, 5회 이상 구매 : 실버 / / 1회 이상 구매 : 일반 / / 나머지 : 비활성
IFS 함수는 여러 조건을 순차적으로 비교하는 반면, SWITCH 함수는 단일 수식의 결과를 여러 값과 비교합니다.
=SWITCH(평가식,결과1,반환값1,[결과2],[반환값2],...) / / 평가식의 결과에 따라 다른 값을 반환합니다. =SWITCH(만족도,1,"불만족",2,"보통",3,"만족) / / 만족도가 1일 경우 "불만족", 2일 경우 "보통", 3일 경우 "만족"을 반환합니다.
따라서 단일 수식에 대해 여러 조건을 비교해야 할 경우에는 SWITCH 함수를 사용하는 것이 효율적입니다.
IFS 함수는 엑셀 2019 이후 버전에서만 사용 가능합니다. 엑셀 이전 버전에서는 다중 조건 IF 함수를 사용해야 합니다.
만약 모든 조건을 만족하지 않고, 마지막에 TRUE 조건이 없으면 함수는 #N/A 오류를 반환합니다.
IFS 함수에는 최대 127개의 조건쌍을 입력할 수 있으며, 너무 많은 조건을 사용하면 성능에 영향을 줄 수 있습니다.
IFS 함수의 조건은 앞에서부터 순차적으로 평가되므로, 조건의 순서가 중요합니다.
=IFS(점수>=70,"C",점수>=80,"B",점수>=90,"A") / / 점수가 85점일 경우, 조건1에서 평가되어 잘못된 결과로 "C"가 반환됩니다. =IFS(점수>=90,"A",점수>=80,"B",점수>=70,"C") / / 점수가 85점일 경우 올바른 결과로 "B"를 반환합니다.
if 함수에서
만약 제가 원하는 값
ex =IFS(Z5<=-10,"..",Z5<=15,"Checking",TRUE,"A")
TRUE 일때 문자를 나타내는 것이 아닌(A가 아닌 다른 셀의 값 ex) A1? A2
을 나타나게 하는 것은 불가능 한가요?...
ex =IFS(Z5<=-10,"..",Z5<=15,"Checking",TRUE,"=A1+A2")
A1 =1 , A2 = 2 A1+A2 = 3, 3이 나타나게요~
IFS함수에서 각 구간별(조건별) 색깔을 바꾸는 것도 가능한가요?
=IFS(Z5<=-10,"..",Z5<=15,"Checking",TRUE,"=A1+A2")…
-> -10 이하는 파랑색, 15이하는 빨강색, True일 때는 검정색?
글을 남깁니다.
=IFS(D5*E5*B5<300000,300000,D5*E5*B5>=300000,D5*E5*B5,B5*D5*E5>1000000,1000000)
예를 들면 이런 수식이 있으면
제가 입력을 할때 셀을 곱한 값이 300000 미만이면
300000으로 출력은 되는데
셀을 곱한 값이
1000000을 초과하는 경우는 1000000으로
출력되게 하고 싶은데
1000000을 초과하는 경우
그대로 곱한 값이 출력이 되는데
이런 경우는 어떻게 해야 되나요?
=IF(E3=F3,1,2)가 맞나요? 그리고 E3값이 0보다 클때만 비교해서 결과를 받으려면 어떻해 해야 되나요??
=IF(AND(E3=F3,E3>0),1,2)
주차 시간별로 해당하는 시간대에 주차도장을 찍어드려야 하는 상황입니다.
입차시간 (A2) 출차시간(B2) 주차시간(C2) 주차권(D2)
- 30분 미만 --> "30분"
- 30분 이상 ~ 1시간 미만 --> "1시간"
- 1시간 이상 ~ 3시간 미만 --> "3시간"
- 3시간 초과 --> "3시간
상기 4가지 조건을 D2에 표기하는 함수식을 알 수 있을까요 ?구조로 작성해보세요.
팔린 상품을 각 판매처별로 보이게하려고
=IFS(COUNTIF(rng스마트스토어,G116),"스마트스토어",COUNTIF(rng쿠팡,G116),"쿠팡")
라는 함수를 만들었는데요,
rng스마트스토어(스마트스토어 품목들을 적어놓은 동적범위입니다) 안에 G116셀의 품목이 존재한다면 "스마트스토어"라는 텍스트를 넣고,
쿠팡 품목 범위에 팔린 G116 품목이 존재한다면 "쿠팡" 이라는 텍스트를 넣고싶어서 저렇게 만들었는데 제대로 작동을 안하네요,,
혹시 제가 잘못 이해하고 있는게 있는걸까요?ㅜㅜ
로 작성해보시겠어요?
감사합니다.
B2칸이 아직 빈칸일 경우 > 빈칸
B2칸에 A가 들어갈 경우 > O
B2칸에 A가 들어가지 않을 경우 > X 로 표시하려고 하는데
=if(iserror(find("A", B2))=False,"X",if(B2="","","O"))
이렇게 표시하는게 맞을까요?
어찌저찌 수식은 돌아가고 있습니다만
순서나 함수 서식을 정확히 했는지 모르겠어 문의드립니다.
다만 B2="" 조건이 맨 처음으로 들어가면 공식이 조금 더 깔끔해질 것 같습니다.