사용자 정의 함수를 다른 컴퓨터에서 사용

Sub FixUDFPath()
    Dim WB As Workbook, sh As Worksheet, ad As AddIn
    Dim ExLinks As Variant, newName As String, openName As String, vEvents As Variant
    Dim i As Long

    For Each ad In Application.AddIns
        If InStr(1, ad.FullName, "MyAddIn", vbTextCompare) > 0 Then
            If ad.Installed Then
                newName = ad.FullName
                Exit For
            End If
        End If
    Next
    If newName = vbNullString Then newName = ThisWorkbook.FullName
    
    On Error Resume Next
    ExLinks = ActiveWorkbook.LinkSources(xlExcelLinks)
    On Error GoTo 0
    If Not IsEmpty(ExLinks) Then
        For i = LBound(ExLinks) To UBound(ExLinks)
            If InStr(1, ExLinks(i), "MyAddIn", vbTextCompare) Then
                If ExLinks(i) <> newName Then
                    vEvents = Application.EnableEvents
                    Application.EnableEvents = False
                    Application.ScreenUpdating = False
                    openName = ActiveWorkbook.FullName
                    ActiveWorkbook.Close False
                    Workbooks.Open FileName:=openName, UpdateLinks:=False
                    For Each sh In ActiveWorkbook.Sheets
                         sh.Cells.Replace What:="'" & ExLinks(i) & "'!", Replacement:="", _
                                          LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False
                    Next
                    Application.EnableEvents = vEvents
                    Application.ScreenUpdating = True
                End If
            End If
        Next
    End If
    
End Sub