네,

아주 잘 코딩하셨네요^^

다만, 
이 부분은 한 행당 셀을 12번 호출을 해서
n행이면 12* n 번 호출을 합니다.  

' 데이터 출력
    Dim rowIdx As Long: rowIdx = 2: Dim k As Variant
    For Each k In dic.Keys
        With wsTo
            .Cells(rowIdx, 1).Value = dic(k)(0)
            .Cells(rowIdx, 2).Formula = "=INT((SUBSTITUTE(C" & rowIdx & ",""월"","""")-1)/3)+1 & ""분기"""
            .Cells(rowIdx, 3).Value = val(Replace(dic(k)(1), "월", "")) & "월"
            .Cells(rowIdx, 4).Value = dic(k)(2)
            .Cells(rowIdx, 5).Value = dic(k)(3)
            .Cells(rowIdx, 6).Formula = "=IF(D" & rowIdx & "=0,0,E" & rowIdx & "/D" & rowIdx & ")"
            .Cells(rowIdx, 7).Value = dic(k)(4)
            .Cells(rowIdx, 8).Value = dic(k)(5)
            .Cells(rowIdx, 9).Formula = "=IF(G" & rowIdx & "=0,0,H" & rowIdx & "/G" & rowIdx & ")"
            .Cells(rowIdx, 10).Formula = "=D" & rowIdx & "+G" & rowIdx
            .Cells(rowIdx, 11).Formula = "=E" & rowIdx & "+H" & rowIdx
            .Cells(rowIdx, 12).Formula = "=IF(J" & rowIdx & "=0,0,K" & rowIdx & "/J" & rowIdx & ")"
        End With
        rowIdx = rowIdx + 1
    Next k

​

이를 메모리에서 연산하고 
바로 한번에 기록할 수 있도록 아래와 같이 수정하면
성능이 많이 올라갑니다.

   Dim rowIdx As Long
    Dim n As Long, i As Long
    Dim arrV As Variant
    Dim keys As Variant
    Dim rng As Range
    
    rowIdx = 2
    n = dic.Count
    If n = 0 Then GoTo DataOut_Exit
    
    ReDim arrV(1 To n, 1 To 12)   '// 값만 사용
    keys = dic.keys               '// 0-base
    
    For i = 1 To n
        tmp = dic(keys(i - 1))
    
        arrV(i, 1) = tmp(0)                                  '// 회신과
        arrV(i, 3) = val(Replace(tmp(1), "월", "")) & "월"   '// 월(중요: 값으로 유지)
        arrV(i, 4) = tmp(2)                                  '// 응급의뢰
        arrV(i, 5) = tmp(3)                                  '// 24시간내회신
        arrV(i, 7) = tmp(4)                                  '// 비응급의뢰
        arrV(i, 8) = tmp(5)                                  '// 48시간내회신
    Next i
    
    Set rng = wsTo.Range("A2").Resize(n, 12)
 
    rng.Value2 = arrV
    
    wsTo.Range("B2").Resize(n, 1).FormulaR1C1 = _
        "=INT((SUBSTITUTE(RC[1],""월"","""")-1)/3)+1 & ""분기"""
    
    wsTo.Range("F2").Resize(n, 1).FormulaR1C1 = _
        "=IF(RC[-2]=0,0,RC[-1]/RC[-2])"
    
    wsTo.Range("I2").Resize(n, 1).FormulaR1C1 = _
        "=IF(RC[-2]=0,0,RC[-1]/RC[-2])"
    
    wsTo.Range("J2").Resize(n, 1).FormulaR1C1 = _
        "=RC[-6]+RC[-3]"
    
    wsTo.Range("K2").Resize(n, 1).FormulaR1C1 = _
        "=RC[-6]+RC[-3]"
    
    wsTo.Range("L2").Resize(n, 1).FormulaR1C1 = _
        "=IF(RC[-2]=0,0,RC[-1]/RC[-2])"
    
    rowIdx = n + 2
    
DataOut_Exit:

응원의 박수를 보내드립니다~