엑셀 두 숫자사이 값 중복없이 랜덤 생성 :: 액셀함수공식

1. 세로방향으로 생성 할 경우
   { =LARGE(ROW(INDIRECT($시작값&":"&$종료값))*NOT(COUNTIF($시작범위윗셀:시작범위윗셀, ROW(INDIRECT($시작값&":"&$종료값)))), RANDBETWEEN(1,$종료값-$시작값+2-ROWS($시작범위윗셀:시작범위윗셀))) }
2. 가로방향으로 생성 할 경우
   { =LARGE(ROW(INDIRECT($시작값&":"&$종료값))*NOT(COUNTIF($시작범위좌측셀:시작범위좌측셀, ROW(INDIRECT($시작값&":"&$종료값)))), RANDBETWEEN(1,$종료값-$시작값+2-COLUMNS($시작범위좌측셀:시작범위좌측셀))) }

본 공식은 배열수식이므로 MS365 버전 사용자가 아닐 경우 Ctrl + Shift + Enter 로 수식을 입력합니다.

1. ROW 함수의 인수로 범위를 입력하면, 범위의 행 번호(숫자)가 배열로 반환됩니다.
   =ROW(INDIRECT($시작값&":"&$종료값))
   =ROW(INDIRECT($1&":"&$10))
   =ROW(INDIRECT($1:$10))
   ={1,2,3,4,5,6,7,8,9,10}
2. COUNTIF 함수와 확장범위($셀:셀)을 사용하여 범위에 중복되는 값이 있는지 여부를 확인합니다. 기준셀 이전에 중복되는 값이 있을 경우 COUNTIF 함수는 0보다 큰 수를 반환합니다.
   =COUNTIF($시작범위윗셀:시작범위윗셀, ROW(INDIRECT($시작값&":"&$종료값)))
   =COUNTIF($A1:A1,ROW($1:$10))
   =COUNTIF($A1:A1,{1,2,3,4,5,6,7,8,9,10})
   =COUNTIF({머릿글},{1,2,3,4,5,6,7,8,9,10})
   ={0,0,0,0,0,0,0,0,0,0}   'A1셀에는 중복되는 값이 없으므로 모두 0을 반환합니다.
   '셀이 아래로 한칸 자동채우기 되었고, 윗셀에 값으로 4가 반환되었다고 가정하면 공식은 아래와 같이 동작합니다.
   =COUNTIF($A1:A2,{1,2,3,4,5,6,7,8,9,10})
   =COUNTIF({머릿글,4},{1,2,3,4,5,6,7,8,9,10})
   ={0,0,0,1,0,0,0,0,0,0}  ' 범위에 4가 있으므로 네번째 값이 1로 반환됩니다.
3. NOT 함수를 사용하여 1은 FALSE로, 0은 TRUE로 변환합니다.
   =NOT(COUNTIF($시작범위윗셀:시작범위윗셀, ROW(INDIRECT($시작값&":"&$종료값)))
   =NOT({0,0,0,1,0,0,0,0,0,0})
   ={TRUE,TRUE,TRUE,FALSE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE}
4. 1번에서 구한 숫자범위와 NOT 함수로 계산된 논리값을 곱하면 중복값을 제외한 값만 반환됩니다.
   ={1,2,3,4,5,6,7,8,9,10}*{TRUE,TRUE,TRUE,FALSE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE}
   ={1,2,3,0,5,6,7,8,9,10}
5. RANDBETWEEN 함수로 두 정수 사이의 값을 랜덤으로 생성합니다.
   =RANDBETWEEN(1,$종료값-$시작값+2-ROWS($시작범위윗셀:시작범위윗셀))
   =RANDBETWEEN(1,10-1+2-ROWS($A1:A1))
   =RANDBETWEEN(1,10-1+2-1)
   =RANDBETWEEN(1,10)  ' 1과 10 사이의 정수를 랜덤으로 생성합니다.
   ' 셀이 아래로 한칸 자동채우기 될 경우, 공식은 아래와 같이 동작합니다.
   =RANDBETWEEN(1,10-1+2-ROWS($A1:A2))
   =RANDBETWEEN(1,10-1+2-2)
   =RANDBETWEEN(1,9)  ' 1과 9사이의 정수를 랜덤으로 생성합니다.
6. 최종적으로 LARGE 함수를 사용하여 두 사이의 값을 중복없이 랜덤으로 생성합니다.
   '두번째 값을 생성하는 것을 예제로 알아봅니다.
   =LARGE(ROW(INDIRECT($시작값&":"&$종료값))*NOT(COUNTIF($시작범위윗셀:시작범위윗셀, ROW(INDIRECT($시작값&":"&$종료값)))), RANDBETWEEN(1,$종료값-$시작값+2-ROWS($시작범위윗셀:시작범위윗셀)))
   =LARGE({1,2,3,0,5,6,7,8,9,10},RANDBETWEEN(1,9))  ' 범위 내 n번째로 큰 수를 랜덤으로 추출합니다.
   =LARGE({1,2,3,0,5,6,7,8,9,10},{4}) ' RANDBETWEEN 함수로 4가 반환되었고, 범위내에서 4번째로 큰 수를 추출합니다.
   =7  ' 7이 반환됩니다.