앞 단어의 받침 유무에 따라 잘못 사용된 (을/를) 검사 매크로 만들기 질문

Sub CheckWordPP()
    Dim C As Range, vData As Variant, vError As Variant, i As Long, iCnt As Long
    
    For Each C In Selection
        iCnt = 0
        ReDim vError(1 To 1)
        vData = Split(Replace(Replace(C.Value2, chr(10), " "), ",", " "), " ")
        For i = LBound(vData) To UBound(vData)
            If (Right(vData(i), 1) = "을" And HasFC(Left(Right(vData(i), 2), 1)) = False) Or _
               (Right(vData(i), 1) = "를" And HasFC(Left(Right(vData(i), 2), 1)) = True) Then
                iCnt = iCnt + 1
                ReDim Preserve vError(1 To iCnt)
                vError(iCnt) = vData(i)
            End If
        Next i
        '// 검토할 부분에 색칠하기
        iCnt = 0
        For i = 1 To UBound(vError)
            iCnt = InStr(iCnt + 1, C.Value2, vError(i), vbTextCompare)
            C.Characters(iCnt, Len(vError(i))).Font.Color = vbRed
            C.Characters(iCnt, Len(vError(i))).Font.Bold = True
        Next i
        '// 검토할 단어를 옆에 나열하기
        C.Offset(, 1).Resize(1, UBound(vError) - LBound(vError) + 1) = vError
    Next C
    
End Sub

Function HasFC(Text As String)
    '// 종성을 가지고 있는지,,,
    '// 결과: 한글이 아니면 "", 받침있으면 True, 없으면 False
    Dim Uno As Long
    On Error Resume Next
    HasFC = "":   Uno = AscW(Left(Text, 1)) - &HAC00
    If Uno < 0 Or Uno > 11171 Then Else HasFC = (AscW(Left(Text, 1)) - &HAC00) Mod 28 > 0
End Function