엑기스 함수 마스터 챌린지 2-1, 2-2

1. 엑셀 LET함수

= LET ( 이름1, 값1, [이름2], [값2], … , 계산식 )

=LET(a,1,b,2,a+b)

=LET(View1,10000,View3,25000,View3*(2+0.2*(View3/View1)+1.8*(View1/View3)+3*(View3/View1)))

=TEXTBEFORE(I10," ")

=LET(국가번호,TEXTBEFORE(I10," "),국가, XLOOKUP(국가번호,$M$10:$M$15,$N$10:$N$15),국가)

=LET(합계,SUM(Q10:S10),IF(합계>=100,합계*1.1,합계))

 

2. 엑셀 LAMBDA 함수

= LAMBDA ( 인수1, [인수2], … , 수식 )

 

→ FindGender  함수  :  8번째자리가 홀수면 남성, 그렇지 않으면 여성

=lambda(주민번호,if(isodd(mid(주민번호,8,1)),"남성","여성"))(G10) (확인 후 삭제)

수식-이름관리자 ( 새항목 - 이름 : FindGender  참조대상 : =lambda(주민번호,if(isodd(mid(주민번호,8,1)),"남성","여성") 메모 : 올바른 주민번호를 추출합니다.)

=FindGender(G10:G16)

 

3. 엑셀 TEXT 함수

= TEXT ( 값, 표시형식 )

=B10&" ("&TEXT(C10,"yyyy-mm-dd(aaa)")&")"

=B14&" ("&TEXT(C14,"#,##0원")&")"

→ PhoneNo : 휴대폰 번호 형식으로 출력하는 함수 만들기

=lambda(연락처, text(연락처,"000-0000-0000"))(f10) (확인 후 삭제)

수식-이름관리자 ( 새항목 - 이름 :PhoneNo  참조대상 : =lambda(연락처, text(연락처,"000-0000-0000")) 메모 : 휴대폰 번호 형식으로 출력합니다.)

=PHONENO(F10:F15)

 

4. 엑셀 TEXTSPLIT 함수

= TEXTSPLIT ( 텍스트, 열구분자, [행구분자], [빈칸무시], [일치옵션], [기본값] )

=IFERROR(TEXTSPLIT(TEXTJOIN("/",,B10:B15),">","/"),"")

=SORT(IFERROR(TEXTSPLIT(TEXTJOIN("/",,I10:I16),":","/")*1,TEXTSPLIT(TEXTJOIN("/",,I10:I16),":","/")),2,-1)

→ 선택한 범위 데이터를 "이메일 | 연락처 | 부서"로 가공하는 CLEANDATA 함수 만들기

=lambda(데이터, iferror(textsplit(textjoin(",",,데이터),"/",","),""))(F9:F15) (확인 후 삭제)

수식-이름관리자 ( 새항목 - 이름 :cleandata  참조대상 : =lambda(데이터, iferror(textsplit(textjoin(",",,데이터),"/",","),"")) 메모 : 선택한 범위  데이터를 "이메일, 연락처, 부서"로 가공합니다.)

=CLEANDATA(F9:F15)

 

5. 엑셀 배열 계산 : 엑셀에서 논리(TRUE, FALSE)는 각각 TRUE = 1, FALSE = 0 으로 계산됩니다.

① 모든 조건을 만족(AND) → 곱셈 / ② 둘 중 하나라도 만족(OR) → 덧셈

→부서 : O8(A) 이고 실적기준 : Q8(80)

=FILTER(K10:M20,(K10:K20=O8)*(M10:M20>=Q8))

 

6. 엑셀 TAKE 함수

= TAKE ( 범위, 추출할행수, [추출할열수] )

=TAKE(SORT(B10:D13,3,-1),3)

① 회의실을 선택하는 목록상자를 만듭니다. (O7셀)

=UNIQUE(L10:L39)

데이터-데이터유효성검사-목록, 회의실목록 범위#

② 기준날짜/회의실 선택 → 이후 일정 중 가장 가까운 5건 표시

=TAKE(SORT(FILTER(J10:K39,(J10:J39>=N8)*(L10:L39=O8)),1,1),5)

 

7. 엑셀 DROP 함수

= DROP ( 범위, 제거할행수, [제거할열수] )

최상/최하위 각 2명씩 제거

=DROP(DROP(SORT(DROP(B10:C20,-1),2,-1),2),-2)

 

8. 엑셀 HSTACK 함수

= HSTACK ( 범위1, [범위2], … )

=HSTACK(C10:C14,F10:F14,I10:I14)



=MYREPORT(K10:K24,M10:M24)

 

8.

=UNIQUE(B2:B1187)

데이터-데이터유효성검사-목록, B2#

=FILTER(A2:G1187,B2:B1187=L1)

=MYREPORT(INDEX(N3#,,3),INDEX(N3#,,7)) (choosecols 함수는 배열계산 이므로 에러가 나서  INDEX 함수를 사용한다)