수식에 iferror를 일괄적으로 넣는 방법이 있을까요?

안녕하세요~

셀수식이나 기타 다른 방법은
실제적으로 어럽다고 보입니다.

VBA로 코딩했으니
한번 적용해 보세요~

Sub IFERROR감싸기()

    Dim ws As Worksheet
    Dim rng As Range
    Dim cell As Range
    Dim f As String
    
    Set ws = ActiveSheet
    
    '// 범위 입력받기
    On Error Resume Next
    Set rng = Application.InputBox( _
        Prompt:="IFERROR로 감쌀 범위를 선택하세요:", _
        Title:="범위 선택", _
        Type:=8)  '// Type:=8 은 Range 타입
    On Error GoTo 0
    
    '// 취소 버튼 누르면 종료
    If rng Is Nothing Then
        MsgBox "취소되었습니다.", vbInformation
        Exit Sub
    End If
    
    '// 성능 최적화
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    Application.EnableEvents = False
    
    On Error GoTo ErrorHandler
    
    '// 선택한 범위의 각 셀 처리
    For Each cell In rng
        If cell.HasFormula Then
            f = cell.Formula2
            
            '// IFERROR 체크
            If Not (UCase$(f) Like "=IFERROR(*") Then
                cell.Formula2 = "=IFERROR(" & Mid$(f, 2) & ",0)"
            End If
        End If
    Next cell
    
    MsgBox "완료: " & rng.Address & " 범위의 수식을 IFERROR로 감쌌습니다.", vbInformation
    
ErrorHandler:
    Application.ScreenUpdating = True
    Application.Calculation = xlCalculationAutomatic
    Application.EnableEvents = True
    
    If Err.Number <> 0 Then
        MsgBox "오류 발생: " & Err.Description, vbCritical
    End If
    
End Sub

​