=MAP(D2:D11,LAMBDA(irng,
LET(xFT,FILTER(B2:B41,B2:B41<>""), xSch,IFERROR(SEARCH(xFT,irng),0), xSBa,SORTBY(xFT,xSch,1,LEN(xFT),-1), xSBb,SORTBY(xSch,xSch,1,LEN(xFT),-1), aFT,FILTER(xSBa,xSBb>0), bFT,FILTER(xSBb,xSBb>0),
ReVe,SCAN(0,SEQUENCE(ROWS(bFT)),LAMBDA(xAcc,iseq, LET(ibrng,INDEX(bFT,iseq), IF(ibrng>xAcc,ibrng+LEN(INDEX(aFT,iseq))-1,xAcc)))),
TEXTJOIN(", ",,FILTER(aFT,bFT>VSTACK(0,DROP(ReVe,-1)))))))

마

마법의손 작성자 9월 1일

@라온보리 님 빠르고 좋네요.. b^^) scan부분이 이해가 안되네요..노화진행형..T.T...

라

라온보리 9월 1일

@마법의손 님 현재 단어가 직전까지 채택된 단어의 끝(xAcc) 뒤에서 시작하면 현재 단어의 끝 위치로 xAcc 갱신,
현재 시작이 이전 끝 이내면 이전 xAcc 유지

더

더블유에이 9월 1일

=LET(r,표1[단어 목록], BYROW(D2:D11,LAMBDA(a,LET(v,IFERROR(ISNUMBER(SEARCH(r,a))*SEARCH(r,a),0),TEXTJOIN(", ",,,SORTBY(IF(v,r,""),v,1))))))

마

마법의손 작성자 9월 1일

삭제된 댓글입니다.

exceller1 9월 1일

@마법의손 님 저도 같은 오류가...

TEXTJOIN(",",TRUE,IFERROR(MID(F2,FIND($A$2:$A$41,F2),LEN($A$2:$A$41)),""))
2021버전은 여기까지..

박

박정호2 9월 2일

@exceller1 님 마법의손 퀴즈는 2024 이하는 참가 자격이 없다는걸 아직 모르셨습니까?

exceller1 9월 2일

@박정호2 님 진짜 몰라서 묻습니다. 맞다면 눈치 챙기겠습니다.

박

박정호2 9월 2일

@exceller1 님 당연히 조크죠. 하지만 실제로도 그렇습니다. 2024 이하 버전이 풀 수 있는 문제 낸걸 거의 본적 없습니다. 마법의 손님 취향도 좀 있는데 같은 성능을 가진 경우 상위 버전 답변만 채택하시더라구요. 하위 버전으로 짜는게 몇배는 어려운데요.

그렇기에 2024 이하는 손대지 않는게 좋습니다.

마

마법의손 작성자 9월 2일

@박정호2 님 그럴리가요.. 아래 답안 참고해보세요...~

더

더블유에이 9월 2일

@마법의손 님

=LET(r,표1[단어 목록],
f,LAMBDA(i,LET(v,IFERROR(ISNUMBER(SEARCH(r,i))*SEARCH(r,i),0),
l,LEN(r),
a,TEXTJOIN(", ",,,SORTBY(IF(v,r,""),v,1)),
b,SORTBY(HSTACK(v,IF(v,r,"")),v,1,l,-1),
c,REDUCE("",UNIQUE(INDEX(b,,1)),LAMBDA(x,y,TEXTJOIN(", ",,VSTACK(x,TAKE(FILTER(INDEX(b,,2),INDEX(b,,1)=y),1))))),c)),
BYROW(D2:D11,LAMBDA(d,f(d))))

마

마법의손 작성자 9월 2일

2021, 2019이하의 보조열 이용해서 푸는 법을 넣었습니다.. 참고하세요..~
퀴즈는 도구제한 없습니다.. 방법 제한 없습니다..
보조열은 좀 귀찮을 뿐 아주 훌륭한 도구입니다..
버전이 낮다고 푸는 걸 포기하지마세요..
같이 들어 있는 365버전 수식은 이 보조열을 수식으로 구현해서 만든 것 일 뿐입니다.
수식을 만들 때 365수식으로 바로 만든 경우도 많지만 파트별로 구현한후 본수식에 치환하는 경우도 많습니다.
보조열을 잘 구현할 수 있으면 나중에 m365으로 구현할때 별로 어렵지 않게 사용할 수 있을 겁니다..
배열좋아하는 취향....맞습니다..... 근데..배열아닌 문제가 별로 없습니다.

반대의견이 있을 경우 그러한 의견도 옳습니다..^^

컴마복원_답안.xlsx 30 KB

exceller1 9월 2일

@마법의손 님 버전별 답변 감사합니다. 열공모드..

박

박정호2 9월 3일

@마법의손 님 보조열을 써도 가능한 거였습니까?
ㄷㄷㄷㄷ
보기랑 달리 이거 난이도 엄청난 건데

박

박정호2 9월 3일

@마법의손 님 보조열을 써도 좀 정도가 있지 이건 너무한데요
차라리 포기하라고 말하는게 합리적이지 않을까요 이 정도면?
그리고 이 문제 보고 바로 포기했던 이유가
2019에는 filter 함수가 없어서 였습니다.
2019 해답이라는 공식을 봤는데 착각하신거 같습니다.
2019는 필터 함수가 없는
개쓰레기 입니다.

마

마법의손 작성자 9월 3일

@박정호2 님
앗...textjoin만 생각하다가 그렇게 되었네요.... FILTER없애고.....IF로 바꾸면 됩니다.
=TEXTJOIN(", ",1,IF($J$1:$AB$1="찾은단어", $J2:$AB2,""))
CTRL+SHIFT+ENTER
님은 불평이 넘 많아요....~ㅋㅋㅋ

박

박정호2 9월 3일

@마법의손 님 확실히 진짜 대단하십니다.
그런데 2019 쓰면 불만이 많을 수 밖에 없답니다.

마

마법의손 작성자 9월 3일

@박정호2 님 네.....당연히 불편합니다.....

박

박정호2 9월 3일

솔직히 2019 기준으로는
G2=SUBSTITUTE(TEXTJOIN(",",1,IF(ISNUMBER(FIND(B1:B101,D2)),B1:B101,"")),",0","")
(배열수식)
이 정도가 합리적입니다.
난이도가 너무 극악입니다.

마

마법의손 작성자 9월 3일

@박정호2 님 위에 달린 답변에도 있는 오류잖아요.....
"배추"를 "배", "배추"를 포함시키게 됨..
"양파"를 "파", "양"를 포함시키게 됨.
엄청 느리지만 오류없는 수식, 엄청 빠르지만 0.5%정도 틀릴 가능성이 있는 수식
어느걸 선택할건가요.