5년 연속 IT분야 베스트셀러! 「 진짜쓰는 실무엑셀 」로 2026년 공부 끝내기 오빠두엑셀 `2026 무료 챌린지` 오픈! 완주하고 수료증 받아가세요! 엑셀이 막히셨나요? Q&A 게시판에서 바로 해결하세요.
메뉴
미해결 M365윈도우11

원본데이터에서 원하는 행의 순서대로 데이터 추출

파
파이팅
11월 22일 조회 765

아래 C2:E11 원본데이터에서

 

H2:H8의 순서대로 원본데이터 추출하는 방법을 알고싶네요~

 

 

 

#MATCH 함수 #INDEX 함수

댓글 12

마
마법의손 11월 22일

Match(D열범위, h열범위,0)한,값으로 c:e열범위를 sortby하면 됩니다

파
파이팅 작성자 11월 23일

@마법의손 님 =SORTBY(C2:E11,MATCH(D2:D11,H2:H8,0))로 했을 때 h열에 있는 순서대로 추출이 되긴하는데, h열에 없는 내용까지 같이 추출됩니다 h열에 없는 내용에 대해서는 제외하고 추출하는 방법이 있을까요?

라
라온보리 11월 23일

=LET(rngAl,C2:E11, cnD,INDEX(rngAl,,2), xOrder,H2:H8, DROP(REDUCE("",xOrder,LAMBDA(xAcc,irng,
VSTACK(xAcc,FILTER(rngAl,cnD=irng)))),1))

파
파이팅 작성자 11월 25일

@라온보리 님 감사합니다!

마
마법의손 11월 23일
삭제된 댓글입니다.
파
파이팅 작성자 11월 25일

@마법의손 님 감사합니다, 큰 도움됐습니다 ^^

츠
츠츠°º⁰ 11월 23일

CDE값에서,  D열중 소닉프레셔 제외처리후, H열순서대로 정렬

J2 =LET(r,$C$2:$E$11,   s,$H$2:$H$8,
    d,FILTER(r,  COUNTIF(s,INDEX(r,,2))), 
    SORTBY(d,  MATCH(INDEX(d,,2),s,0)))

수정_제외후 정렬.xlsx 12 KB
파
파이팅 작성자 11월 25일

@츠츠°º⁰ 님 감사합니다!

수
수미수 11월 23일

파
파이팅 작성자 11월 25일

@수미수 님 감사합니다!

박
박정호2 11월 23일

=IFERROR(INDEX(C1:E101,MOD(AGGREGATE(15,6,ROW(D1:D101)/(D1:D101<>"")+MATCH(D1:D101,H1:H101,0)*1000,ROW(A1:C11)),1000),COLUMN(A1:C11)),"")

파
파이팅 작성자 11월 25일

@박정호2 님 감사합니다!

질문답변 게시판의 최근 글

스크랩 완료