퀴즈

[퀴즈_76] 다중조건일 때 찾는 방법

마

마법의손

9월 29일 조회 758

(필드명 순서는 둘다 똑같다고 가정합니다..)

문제1

문제2 추가했어요..^^;;;;;;;

2024이상에선 byrow함수가 있어서 쉽게 처리하기가 가능하죠..
2021이하에선 어떻게 해야할까요?

다중 조건일때_문제.xlsx 29 KB · 다운로드

#MATCH 함수 #INDEX 함수 #퀴즈

라

라온보리 9월 29일

T6 =XLOOKUP(N6:N15&O6:O15&P6:P15&Q6:Q15&R6:R15&S6:S15,C6:C105&D6:D105&E6:E106&F6:F106&G6:G106&H6:H106,I6:I106,,0)
U6는 위 I6:I106 → B6:B106

라

라온보리 9월 29일

@라온보리 님 =XLOOKUP(BYROW(N6:S15,LAMBDA(iRw, TEXTJOIN("",,iRw))),BYROW(C6:H105,LAMBDA(iRw, TEXTJOIN("",,iRw))),I6:I105,,0)

라

라온보리 9월 29일

@라온보리 님 좌, 우측 테이블 열 순서가 같다면, 위와 같이~!

exceller1 9월 29일

XLOOKUP(1,($C$6:$C$105=M6)*($D$6:$D$105=N6)*($E$6:$E$105=O6)*($F$6:$F$105=P6)*($G$6:$G$105=Q6)*($H$6:$H$105=R6),$I$6:$I$105,,0)

파워쿼리로 한다면
힌트 : 쿼리병합

exceller1 9월 29일

@exceller1 님 이건 파워쿼리로 하면 편합니다.
조건1~조건20까지 shift로 한번에 지정되기에
그리고, 좌, 우측 테이블 열 순서가 섞여있어도 자동으로 값을 찾음

츠

츠츠°º⁰ 9월 29일

같은 방식입니다만, concat으로 묶어서도 해보았습니다.
가운데 콤마를 추가하여 textjoin효과를 더해보았습니다. ㅎ

AA6 =XLOOKUP(CONCAT($AC6:$AV6&","),
     BYROW($D$6:$W$105&",",CONCAT),$B$6:$B$105) 아래로복사

마

마법의손 작성자 9월 29일

삭제된 댓글입니다.

츠

츠츠°º⁰ 9월 29일

@마법의손 님 =INDEX($B$6:$B$105, MATCH(TRUE,MMULT($D$6:$W$105,{1;1;1;1;1;1;1;1;1;1;1;1;1;1;1;1;1;1;1;1})=SUM(AC6:AV6),0))
mmult를 떠올렸긴했는데, 행합계가 같은걸 찾는식으로 원초적으로 해봤는데,,, 안맞는거 같네요ㅎ...
올려주신 아래수식 학습하겠습니다. 감사합니다.

마

마법의손 작성자 9월 29일

2021이하시
아래 빨간부분은 조건의 갯수를 넣어주면 됩니다.

문제2
AA6  = SUMPRODUCT(B$6:B$105*(MMULT(($D$6:$W$105=$AC6:$AV6)*1,ROW($A$1:$A$20)^0)=20))

OR
= SUMPRODUCT(B$6:B$105*(MMULT(($D$6:$W$105=$AC6:$AV6)*1,
TRANSPOSE(COLUMN($AC6:$AV6)^0))=COLUMNS($AC6:$AV6)))