퀴즈

[퀴즈_131] 숫자 배열 만들기

마

마법의손

8월 21일 조회 188

제한 : 없음.. M365, VBA, 파이썬, ....

숫자-배열-만들기_문제.xlsx 14 KB · 다운로드

exceller1 8월 21일

파워쿼리로 만들어 봅니다.

(1번은 퀴즈108번과 유사)

마

마법의손 작성자 8월 21일

@exceller1 님 헐 2번은.... 파일올려주세요

원

원조백수 8월 22일

무식한 수식으로
1번

=MAKEARRAY(C2,C2,LAMBDA(r,c,MAX(r,c)*2-1))

2번 : ㄹ자 배치에 대한 규칙을 못 찾아서 그냥 ifs로 처리함 ㅠㅠ

=LET(N, M2,
DC, TOCOL(MAKEARRAY(N,N,LAMBDA(r,c,IF(c<=r,r,NA()))),3),
WR, WRAPROWS(DC,8),
fX, LAMBDA(x,y, MAKEARRAY(4,3,LAMBDA(r,c,INDEX(x,y,IFS(r=1,c,(r=2)*(c=3),c+1,r=3,r*3-1-c,(r=4)*(c=1),r*2,TRUE,NA()))))),
RT, DROP(REDUCE("",SEQUENCE(ROWS(WR)), LAMBDA(t,r, VSTACK(t, fX(WR,r)))),1),
IFERROR(RT,"") )

마

마법의손 작성자 8월 22일

원조백수님의 WR배열에서 아이디어 얻어 처리했습니다.. (fX함수가 뭔지 분석할수 없어서^^;;)

WR에다 3열에 공백2줄 끼워넣고 끝에 2줄추가 .. 3줄짜리로 만들어보면 4N+3 인 곳마다.. 역순배열이어야 하므로 mod 4해서 3인곳마다 역순으로 sort해서 vstack했음...

=LET(N,M2,
WR,WRAPROWS(TOCOL(MAKEARRAY(N,N,LAMBDA(r,c,IF(c<=r,r,NA()))),3),8),
SP,HSTACK(TAKE(WR,,3),"","",DROP(WR,,3),"",""),
RS, IFNA(WRAPROWS(TOCOL(SP),3),""),
DROP(REDUCE("", SEQUENCE(ROWS(RS)), LAMBDA(a,r, VSTACK(a, IF( MOD(r,4)=3, SORT(INDEX(RS,r,),1,-1,TRUE), INDEX(RS,r,))))),1))

원

원조백수 8월 23일

@마법의손 님 그냥 ChooseCols로 순서 정리...

=LET(N,M2,
WR, WRAPROWS(TOCOL(MAKEARRAY(N,N,LAMBDA(r,c,IF(c<=r,r,NA()))),3),8),
SP, CHOOSECOLS(HSTACK(TAKE(WR,,3),"","",DROP(WR,,3),"",""),SEQUENCE(6),9,8,7,10,11,12),
IFNA(WRAPROWS(TOCOL(SP),3),""))

마

마법의손 작성자 8월 23일

@원조백수 님 저도 어제 이 생각 했어요 b^^)

=LET(N,M2,
WR,WRAPROWS(TOCOL(MAKEARRAY(N,N,LAMBDA(r,c,IF(c<=r,r,NA()))),3),8),
SP,HSTACK(TAKE(WR,,3),"","",CHOOSECOLS(WR,4,7,6,5,8),"",""),
IFNA(WRAPROWS(TOCOL(SP),3),""))