이런걸 원하시는 걸까요?

K24=G13*1000/(2*COS(RADIANS(H13)))
L24=INDEX(P1:P1000,1/SUMPRODUCT(MAX((1/ROW(Q6:S10))*(Q6:S10>K24)*(Q5:S5=I13))))


I26=G35*1000*SIN(RADIANS(I35))/SIN(RADIANS(H35)+RADIANS(I35))
J26=G35*1000*SIN(RADIANS(H35))/SIN(RADIANS(H35)+RADIANS(I35))
K26=MAX(I26,J26)
L26=INDEX(P1:P1000,1/SUMPRODUCT(MAX((1/ROW(Q6:S10))*(Q6:S10>K26)*(Q5:S5=I13))))

지금 제가 파일이 안 올려줘서

답만 구한다고 할때
사이값 같은경우

=INDEX(P1:P1000,1/SUMPRODUCT(MAX((1/ROW(Q6:S10))*(Q6:S10>(G13*1000/(2*COS(RADIANS(H13)))))*(Q5:S5=I13))))

사이값 다른 경우

=INDEX(P1:P1000,1/SUMPRODUCT(MAX((1/ROW(Q6:S10))*(Q6:S10>MAX(G35*1000*SIN(RADIANS(I35))/SIN(RADIANS(H35)+RADIANS(I35)),G35*1000*SIN(RADIANS(H35))/SIN(RADIANS(H35)+RADIANS(I35))))*(Q5:S5=I13))))

​

​

근데 제가 뭘 알고 한게 아니라 순수하게 수학으로 한거라 확인해 보시면서 하셔야 해요.
전 내용은 모릅니다. 써 있는 공식대로 한거에요

안녕하세요~

이렇게 한번 해보세요.

[사잇각 동일]

=IF(COUNTA($A$3:$C$3)=3,
LET(
ton, $A$3,
ang, $B$3,
typ, $C$3,
req, ton*1000/(2*COS(RADIANS(ang))),
w, $K$3:$K$7,
cap, CHOOSECOLS($L$3:$N$7, XMATCH(typ, $L$2:$N$2)),
XLOOKUP(req, cap, w, "", 1)
),"")

[사잇각이 다를 경우]

=IF(COUNTA($A$14:$D$14)=4,
LET(
하중, $A$14,
각도1, $B$14,
각도2, $C$14,
방식, $D$14,
장력1, 하중*1000*SIN(RADIANS(각도2))/SIN(RADIANS(각도1+각도2)),
장력2, 하중*1000*SIN(RADIANS(각도1))/SIN(RADIANS(각도1+각도2)),
필요장력, MAX(장력1,장력2),
슬링폭범위, $K$3:$K$7,
안전하중열, CHOOSECOLS($L$3:$N$7, XMATCH(방식, $L$2:$N$2)),
XLOOKUP(필요장력, 안전하중열, 슬링폭범위, "", 1)
),"")

도움에 감사 합니다