안녕하세요~

이렇게 해보세요.

1. M:S 표 등록
2. 보조열 P:S

[배송비채움]
P2=LET(x,$K3, IF(x<>"", x, LOOKUP(2,1/($K$3:K3<>""), $K$3:K3)))

[배송키]
Q2=TEXT($E3,"yy-mm-dd")&"|"&$P3

[업체키]
R2=LET(x,$F3, TRIM(SUBSTITUTE(CLEAN(x),CHAR(160)," ")))

[업체배송키]
S2=$Q3&"|"&$R3

[거리당배송비]

M2=LET(
  firstRow, ROW(INDEX([업체배송키],1)),
  i, ROW()-firstRow+1,

  fee, [@배송비채움],
  sk,  [@배송키],
  ok,  [@업체배송키],
  dist, INDEX(표1_3[거리(km)], i),

  skR,  [배송키],
  okR,  [업체배송키],
  distR,표1_3[거리(km)],

  okFirstVec, --(ROW(okR)=firstRow + MATCH(okR, okR, 0) - 1),
  grpDistU,   SUMPRODUCT((skR=sk)*okFirstVec*distR),
  grpOkCnt,   SUMPRODUCT((skR=sk)*okFirstVec),

  isFirst, COUNTIF(INDEX(okR,1):[@업체배송키], ok)=1,

  IF(fee=0, 0,
     IF(isFirst,
        IF(grpOkCnt>1,
           IF(grpDistU=0,0, fee * dist / grpDistU),
           IF(dist=0,0, fee / dist)
        ),
        ""
     )
  )
)

[수량별배송비]

N2=LET(
  firstRow, ROW(INDEX([배송키],1)),
  i, ROW()-firstRow+1,

  fee, [@배송비채움],
  sk,  [@배송키],
  qty, INDEX(표1_3[수량], i),

  skR,  [배송키],
  qtyR, 표1_3[수량],

  totQty, SUMPRODUCT((skR=sk)*qtyR),

  IF(fee=0, 0,
     IF(totQty=0, 0, fee / totQty)
  )
)

[총수량별배송비]

O2=LET(
  firstRow, ROW(INDEX([배송키],1)),
  i, ROW()-firstRow+1,

  unitFee, [@수량별배송비],
  qty,     INDEX(표1_3[수량], i),

  IF(unitFee=0, 0, unitFee * qty)
)

안녕하세요. 답변 감사드립니다

해주시 코드로 작성을 해봤는데, 배송비가 있는 부분은 수식이 활성화되는데

그 외의 부분은 에러가 발생하네요 ㅠㅠ 왜그럴까요?