엑셀 시트 저장 :: SaveWS 명령문 사용법 총정리

Function SaveWS(Optional WS As Worksheet, Optional Path As String, Optional FileName As String, Optional Ext As String) As Boolean
 
'###############################################################
'오빠두엑셀 VBA 사용자지정함수 (https://www.oppadu.com)
'▶ SaveWS 함수
'▶ 선택한 시트를 해당 경로에 저장합니다. 저장에 실패했을 경우 False를 반환합니다.
'▶ 인수 설명
'_____________WS        : 저장할 시트입니다. 기본값은 현재 활성화된 시트입니다.
'_____________Path      : 저장할 파일 경로입니다. 기본값은 바탕화면입니다.
'_____________FileName  : 파일명입니다. 기본값은 시트 이름입니다.
'_____________Ext       : 파일 확장자입니다. 기본값은 "xlsx" 입니다.
'▶ 사용 예제
'Dim blnPass As Boolean
'blnPass = SaveWS(ThisWorkBook.WorkSheets("시트명"))
'if blnPass = True Then MsgBox("시트를 저장했습니다.")
'▶ 사용된 보조함수
'GetDesktopPath 함수
'FileExists 함수
'##############################################################
 
Application.ScreenUpdating = False
 
On Error GoTo EH:
 
Dim fFormat As Long
If WS Is Nothing Then Set WS = ActiveSheet
If Path = "" Then Path = GetDesktopPath
If FileName = "" Then FileName = WS.Name
If Ext = "" Then Ext = "xlsx"
 
Select Case Ext
    Case "xlsm": fFormat = 52
    Case "xls": fFormat = -4143
    Case "xlsx": fFormat = 51
End Select
 
If Right(Path, 1) <> "\" Then Path = Path & "\"
 
If Not FileExists(Path) Then MsgBox "저장 경로가 잘못되었습니다. 다시 확인해주세요.", vbInformation: SaveWS = False: Exit Function
If FileExists(Path & FileName & "." & Ext) Then
    Dim vbYN As VbMsgBoxResult
    vbYN = MsgBox("경로에 동일한 파일이 존재합니다. 기존파일을 지우고 새로운 파일로 덮어쓰기 하시겠습니까?", vbYesNo)
    If vbYN = vbNo Then SaveWS = False: Exit Function
End If
 
WS.Copy
With Application.ActiveWorkbook
    Application.DisplayAlerts = False
    .SaveAs Path & FileName & "." & Ext, FileFormat:=fFormat
    Sheets(1).Name = WS.Name
    .Close True
    Application.DisplayAlerts = True
End With
 
SaveWS = True
 
Application.ScreenUpdating = True
 
Exit Function
 
EH:
SaveWS = False
Application.ScreenUpdating = True
 
End Function
 
Public Function GetDesktopPath(Optional BackSlash As Boolean = True) As String
 
'########################################################
'사용중인 PC의 바탕화면 경로를 출력합니다.
'https://www.oppadu.com/vba-fileexists-함수/
'########################################################
 
Dim oWSHShell As Object
 
Set oWSHShell = CreateObject("WScript.Shell")
 
If BackSlash = True Then
    GetDesktopPath = oWSHShell.SpecialFolders("Desktop") & "\"
Else
    GetDesktopPath = oWSHShell.SpecialFolders("Desktop")
End If
 
Set oWSHShell = Nothing
 
End Function
 
Public Function FileExists(ByVal path_ As String) As Boolean
 
'########################################################
'입력한 파일경로에 파일 존재여부를 확인합니다.
'https://www.oppadu.com/vba-fileexists-함수/
'########################################################
 
    FileExists = (Dir(path_, vbDirectory) <> "")
 
End Function