오빠두엑셀 `2026 무료 챌린지` 오픈! 완주하고 수료증 받아가세요! 5년 연속 IT분야 베스트셀러! 「 진짜쓰는 실무엑셀 」로 2026년 공부 끝내기 엑셀이 막히셨나요? Q&A 게시판에서 바로 해결하세요.
메뉴
해결 엑셀2021윈도우

조건부 평균 구하기

꿈
꿈꾸는집사
3월 24일 조회 606

안녕하세요.

 

어제에 이어 또 질문드립니다.

 

첨부파일 C90~F93에 평균을 구하도록 수식을 입력했습니다.

 

C열에서 D90에 해당되면 F6~I87 평균을 구하고자했으나

 

결과는 조건에 맞는 F열의 평균만 나옵니다.

 

조언부탁드립니다.

통합 문서1.xlsx 18 KB · 다운로드
#함수·수식(일반) #통계 함수 #AVERAGE 함수

댓글 2

수
수메리안 채택된 답변 3월 24일

안녕하세요~

이렇게 해보세요.

[A1 전체평균]

C19=SUMPRODUCT((ISNUMBER(MATCH($C$6:$C$87, $C$90:$F$90, 0)))*$F$6:$I$87)
/SUMPRODUCT((ISNUMBER(MATCH($C$6:$C$87, $C$90:$F$90, 0)))*($F$6:$I$87<>""))

[A2 전체평균]

=SUMPRODUCT((ISNUMBER(MATCH($C$6:$C$87, $C$90:$F$90, 0)))*$J$6:$N$87)
/SUMPRODUCT((ISNUMBER(MATCH($C$6:$C$87, $C$90:$F$90, 0)))*($J$6:$N$87<>""))

[A3 전체평균]

=SUMPRODUCT((ISNUMBER(MATCH($C$6:$C$87, $C$90:$F$90, 0)))*$O$6:$R$87)
/SUMPRODUCT((ISNUMBER(MATCH($C$6:$C$87, $C$90:$F$90, 0)))*($O$6:$R$87<>""))

[A1 다중평균]

=SUMPRODUCT(($C$6:$C$87=D$90)*$F$6:$I$87)
/SUMPRODUCT(($C$6:$C$87=D$90)*($F$6:$I$87<>""))


A2, A3는
전체평균처럼
$F$6:$I$87 참조범위를 $J$6:$N$87, $O$6:$R$87 으로 변경하고,
A1:A3까지 범위 지정하고 우측으로 복사합니다.





마
마법의손 3월 24일

수메리안님 수식 통합.

C91
=LET(Data,FILTER($F$6:$R$87,LEFT($F$5:$R$5,2)=$B91),
유형,$C$6:$C$87,
IF(C$90="", AVERAGE(Data),
SUMPRODUCT((유형=C$90)*Data)/SUMPRODUCT((유형=C$90)*(Data<>""))))



질문답변 게시판의 최근 글

스크랩 완료