H4=IF(TRIM(CLEAN(B2))="", "B2셀에 실습생 이름을 입력하세요",
IFERROR(
QUERY(
REDUCE({"일자","지도자","이름"}, SEQUENCE(10, 1, 3), LAMBDA(acc, col, 
VSTACK(acc, 
HSTACK(
'배정명단'!A2:A500, 
ARRAYFORMULA(IF(LEN('배정명단'!A2:A500), IF(col<=7, "최문희", "김경아"), "")), 
ARRAYFORMULA(TRIM(CLEAN(INDEX('배정명단'!A2:L500, , col))))
)
)
)),
"SELECT Col1, Col2 WHERE Col3 = '" & TRIM(CLEAN(B2)) & "' ORDER BY Col1 ASC LABEL Col1 '실습일자', Col2 '담당지도자'", 1
),
"해당 실습생의 배정 내역이 없습니다."
)
)

이렇게 적용했으니 확인해 보세요~

​

M4=ARRAYFORMULA(
LET(
name, TRIM(CLEAN(B2)),
raw, REDUCE({"일자","지도자","이름"}, SEQUENCE(10, 1, 3), LAMBDA(acc, col, 
VSTACK(acc, 
HSTACK(
'배정명단'!A2:A500, 
IF(LEN('배정명단'!A2:A500), INDEX('배정명단'!A1:N1, , col), ""), 
TRIM(CLEAN(INDEX('배정명단'!A2:N500, , col)))
)
)
)),
filtered, IF(name="", "", QUERY(raw, "SELECT Col1, Col2 WHERE Col3 = '" & name & "' ORDER BY Col1 ASC", 0)),

IF(name="", "B2셀에 실습생 이름을 입력하세요",
IF(ISERROR(INDEX(filtered, 1, 1)), "해당 실습생의 배정 내역이 없습니다.",
VSTACK(
{"시수", "실습일자", "담당지도자(교시)"},
HSTACK(
SEQUENCE(ROWS(filtered)), 
TEXT(CHOOSECOLS(filtered, 1), "mm/dd"),
CHOOSECOLS(filtered, 2)
)
)
)
)
)
)

​

확인해 보세요.