매크로는
이렇게 생성합니다.

1. Alt + F11 또는 개발도구 → Microsoft Visual Basic for Application 을 열고,

2. 좌측 프로젝트 창에서 해당 파일 → 마우스 오른쪽 버튼 → 삽입 : 모듈 추가

3. Module 1 클릭 → 오른쪽 화면에 아래 코딩을 넣습니다.

Option Explicit

'// ============================================================
'// MkAll
'// - A:B:C:D 계층 데이터를 읽어 폴더 일괄 생성
'// - 상위값 누적 방식
'// - 배열 기반 처리로 속도 개선
'// ============================================================
Public Sub MkAll()

Dim ws As Worksheet
Dim arr As Variant

Dim bPath As String
Dim fPath As String

Dim eRow As Long
Dim i As Long

Dim vA As String
Dim vB As String
Dim vC As String
Dim vD As String

Dim crtCnt As Long
Dim errMsg As String

Dim fDlg As FileDialog

On Error GoTo EH

Set ws = ActiveSheet
Set fDlg = Application.FileDialog(msoFileDialogFolderPicker)

With fDlg
.Title = "루트 폴더를 선택하세요"
.InitialFileName = "C:\"
.AllowMultiSelect = False

If .Show <> -1 Then Exit Sub

bPath = .SelectedItems(1)
End With

If Right$(bPath, 1) <> "\" Then bPath = bPath & "\"

'// 마지막 행 : A:D 중 최대 사용행
eRow = MaxRow_(ws, 1, 4)
If eRow < 2 Then
MsgBox "데이터가 없습니다.", vbExclamation
Exit Sub
End If

'// 배열로 일괄 로드
arr = ws.Range("A2:D" & eRow).Value2

For i = 1 To UBound(arr, 1)

'// A 갱신 시 하위 초기화
If Len(Trim$(CStr(arr(i, 1)))) > 0 Then
vA = ClnNm_(CStr(arr(i, 1)))
vB = ""
vC = ""
End If

'// B 갱신 시 하위 초기화
If Len(Trim$(CStr(arr(i, 2)))) > 0 Then
vB = ClnNm_(CStr(arr(i, 2)))
vC = ""
End If

'// C 갱신
If Len(Trim$(CStr(arr(i, 3)))) > 0 Then
vC = ClnNm_(CStr(arr(i, 3)))
End If

'// D는 현재행 기준
vD = ClnNm_(CStr(arr(i, 4)))

'// 최소 A/B는 있어야 생성
If vA <> "" And vB <> "" Then

If vC <> "" And vD <> "" Then
fPath = bPath & vA & "\" & vB & "\" & vC & "\" & vD

ElseIf vC <> "" Then
fPath = bPath & vA & "\" & vB & "\" & vC

Else
fPath = bPath & vA & "\" & vB
End If

If MkFdr_(fPath) Then
crtCnt = crtCnt + 1
Else
errMsg = errMsg & vbCrLf & fPath
End If

End If

Next i

If Len(errMsg) = 0 Then
MsgBox "폴더 생성 완료!" & vbCrLf & _
"처리 경로 수 : " & Format$(crtCnt, "#,##0"), vbInformation
Else
MsgBox "일부 경로 생성에 실패했습니다." & vbCrLf & _
"성공 : " & Format$(crtCnt, "#,##0") & vbCrLf & _
"실패 경로 : " & vbCrLf & errMsg, vbExclamation
End If

Exit Sub

EH:
MsgBox "오류: " & Err.Description, vbCritical

End Sub

'// ============================================================
'// MkFdr_
'// - 전체 경로를 "\" 기준으로 잘라 단계별 생성
'// - 이미 존재하면 건너뜀
'// - 성공/실패 Boolean 반환
'// ============================================================
Private Function MkFdr_(ByVal fPath As String) As Boolean

Dim arr() As String
Dim cur As String
Dim i As Long

On Error GoTo EH

arr = Split(fPath, "\")

'// 예: C:\Test\A\B
'// arr(0)="C:" arr(1)="Test" ...
cur = arr(0) & "\"

For i = 1 To UBound(arr)
If Len(arr(i)) > 0 Then
cur = cur & arr(i) & "\"

If Dir(cur, vbDirectory) = "" Then
MkDir cur
End If
End If
Next i

MkFdr_ = True
Exit Function

EH:
MkFdr_ = False

End Function

'// ============================================================
'// MaxRow_
'// - 지정 열 범위 중 최대 마지막 행 반환
'// ============================================================
Private Function MaxRow_(ByVal ws As Worksheet, _
ByVal c1 As Long, _
ByVal c2 As Long) As Long

Dim i As Long
Dim r As Long
Dim mx As Long

For i = c1 To c2
r = ws.Cells(ws.Rows.Count, i).End(xlUp).Row
If r > mx Then mx = r
Next i

MaxRow_ = mx

End Function

'// ============================================================
'// ClnNm_
'// - 폴더명 금지문자 제거/치환
'// ============================================================
Private Function ClnNm_(ByVal s As String) As String

Dim bad As Variant
Dim i As Long

s = Trim$(s)

bad = Array("\", "/", ":", "*", "?", """", "<", ">", "|")

For i = LBound(bad) To UBound(bad)
s = Replace$(s, bad(i), "_")
Next i

Do While InStr(s, " ") > 0
s = Replace$(s, " ", " ")
Loop

ClnNm_ = s

End Function