안녕하세요~

H1=LET(
    hdr, HSTACK("직책", "이름", "직책", "이름"),
    src, B2:E11,
    h, ROWS(src),
    raw, VSTACK(CHOOSECOLS(src, 1, 2), CHOOSECOLS(src, 3, 4)),
    staff, SORT(FILTER(raw, (INDEX(raw, 0, 1)="직원") * (INDEX(raw, 0, 2)<>"")), 2),
    data, MAKEARRAY(h, 4, LAMBDA(r,c,
        IF(c <= 2,
            IF(r <= 3, INDEX(src, r, c), IFERROR(INDEX(staff, r-3, c), IF(c=1, "직원", ""))),
            IFERROR(INDEX(staff, r + (h-3), c-2), IF(c=3, "직원", ""))
        )
    )),
    VSTACK(hdr, data)
)

H16=LET(
    hdr, HSTACK("직책", "이름", "직책", "이름"),
    src, B17:E32,
    h, ROWS(src),
    raw, VSTACK(CHOOSECOLS(src, 1, 2), CHOOSECOLS(src, 3, 4)),
    staff, SORT(FILTER(raw, (INDEX(raw, 0, 1)="직원") * (INDEX(raw, 0, 2)<>"")), 2),
    data, MAKEARRAY(h, 4, LAMBDA(r,c,
        IF(c <= 2,
            IF(r <= 3, INDEX(src, r, c), IFERROR(INDEX(staff, r-3, c), IF(c=1, "직원", ""))),
            IFERROR(INDEX(staff, r + (h-3), c-2), IF(c=3, "직원", ""))
        )
    )),
    VSTACK(hdr, data)
)

=LET(r,B17:E32,a,SORT(WRAPROWS(TOCOL(r,1),2),2),
           c,ROWS(r),rs,ROWS(a),
           IFERROR(DROP(REDUCE("",SEQUENCE(ROUNDUP(rs/c,0)),LAMBDA(x,y,HSTACK(x,TAKE(DROP(a,(y-1)*c),c)))),,1),""))

=LET(xDB,VSTACK(B3:C5,SORT(VSTACK(B6:C17,D3:E17),2,1)), xRws,ROWS(B3:B17), xCns,COLUMNS(xDB), cCut,CEILING(ROWS(xDB)/xRws,1),
MAKEARRAY(xRws,xCns*cCut,LAMBDA(iRw,iCn, LET(rCut,QUOTIENT(iCn-1,xCns), xCn,MOD(iCn-1,xCns)+1, xRw,iRw+xRws*rCut,
IF(xRw>ROWS(xDB),"",INDEX(xDB,xRw,xCn))))))

더블유에이님 수식으로 공부해 보았습니다.  감사합니다.
여러칼럼을 옆으로 꼐속 붙이는거 궁금했었는데 이해했습니다.^^  

-관리자는 변동없는부분 확인하려고  이름순서를 바꿔봤습니다.

파워쿼리로 만들어 봅니다.

(관리자, 직원 추가시 순서 반영)

=LET(Area, B17:G32, nRow, ROWS(Area), nCol, COLUMNS(Area),
Data, SORT(WRAPROWS(TOCOL(Area), 2), {1,2}),
seq, TOROW(WRAPROWS(SEQUENCE(nCol), nCol / 2), , TRUE),
CHOOSECOLS(WRAPCOLS(TOCOL(Data, , TRUE), nRow), seq) & "")

​