메뉴
해결 HOT 엑셀2019윈도우11

비어있는 셀 제외하고 값이 있는 셀의 제목만 찾기

코
코알라
9월 8일 조회 649
제안번호별로 빈칸을 제외하고 순서대로 제목을 자동으로 채우고 싶습니다..

ㅠㅠ



제안 (2)의 각 항목별 점수가 있는데 순서대로 점수의 제목을 채울 수 있을까요..?

결과 표의 제목을 참조해서 "제안 (1) ~ 제안 (7)"까지 자동으로 항목을 채워야 합니다.

엑셀 질문.xlsx 11 KB · 다운로드
#함수·수식(일반)

댓글 21

박
박정호2 9월 8일
고유값 찾기로 검색하시면 되고
2019로는 극도로 어려운 문제 입니다.
코
코알라 작성자 9월 8일
@박정호2 님 2019로는 어려군요...ㅠㅠ
빠른 답변 감사합니다..
덕분에 빨리 노가다라도 할 수 있겠습니다.
박
박정호2 9월 8일
물론 저걸 할 수는 있지만
왠만하면 2021 로 하세요. 
코
코알라 작성자 9월 8일
@박정호2 님 빠른 답변 감사합니다..
혹시 2021로는 어떻게 할 수 있나요..?
지금 버전은 안되지만 나중에 쓸 수 있게 공부라도 하게요..
박
박정호2 9월 8일
2021 로는 transpose 하신 다음 그걸 filter 하면 간단하게 됩니다.
2019로는 CES 사용하는 버전으로 만들어 드릴께요 잠시만
라
라온보리 9월 8일
제안 (1)의 경우
=IFERROR(INDEX($C$1:$O$1,AGGREGATE(15,6,(COLUMN($C$2:$O$2)-COLUMN($C$2)+1)/($C$2:$O$2<>""),ROW(A1))),"")
↓드래그
박
박정호2 9월 8일
@라온보리 님 진짜 고수시네요. 이걸 사용하시면 됩니다.
라
라온보리 9월 8일
@라온보리 님 365버전
=VSTACK(TRANSPOSE(B2:B8),LET(cnFN,$C$1:$O$1, rng,$C$2:$O$8, MAKEARRAY(6,ROWS(rng),LAMBDA(iRw,iCn,
LET(xTC,TOCOL(FILTER(cnFN,INDEX(rng,iCn,)<>""),3), IF(iRw<=ROWS(xTC),INDEX(xTC,iRw),""))))))
박
박정호2 9월 8일
@라온보리 님 2021 버전으로는 훨씬 쉬워 보이는데??? 왜 이렇게??
라
라온보리 9월 8일
@박정호2 님 ??
박
박정호2 9월 9일
@라온보리 님 보통 2021 이상 함수가 훨씬 짧고 쉽게 나오는데 오히려 2019 함수 보다 복잡하게 나와서 의외라 그렇습니다. 전 transpose 하고 filter 쓰면 바로 나오겠다 싶은 간단한 문제로 보여 간단한 함수라고 예상하고 잇었는데 저게 실화냐 싶을 정도로 함수가 더럽네요. 거참... 어려운 문제였나?
라
라온보리 9월 9일
@박정호2 님
참고하겠습니다
박
박정호2 9월 9일
@라온보리 님 보통 2021 이 훨씬 효율적이까요. 
제가 2019를 사용해서 2021 특성을 정확하게는 모릅니다. 저 함수를 보면서 이 경우는 오히려 상위버전 으로 더 어려운 문제였을 수도 있다고 봅니다.
박
박정호2 9월 9일
@라온보리 님 일단 2021 함수를 사용해 제 스타일 대로 짰을때는
=FILTER(TRANSPOSE($C$1:$O$1),ISNUMBER(TRANSPOSE($C$2:$O$2)))
나옵니다.
물론 저건 배열수식으로 통채로 나온거니까. 목적이 다르긴 하지만요.
 
전 이게 더 예쁘네요.
박
박정호2 9월 9일
@라온보리 님 라온보리님 수식을 제 스타일 대로 최적화 하면
=INDEX($1:$1,AGGREGATE(15,6,COLUMN($C$2:$O$2)/ISNUMBER($C$2:$O$2),ROW(A1)))
마
마법의손 채택된 답변 9월 8일 
C4
=IFERROR(INDEX(Sheet1!$1:$1,
SMALL(IF(INDEX(Sheet1!$C$2:$O$8, MATCH(B$2, Sheet1!$B$2:$B$8,0),)<>"",
COLUMN(Sheet1!$C$1:$O$1),""),ROW(Sheet1!$A1))),"")

CTRL+SHIFT+ENTER
m365 
=TRIMRANGE(TRANSPOSE(HSTACK($B$2:$B$8,DROP(REDUCE("",SEQUENCE(7),LAMBDA(a,b,VSTACK(a,EXPAND(FILTER($C$1:$O$1,INDEX($C$2:$O$8,b,)<>""),,10,"")))),1))))
 
 
 
 
코
코알라 작성자 9월 9일
@마법의손 님 감사합니다~
2019에서도 해결이 되네요
원
원조백수 9월 8일
수식은 아래로 복사후 마법사님처럼 3개열을 오른쪽으로 끌기 복사
B12 =INDEX($1:$1,AGGREGATE(15,6,IF(OFFSET($C$1:$O$1,MATCH(A$10,$B$2:$B$8),0),COLUMN($C$1:$O$1),NA()),ROW(A1)))

엑셀 질문.xlsx 14 KB
e
exceller1 9월 9일
파워쿼리로 만들어 봅니다.
엑셀 질문.xlsx 24 KB
박
박정호2 9월 9일
@exceller1 님 파워쿼리 불편해서 안 쓰게 됐는데
도대체 얼마나 고수십니까 코드 보고 배워야겠습니다. ㄷㄷㄷ
함수 보다 파워쿼리를 잘 쓰시 특별한 고수십니다.
코
코알라 작성자 9월 9일
@exceller1 님 파워쿼리가 있었네요...
감사합니다~ ^^

질문답변 게시판의 최근 글

스크랩 완료