[액셀 VBA] 자동화 - 직책별로 뽑은 직원들을 폼에 연동하여 수정 조회 하기

Private Sub cboPos_Change()
   Me.lboxEmployees.RowSource = "[" & wbYS.Name & "]SCHEMA!" & Me.cboPos.Value
End Sub

Private Sub lboxEmployees_Click()
   EMP.EID = Me.lboxEmployees.Value
   If EMP.EID <> vbNullString Then EMP_ConnectPersonalInfoToForm
End Sub

Public Function EMP_ConnectPersonalInfoToForm() As Boolean
   RowEmp = EMP_GetEmpRow(EMP.EID)     '해당 직원의 행 번호를 찾아 반환
   If RowEmp = 0 Then Exit Function
 
   If EMP_SetEmpCellAddressToDictionary = False Then    '클릭한 직원 행 번호 가져오기. RowEmp는 전역변수기 때문에 매개변수로 넘길 필요 없다.
      EMP_ConnectPersonalInfoToForm = False
      Exit Function
   End If
End Function
 
'클릭한 직원 행 번호 찾아 반고 Dictonary에 셀주소 담기
Public Function EMP_GetEmpRow(EID As String, Optional Col As String = "A") As Long
   Dim RowLast    As Long
   Dim rng        As Range
 
   With wsYS.wsEmp
      RowLast = sh.GetLastRow(Col, wsYS.wsEmp)
      Set rng = .Range("A2:A" & RowLast).Find(What:=EID)      '여기가 직원의 EID로 행 번호를 찾는 부분입니다.
 
      If rng Is Nothing Then
         MsgBox "EID doesn't exist. Check this employees record and try again.", vbInformation
         EMP_GetEmpRow = 0
         Exit Function
      End If
 
      EMP_GetEmpRow = rng.Row
   End With
End Function

'찾은 행번호로 Dictonary에 셀주소 담고 컨트롤에 연동시킴
Public Function EMP_SetEmpCellAddressToDictionary() As Boolean
 
   Dim ColLast As Long
   Dim i As Long
   Dim key As String
   Dim addr As String
   ColLast = sh.GetLastColumn(1, wsYS.wsEmp)  '◀ 마지막 행이나 열 갖은 값을 찾기 위해 만들어 둔 클래스 모듈
 
   dtEmp.RemoveAll
 
   With wsYS.wsEmp
      For i = 1 To ColLast
         key = .Cells(1, i).Value    '◀ 여기에 필드명을 담아 둡니다.
         addr = "[" & wbYS.Name & "]EMPLOYEES!" & .Cells(RowEmp, i).Address '◀ 여기에 셀 주소값을 담아 둠
         On Error Resume Next
            frmEmp.Controls(key).ControlSource = addr     '◀ 이 부분이 해당 폼 컨트를에 각각의 셀을 연동 시켜주는 부분
         On Error GoTo 0                                           '◀ 필드명과 컨트롤의 이름이 같기에 쉽게 루프로 연동 가능
      Next i
   End With
 
   EMP_SetEmpCellAddressToDictionary = True
End Function

Public wbYS As Workbook               '워크불 이름 명명
 
Public Type pwsYS                         '위의 위크복에 속해 있는 워크시트들
   wsEmp          As Worksheet
   wsSCM          As Worksheet
   wsRH           As Worksheet
   wsSF1          As Worksheet
   wsSF2          As Worksheet
   wsTemp         As Worksheet
   attPasteArea   As Range
End Type
 
Public wsYS As pwsYS                     '워크시트들을 접근할 수 있게 하는 전역변수

Private Sub SetWorkbooksAndSheets()
   If sh Is Nothing Then Set sh = New clsSheets
   If xlDb Is Nothing Then Set xlDb = New clsXLDataBase
   If DT Is Nothing Then Set DT = New clsDate
   If cUtil Is Nothing Then Set cUtil = New clsControlUtil
 
   Set wbYS = ThisWorkbook
 
   With wsYS
      Set .wsSCM = wbYS.Worksheets("SCHEMA")
      Set .wsEmp = wbYS.Worksheets("EMPLOYEES")
      Set .wsRH = wbYS.Worksheets("Regular Holidays")
      Set .wsSF1 = wbYS.Worksheets("SalaryFormat1")
      Set .wsSF2 = wbYS.Worksheets("SalaryFormat2")
      Set .wsTemp = wbYS.Worksheets("TEMP")
      Set .attPasteArea = .wsTemp.Range("A2")
   End With   
End Sub