=LET(
s, $C$2,
n, $C$3,
IFERROR(
MAKEARRAY(n, n,
LAMBDA(r,c,
LET(
k, r+c,
t, 2*n+2-k,
v, IF(k<=n+1,
1+(k-2)*(k-1)/2+(r-1),
n^2-t*(t-1)/2+1+(r-(k-n))),
s+v-1
))),
"입력 오류")
)

파워쿼리로 만들어 봅니다.

=LET(xSize,C3, xStt,C2, xRws,SEQUENCE(xSize), xCns,SEQUENCE(1,xSize), xSum,xRws+xCns,
Cnts,IF(xSum<=xSize+1,(xSum-2)*(xSum-1)/2,xSize^2-(2*xSize-xSum+1)*(2*xSize-xSum+2)/2), xIdx,IF(xSum<=xSize+1,xRws,xRws-(xSum-xSize)+1),
Cnts+xIdx+xStt-1)

처음에 만들었던 수식

=LET(Snum,$C$2, nCol,$C$3,
Data,REDUCE(SEQUENCE(,nCol*nCol),SEQUENCE(,nCol*2-1), LAMBDA(a,b,
LET(pb,IF(b<=nCol,b,2*nCol-b), HSTACK(DROP(a,,pb),
IF(b>nCol,VSTACK(EXPAND("",b-nCol),TOCOL(TAKE(TAKE(a,,pb),1))),TOCOL(TAKE(TAKE(a,,pb),1))))))),
Snum-1+TAKE(DROP(REDUCE("",SEQUENCE(ROWS(Data)),LAMBDA(a,b,VSTACK(a,TOROW(CHOOSEROWS(Data,b),3)))),1),,nCol))

​

다시 다른 방식으로 만든 수식

=LET(Snum,$C$2, nCol,$C$3,
Data,MAKEARRAY(nCol,nCol,LAMBDA(r,c,r+c&"/"&r&"/"&c)),tD,TOCOL(Data),
sData, SORTBY(tD,--TEXTBEFORE(tD,"/")), Snum-1+MATCH(Data, sData,0) )

​

=LET(N,5, S,7, MAKEARRAY(N,N,
  LAMBDA(r,c,LET(X,r+c-2, S-1 + IF(X<N, X*(X+1)/2+r, N*N-(2*N-2-X)*(2*N-1-X)/2-N+r )))))