안녕하세요~

아래 첨부파일로 활용해 보세요.

Option Explicit

Public Sub 입고라벨출력()

    Dim ws As Worksheet, ws1 As Worksheet
    Dim eRow As Long, r As Long
    Dim a As Variant
        
    Set ws = ActiveSheet
    Set ws1 = ThisWorkbook.Worksheets("결과-1")
    
    eRow = ws.Cells(ws.Rows.Count, "B").End(xlUp).Row
    If eRow < 4 Then Exit Sub
    
    '// B4:G를 통째로 배열로 로드(1회 I/O)
    a = ws.Range("B4:G" & eRow).Value  '// (1..n, 1..6)
    
    Application.ScreenUpdating = False
        
    For r = 1 To UBound(a, 1)
        
        '// 완전 빈 행 스킵(원치 않으면 삭제)
        If Application.WorksheetFunction.CountA(Application.Index(a, r, 0)) = 0 Then GoTo NX
        
        With ws1
            .Range("B1").Value = a(r, 1)  '// 입고일 (B)
            .Range("B4").Value = a(r, 2)  '// 상품명 (C)
            .Range("B2").Value = a(r, 3)  '// 내품바코드 (D)
            .Range("B5").Value = a(r, 4)  '// 박스입수량 (E)
            .Range("B6").Value = a(r, 5)  '// QTY (F)
            .Range("B3").Value = a(r, 6)  '// 유통기한 (G)
        End With
        
        ws1.PrintPreview        '// 실제 출력시에는 앞에 ' (어퍼스트로피) 추가
        'ws1.PrintOut           '// 실제 출력시에는 앞에 ' (어퍼스트로피) 제거
        
NX:
    Next r
    
    Application.ScreenUpdating = True
    MsgBox "라벨 출력 완료 (" & UBound(a, 1) & "건)", vbInformation

End Sub

네, 
원하시는 부분을 이해했습니다.



다시 첨부하니 살펴보세요~