범위에서 첫 번째 일치 셀 주소 찾기 공식
지원 버전 자세히 보기
범위에서 행 우선 첫 일치 셀의 주소를 반환합니다.
인수 설명
01모든 버전 레거시 배열수식
{=ADDRESS ( MIN ( IF ( 범위=단어, ROW ( 범위 ) ) ), MIN ( IF ( ( 범위=단어 ) * ( ROW ( 범위 )=MIN ( IF ( 범위=단어, ROW ( 범위 ) ) ) ), COLUMN ( 범위 ) ) ) )}인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
02M365·Excel 2024 공식
=LET ( hitPos, XMATCH ( 단어, TOCOL ( 범위, 0, FALSE ) ), hitRow, QUOTIENT ( hitPos-1, COLUMNS ( 범위 ) ) + 1, hitCol, MOD ( hitPos-1, COLUMNS ( 범위 ) ) + 1, CELL ( "address", INDEX ( 범위, hitRow, hitCol ) ) )인수 설명 자세히 보기
동작 원리
01모든 버전 레거시 배열수식
IF 함수와 MIN 함수가 첫 일치 행을 먼저 고르고, 그 행 안의 첫 일치 열을 ADDRESS 함수로 결합합니다.
모든 버전 레거시 배열수식의 예제 시트에서 H8 셀이 $E$8을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
ROW 함수가 행 번호를 세로 배열로 반환합니다
ROW 함수는 예제 파일의 B8:E14 범위에 해당하는 실제 행 번호를 세로 배열로 반환합니다.
=ROW ( B8:E14 )
B8:E14의 각 행에 대응하는 실제 행 번호입니다. = {8;9;10;11;12;13;14}
세미콜론으로 구분되는 7행×1열 세로 배열입니다. IF 함수와 MIN 함수가 첫 일치 행을 찾습니다
IF 함수는 제주와 일치하는 E8·B9·D14에만 행 번호 8·9·14를 남깁니다. MIN 함수는 이 배열에서 가장 작은 행 번호 8을 반환합니다.
=MIN ( IF ( B8:E14=G8, ROW ( B8:E14 ) ) )
일치 셀에 남은 행 번호 중 최솟값을 계산합니다. = 8
첫 일치 셀이 있는 행 번호입니다. 첫 일치 행 안에서 열 번호를 찾습니다
행 번호가 8이면서 제주와 일치하는 셀만 남기면 E8만 조건을 만족합니다. 따라서 전체 범위의 최소 열 2가 아니라 첫 일치 행 안의 열 번호 5를 반환합니다.
=MIN ( IF ( ( B8:E14=G8 ) * ( ROW ( B8:E14 )=8 ), COLUMN ( B8:E14 ) ) )
첫 일치 행 8에서 일치하는 열 번호의 최솟값을 계산합니다. = 5
첫 일치 셀 E8의 열 번호입니다. ADDRESS 함수가 행과 열을 주소로 바꿉니다
ADDRESS 함수는 행 번호 8과 열 번호 5를 결합해 첫 일치 셀 E8의 절대 주소를 반환합니다.
=ADDRESS ( 8, 5 )
여덟 번째 행과 다섯 번째 열을 결합합니다. = "$E$8"
행 우선 첫 일치 셀의 절대 주소입니다. 02M365·Excel 2024 공식
TOCOL 함수가 범위를 행 우선 배열로 펼치고 XMATCH 함수와 INDEX 함수가 첫 위치를 참조하면 CELL 함수가 그 주소를 반환합니다.
M365·Excel 2024 공식의 예제 시트에서 H8 셀이 $E$8을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
TOCOL 함수가 범위를 행 우선으로 펼칩니다
TOCOL 함수의 세 번째 인수 FALSE는 각 행을 왼쪽에서 오른쪽으로 읽은 뒤 다음 행으로 이동합니다. 따라서 E8의 제주가 B9의 제주보다 먼저 놓입니다.
=TOCOL ( B8:E14, 0, FALSE )
B8:E14를 행 우선으로 펼칩니다. = {"서울";"부산";"대전";"제주";"제주";"광주";"인천";"수원";"대구";"울산";"성남";"고양";"청주";"전주";"포항";"창원";"춘천";"강릉";"목포";"여수";"파주";"김해";"구미";"천안";"양주";"안산";"제주";"군산"}
28개 셀을 행 우선으로 펼친 세로 배열입니다. XMATCH 함수가 첫 위치를 찾습니다
XMATCH 함수는 펼친 배열에서 제주와 처음 일치하는 항목을 찾아 위치 4를 반환합니다.
=XMATCH ( G8, TOCOL ( B8:E14, 0, FALSE ) )
첫 번째 제주는 펼친 배열의 네 번째 항목입니다. = 4
행 우선 배열에서 첫 일치 위치입니다. 위치 4를 범위 안의 행과 열로 바꿉니다
범위는 네 열이므로 QUOTIENT 함수는 위치 4가 범위의 첫 번째 행에 있음을 계산합니다. MOD 함수는 같은 위치가 범위의 네 번째 열에 있음을 계산합니다.
=( QUOTIENT ( 4-1, COLUMNS ( B8:E14 ) ) + 1 ) & ", " & ( MOD ( 4-1, COLUMNS ( B8:E14 ) ) + 1 )
위치 4의 범위 안 행 번호와 열 번호를 차례로 계산합니다. = "1, 4"
첫 일치 셀은 범위의 첫 번째 행, 네 번째 열에 있습니다. INDEX 함수와 CELL 함수가 주소를 반환합니다
INDEX 함수는 B8:E14의 첫 번째 행과 네 번째 열인 E8을 참조합니다. CELL 함수는 해당 참조를 절대 주소 문자열로 바꿉니다.
=CELL ( "address", INDEX ( B8:E14, 1, 4 ) )
범위의 E8 참조를 주소 문자열로 바꿉니다. = "$E$8"
행 우선 첫 일치 셀의 절대 주소입니다. 댓글 1
