vba 코딩으로는 다음과 같이 할 수 있습니다.

Option Explicit

Public Sub 돌봄무상유상마킹_집계()

Dim ws As Worksheet
Dim eRow As Long
Dim r As Long

Dim isCare As Boolean
Dim isFree As Boolean
Dim isPay As Boolean

Dim cntTot As Long
Dim cntCare As Long
Dim cntFree As Long
Dim cntPay As Long
Dim cntCF As Long
Dim cntCP As Long
Dim cntFP As Long
Dim cntCFP As Long

Dim msg As String

On Error GoTo EH

Set ws = ActiveSheet

eRow = ws.Cells(ws.Rows.Count, "C").End(xlUp).Row
If eRow < 3 Then Exit Sub

Application.ScreenUpdating = False
Application.EnableEvents = False
Application.Calculation = xlCalculationManual

'// 기존 마킹 삭제
ws.Range("L3:N" & eRow).ClearContents

'// 학생 1명 = 4행 블록
For r = 3 To eRow Step 4

isCare = False
isFree = False
isPay = False

'// 이름(B열) 색상 → 돌봄
isCare = HasFill_(ws.Cells(r, "B"))

'// 과목(E:I) 색상 → 무상/유상
CheckFee_ ws, r, isFree, isPay

'// 마킹
If isCare Then ws.Cells(r, "L").Value = "○"
If isFree Then ws.Cells(r, "M").Value = "○"
If isPay Then ws.Cells(r, "N").Value = "○"

'// 집계
cntTot = cntTot + 1

If isCare Then cntCare = cntCare + 1
If isFree Then cntFree = cntFree + 1
If isPay Then cntPay = cntPay + 1

If isCare And isFree Then cntCF = cntCF + 1
If isCare And isPay Then cntCP = cntCP + 1
If isFree And isPay Then cntFP = cntFP + 1

If isCare And isFree And isPay Then cntCFP = cntCFP + 1

Next r

msg = "[구분]" & vbTab & "[인원수]" & vbCrLf & _
"총 인원" & vbTab & cntTot & vbCrLf & _
"돌봄" & vbTab & cntCare & vbCrLf & _
"무상" & vbTab & cntFree & vbCrLf & _
"유상" & vbTab & cntPay & vbCrLf & _
"돌봄/무상 중복" & vbTab & cntCF & vbCrLf & _
"돌봄/유상 중복" & vbTab & cntCP & vbCrLf & _
"무상/유상 중복" & vbTab & cntFP & vbCrLf & _
"돌봄/무상/유상 중복" & vbTab & cntCFP

MsgBox msg, vbInformation, "돌봄/무상/유상 집계"

XIT:
Application.ScreenUpdating = True
Application.EnableEvents = True
Application.Calculation = xlCalculationAutomatic
Exit Sub

EH:
Application.ScreenUpdating = True
Application.EnableEvents = True
Application.Calculation = xlCalculationAutomatic
MsgBox "돌봄/무상/유상 집계 오류: " & Err.Description, vbExclamation

End Sub

Private Sub CheckFee_(ByVal ws As Worksheet, ByVal sRow As Long, _
ByRef isFree As Boolean, ByRef isPay As Boolean)

Dim r As Long
Dim c As Long
Dim txt As String

For r = sRow To sRow + 3
For c = 5 To 9 '// E:I

txt = Trim$(CStr(ws.Cells(r, c).Value))

'// 과목명이 있는 셀만 판정
If Len(txt) > 0 Then
If HasFill_(ws.Cells(r, c)) Then
isFree = True
Else
isPay = True
End If
End If

If isFree And isPay Then Exit Sub
Next c
Next r

End Sub

Private Function HasFill_(ByVal c As Range) As Boolean

Dim cc As Range
Set cc = c.MergeArea.Cells(1, 1)

If cc.Interior.Pattern = xlNone Then
HasFill_ = False
ElseIf cc.Interior.ColorIndex = xlColorIndexNone Then
HasFill_ = False
Else
HasFill_ = True
End If

End Function

※ 매크로를 처음 사용해 보신다면,
인터넷에서 다운받은 매크로 파일은
보안상 기본적으로 차단되어 있어서, 바로 실행하면 매크로가 막히는 경우가 많습니다.

아래와 같이 조치하세요.
[파일 속성에서 차단 해제]
파일을 다운로드 받은 폴더에서 파일 → 마우스 오른쪽 클릭 → 속성
“차단 해제” 체크 후 [확인]

[매크로 보안 설정 확인]
Excel 실행 → [파일] → [옵션] → [보안센터] → [보안센터 설정] → [매크로 설정]
"VBA 매크로 사용" 체크 후 [확인]

(선택)[신뢰할 수 있는 위치에 저장]
자주 쓰는 매크로 파일이라면,
[파일] → [옵션] → [보안센터] → [신뢰할 수 있는 위치]
매크로 파일이 있는 폴더를 추가 후, 그 폴더 안에서 매크로 파일을 실행하면 항상 허용이 됩니다.